| 1 | # boost.m4: Locate Boost headers and libraries for autoconf-based projects.
|
|---|
| 2 | # Copyright (C) 2007, 2008, 2009, 2010, 2011 Benoit Sigoure <tsuna@lrde.epita.fr>
|
|---|
| 3 | #
|
|---|
| 4 | # This program is free software: you can redistribute it and/or modify
|
|---|
| 5 | # it under the terms of the GNU General Public License as published by
|
|---|
| 6 | # the Free Software Foundation, either version 3 of the License, or
|
|---|
| 7 | # (at your option) any later version.
|
|---|
| 8 | #
|
|---|
| 9 | # Additional permission under section 7 of the GNU General Public
|
|---|
| 10 | # License, version 3 ("GPLv3"):
|
|---|
| 11 | #
|
|---|
| 12 | # If you convey this file as part of a work that contains a
|
|---|
| 13 | # configuration script generated by Autoconf, you may do so under
|
|---|
| 14 | # terms of your choice.
|
|---|
| 15 | #
|
|---|
| 16 | # This program is distributed in the hope that it will be useful,
|
|---|
| 17 | # but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|---|
| 18 | # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
|
|---|
| 19 | # GNU General Public License for more details.
|
|---|
| 20 | #
|
|---|
| 21 | # You should have received a copy of the GNU General Public License
|
|---|
| 22 | # along with this program. If not, see <http://www.gnu.org/licenses/>.
|
|---|
| 23 |
|
|---|
| 24 | m4_define([_BOOST_SERIAL], [m4_translit([
|
|---|
| 25 | # serial 16
|
|---|
| 26 | ], [#
|
|---|
| 27 | ], [])])
|
|---|
| 28 |
|
|---|
| 29 | # Original sources can be found at http://github.com/tsuna/boost.m4
|
|---|
| 30 | # You can fetch the latest version of the script by doing:
|
|---|
| 31 | # wget http://github.com/tsuna/boost.m4/raw/master/build-aux/boost.m4
|
|---|
| 32 |
|
|---|
| 33 | # ------ #
|
|---|
| 34 | # README #
|
|---|
| 35 | # ------ #
|
|---|
| 36 |
|
|---|
| 37 | # This file provides several macros to use the various Boost libraries.
|
|---|
| 38 | # The first macro is BOOST_REQUIRE. It will simply check if it's possible to
|
|---|
| 39 | # find the Boost headers of a given (optional) minimum version and it will
|
|---|
| 40 | # define BOOST_CPPFLAGS accordingly. It will add an option --with-boost to
|
|---|
| 41 | # your configure so that users can specify non standard locations.
|
|---|
| 42 | # If the user's environment contains BOOST_ROOT and --with-boost was not
|
|---|
| 43 | # specified, --with-boost=$BOOST_ROOT is implicitly used.
|
|---|
| 44 | # For more README and documentation, go to http://github.com/tsuna/boost.m4
|
|---|
| 45 | # Note: THESE MACROS ASSUME THAT YOU USE LIBTOOL. If you don't, don't worry,
|
|---|
| 46 | # simply read the README, it will show you what to do step by step.
|
|---|
| 47 |
|
|---|
| 48 | m4_pattern_forbid([^_?(BOOST|Boost)_])
|
|---|
| 49 |
|
|---|
| 50 |
|
|---|
| 51 | # _BOOST_SED_CPP(SED-PROGRAM, PROGRAM,
|
|---|
| 52 | # [ACTION-IF-FOUND], [ACTION-IF-NOT-FOUND])
|
|---|
| 53 | # --------------------------------------------------------
|
|---|
| 54 | # Same as AC_EGREP_CPP, but leave the result in conftest.i.
|
|---|
| 55 | #
|
|---|
| 56 | # SED-PROGRAM is *not* overquoted, as in AC_EGREP_CPP. It is expanded
|
|---|
| 57 | # in double-quotes, so escape your double quotes.
|
|---|
| 58 | #
|
|---|
| 59 | # It could be useful to turn this into a macro which extracts the
|
|---|
| 60 | # value of any macro.
|
|---|
| 61 | m4_define([_BOOST_SED_CPP],
|
|---|
| 62 | [AC_LANG_PREPROC_REQUIRE()dnl
|
|---|
| 63 | AC_REQUIRE([AC_PROG_SED])dnl
|
|---|
| 64 | AC_LANG_CONFTEST([AC_LANG_SOURCE([[$2]])])
|
|---|
| 65 | AS_IF([dnl eval is necessary to expand ac_cpp.
|
|---|
| 66 | dnl Ultrix and Pyramid sh refuse to redirect output of eval, so use subshell.
|
|---|
| 67 | dnl Beware of Windows end-of-lines, for instance if we are running
|
|---|
| 68 | dnl some Windows programs under Wine. In that case, boost/version.hpp
|
|---|
| 69 | dnl is certainly using "\r\n", but the regular Unix shell will only
|
|---|
| 70 | dnl strip `\n' with backquotes, not the `\r'. This results in
|
|---|
| 71 | dnl boost_cv_lib_version='1_37\r' for instance, which breaks
|
|---|
| 72 | dnl everything else.
|
|---|
| 73 | dnl Cannot use 'dnl' after [$4] because a trailing dnl may break AC_CACHE_CHECK
|
|---|
| 74 | (eval "$ac_cpp conftest.$ac_ext") 2>&AS_MESSAGE_LOG_FD |
|
|---|
| 75 | tr -d '\r' |
|
|---|
| 76 | $SED -n -e "$1" >conftest.i 2>&1],
|
|---|
| 77 | [$3],
|
|---|
| 78 | [$4])
|
|---|
| 79 | rm -rf conftest*
|
|---|
| 80 | ])# AC_EGREP_CPP
|
|---|
| 81 |
|
|---|
| 82 |
|
|---|
| 83 |
|
|---|
| 84 | # BOOST_REQUIRE([VERSION], [ACTION-IF-NOT-FOUND])
|
|---|
| 85 | # -----------------------------------------------
|
|---|
| 86 | # Look for Boost. If version is given, it must either be a literal of the form
|
|---|
| 87 | # "X.Y.Z" where X, Y and Z are integers (the ".Z" part being optional) or a
|
|---|
| 88 | # variable "$var".
|
|---|
| 89 | # Defines the value BOOST_CPPFLAGS. This macro only checks for headers with
|
|---|
| 90 | # the required version, it does not check for any of the Boost libraries.
|
|---|
| 91 | # On # success, defines HAVE_BOOST. On failure, calls the optional
|
|---|
| 92 | # ACTION-IF-NOT-FOUND action if one was supplied.
|
|---|
| 93 | # Otherwise aborts with an error message.
|
|---|
| 94 | AC_DEFUN([BOOST_REQUIRE],
|
|---|
| 95 | [AC_REQUIRE([AC_PROG_CXX])dnl
|
|---|
| 96 | AC_REQUIRE([AC_PROG_GREP])dnl
|
|---|
| 97 | echo "$as_me: this is boost.m4[]_BOOST_SERIAL" >&AS_MESSAGE_LOG_FD
|
|---|
| 98 | boost_save_IFS=$IFS
|
|---|
| 99 | boost_version_req=$1
|
|---|
| 100 | IFS=.
|
|---|
| 101 | set x $boost_version_req 0 0 0
|
|---|
| 102 | IFS=$boost_save_IFS
|
|---|
| 103 | shift
|
|---|
| 104 | boost_version_req=`expr "$[1]" '*' 100000 + "$[2]" '*' 100 + "$[3]"`
|
|---|
| 105 | boost_version_req_string=$[1].$[2].$[3]
|
|---|
| 106 | AC_ARG_WITH([boost],
|
|---|
| 107 | [AS_HELP_STRING([--with-boost=DIR],
|
|---|
| 108 | [prefix of Boost $1 @<:@guess@:>@])])dnl
|
|---|
| 109 | AC_ARG_VAR([BOOST_ROOT],[Location of Boost installation])dnl
|
|---|
| 110 | # If BOOST_ROOT is set and the user has not provided a value to
|
|---|
| 111 | # --with-boost, then treat BOOST_ROOT as if it the user supplied it.
|
|---|
| 112 | if test x"$BOOST_ROOT" != x; then
|
|---|
| 113 | if test x"$with_boost" = x; then
|
|---|
| 114 | AC_MSG_NOTICE([Detected BOOST_ROOT; continuing with --with-boost=$BOOST_ROOT])
|
|---|
| 115 | with_boost=$BOOST_ROOT
|
|---|
| 116 | else
|
|---|
| 117 | AC_MSG_NOTICE([Detected BOOST_ROOT=$BOOST_ROOT, but overridden by --with-boost=$with_boost])
|
|---|
| 118 | fi
|
|---|
| 119 | fi
|
|---|
| 120 | AC_SUBST([DISTCHECK_CONFIGURE_FLAGS],
|
|---|
| 121 | ["$DISTCHECK_CONFIGURE_FLAGS '--with-boost=$with_boost'"])dnl
|
|---|
| 122 | boost_save_CPPFLAGS=$CPPFLAGS
|
|---|
| 123 | AC_CACHE_CHECK([for Boost headers version >= $boost_version_req_string],
|
|---|
| 124 | [boost_cv_inc_path],
|
|---|
| 125 | [boost_cv_inc_path=no
|
|---|
| 126 | AC_LANG_PUSH([C++])dnl
|
|---|
| 127 | m4_pattern_allow([^BOOST_VERSION$])dnl
|
|---|
| 128 | AC_LANG_CONFTEST([AC_LANG_PROGRAM([[#include <boost/version.hpp>
|
|---|
| 129 | #if !defined BOOST_VERSION
|
|---|
| 130 | # error BOOST_VERSION is not defined
|
|---|
| 131 | #elif BOOST_VERSION < $boost_version_req
|
|---|
| 132 | # error Boost headers version < $boost_version_req
|
|---|
| 133 | #endif
|
|---|
| 134 | ]])])
|
|---|
| 135 | # If the user provided a value to --with-boost, use it and only it.
|
|---|
| 136 | case $with_boost in #(
|
|---|
| 137 | ''|yes) set x '' /opt/local/include /usr/local/include /opt/include \
|
|---|
| 138 | /usr/include C:/Boost/include;; #(
|
|---|
| 139 | *) set x "$with_boost/include" "$with_boost";;
|
|---|
| 140 | esac
|
|---|
| 141 | shift
|
|---|
| 142 | for boost_dir
|
|---|
| 143 | do
|
|---|
| 144 | # Without --layout=system, Boost (or at least some versions) installs
|
|---|
| 145 | # itself in <prefix>/include/boost-<version>. This inner loop helps to
|
|---|
| 146 | # find headers in such directories.
|
|---|
| 147 | #
|
|---|
| 148 | # Any ${boost_dir}/boost-x_xx directories are searched in reverse version
|
|---|
| 149 | # order followed by ${boost_dir}. The final '.' is a sentinel for
|
|---|
| 150 | # searching $boost_dir" itself. Entries are whitespace separated.
|
|---|
| 151 | #
|
|---|
| 152 | # I didn't indent this loop on purpose (to avoid over-indented code)
|
|---|
| 153 | boost_layout_system_search_list=`cd "$boost_dir" 2>/dev/null \
|
|---|
| 154 | && ls -1 | "${GREP}" '^boost-' | sort -rn -t- -k2 \
|
|---|
| 155 | && echo .`
|
|---|
| 156 | for boost_inc in $boost_layout_system_search_list
|
|---|
| 157 | do
|
|---|
| 158 | if test x"$boost_inc" != x.; then
|
|---|
| 159 | boost_inc="$boost_dir/$boost_inc"
|
|---|
| 160 | else
|
|---|
| 161 | boost_inc="$boost_dir" # Uses sentinel in boost_layout_system_search_list
|
|---|
| 162 | fi
|
|---|
| 163 | if test x"$boost_inc" != x; then
|
|---|
| 164 | # We are going to check whether the version of Boost installed
|
|---|
| 165 | # in $boost_inc is usable by running a compilation that
|
|---|
| 166 | # #includes it. But if we pass a -I/some/path in which Boost
|
|---|
| 167 | # is not installed, the compiler will just skip this -I and
|
|---|
| 168 | # use other locations (either from CPPFLAGS, or from its list
|
|---|
| 169 | # of system include directories). As a result we would use
|
|---|
| 170 | # header installed on the machine instead of the /some/path
|
|---|
| 171 | # specified by the user. So in that precise case (trying
|
|---|
| 172 | # $boost_inc), make sure the version.hpp exists.
|
|---|
| 173 | #
|
|---|
| 174 | # Use test -e as there can be symlinks.
|
|---|
| 175 | test -e "$boost_inc/boost/version.hpp" || continue
|
|---|
| 176 | CPPFLAGS="$CPPFLAGS -I$boost_inc"
|
|---|
| 177 | fi
|
|---|
| 178 | AC_COMPILE_IFELSE([], [boost_cv_inc_path=yes], [boost_cv_version=no])
|
|---|
| 179 | if test x"$boost_cv_inc_path" = xyes; then
|
|---|
| 180 | if test x"$boost_inc" != x; then
|
|---|
| 181 | boost_cv_inc_path=$boost_inc
|
|---|
| 182 | fi
|
|---|
| 183 | break 2
|
|---|
| 184 | fi
|
|---|
| 185 | done
|
|---|
| 186 | done
|
|---|
| 187 | AC_LANG_POP([C++])dnl
|
|---|
| 188 | ])
|
|---|
| 189 | case $boost_cv_inc_path in #(
|
|---|
| 190 | no)
|
|---|
| 191 | boost_errmsg="cannot find Boost headers version >= $boost_version_req_string"
|
|---|
| 192 | m4_if([$2], [], [AC_MSG_ERROR([$boost_errmsg])],
|
|---|
| 193 | [AC_MSG_NOTICE([$boost_errmsg])])
|
|---|
| 194 | $2
|
|---|
| 195 | ;;#(
|
|---|
| 196 | yes)
|
|---|
| 197 | BOOST_CPPFLAGS=
|
|---|
| 198 | ;;#(
|
|---|
| 199 | *)
|
|---|
| 200 | AC_SUBST([BOOST_CPPFLAGS], ["-I$boost_cv_inc_path"])dnl
|
|---|
| 201 | ;;
|
|---|
| 202 | esac
|
|---|
| 203 | if test x"$boost_cv_inc_path" != xno; then
|
|---|
| 204 | AC_DEFINE([HAVE_BOOST], [1],
|
|---|
| 205 | [Defined if the requested minimum BOOST version is satisfied])
|
|---|
| 206 | AC_CACHE_CHECK([for Boost's header version],
|
|---|
| 207 | [boost_cv_lib_version],
|
|---|
| 208 | [m4_pattern_allow([^BOOST_LIB_VERSION$])dnl
|
|---|
| 209 | _BOOST_SED_CPP([/^boost-lib-version = /{s///;s/\"//g;p;q;}],
|
|---|
| 210 | [#include <boost/version.hpp>
|
|---|
| 211 | boost-lib-version = BOOST_LIB_VERSION],
|
|---|
| 212 | [boost_cv_lib_version=`cat conftest.i`])])
|
|---|
| 213 | # e.g. "134" for 1_34_1 or "135" for 1_35
|
|---|
| 214 | boost_major_version=`echo "$boost_cv_lib_version" | sed 's/_//;s/_.*//'`
|
|---|
| 215 | case $boost_major_version in #(
|
|---|
| 216 | '' | *[[!0-9]]*)
|
|---|
| 217 | AC_MSG_ERROR([invalid value: boost_major_version=$boost_major_version])
|
|---|
| 218 | ;;
|
|---|
| 219 | esac
|
|---|
| 220 | fi
|
|---|
| 221 | CPPFLAGS=$boost_save_CPPFLAGS
|
|---|
| 222 | ])# BOOST_REQUIRE
|
|---|
| 223 |
|
|---|
| 224 | # BOOST_STATIC()
|
|---|
| 225 | # --------------
|
|---|
| 226 | # Add the "--enable-static-boost" configure argument. If this argument is given
|
|---|
| 227 | # on the command line, static versions of the libraries will be looked up.
|
|---|
| 228 | AC_DEFUN([BOOST_STATIC],
|
|---|
| 229 | [AC_ARG_ENABLE([static-boost],
|
|---|
| 230 | [AC_HELP_STRING([--enable-static-boost],
|
|---|
| 231 | [Prefer the static boost libraries over the shared ones [no]])],
|
|---|
| 232 | [enable_static_boost=yes],
|
|---|
| 233 | [enable_static_boost=no])])# BOOST_STATIC
|
|---|
| 234 |
|
|---|
| 235 | # BOOST_FIND_HEADER([HEADER-NAME], [ACTION-IF-NOT-FOUND], [ACTION-IF-FOUND])
|
|---|
| 236 | # --------------------------------------------------------------------------
|
|---|
| 237 | # Wrapper around AC_CHECK_HEADER for Boost headers. Useful to check for
|
|---|
| 238 | # some parts of the Boost library which are only made of headers and don't
|
|---|
| 239 | # require linking (such as Boost.Foreach).
|
|---|
| 240 | #
|
|---|
| 241 | # Default ACTION-IF-NOT-FOUND: Fail with a fatal error unless Boost couldn't be
|
|---|
| 242 | # found in the first place, in which case by default a notice is issued to the
|
|---|
| 243 | # user. Presumably if we haven't died already it's because it's OK to not have
|
|---|
| 244 | # Boost, which is why only a notice is issued instead of a hard error.
|
|---|
| 245 | #
|
|---|
| 246 | # Default ACTION-IF-FOUND: define the preprocessor symbol HAVE_<HEADER-NAME> in
|
|---|
| 247 | # case of success # (where HEADER-NAME is written LIKE_THIS, e.g.,
|
|---|
| 248 | # HAVE_BOOST_FOREACH_HPP).
|
|---|
| 249 | AC_DEFUN([BOOST_FIND_HEADER],
|
|---|
| 250 | [AC_REQUIRE([BOOST_REQUIRE])dnl
|
|---|
| 251 | if test x"$boost_cv_inc_path" = xno; then
|
|---|
| 252 | m4_default([$2], [AC_MSG_NOTICE([Boost not available, not searching for $1])])
|
|---|
| 253 | else
|
|---|
| 254 | AC_LANG_PUSH([C++])dnl
|
|---|
| 255 | boost_save_CPPFLAGS=$CPPFLAGS
|
|---|
| 256 | CPPFLAGS="$CPPFLAGS $BOOST_CPPFLAGS"
|
|---|
| 257 | AC_CHECK_HEADER([$1],
|
|---|
| 258 | [m4_default([$3], [AC_DEFINE(AS_TR_CPP([HAVE_$1]), [1],
|
|---|
| 259 | [Define to 1 if you have <$1>])])],
|
|---|
| 260 | [m4_default([$2], [AC_MSG_ERROR([cannot find $1])])])
|
|---|
| 261 | CPPFLAGS=$boost_save_CPPFLAGS
|
|---|
| 262 | AC_LANG_POP([C++])dnl
|
|---|
| 263 | fi
|
|---|
| 264 | ])# BOOST_FIND_HEADER
|
|---|
| 265 |
|
|---|
| 266 |
|
|---|
| 267 | # BOOST_FIND_LIB([LIB-NAME], [PREFERRED-RT-OPT], [HEADER-NAME], [CXX-TEST],
|
|---|
| 268 | # [CXX-PROLOGUE])
|
|---|
| 269 | # -------------------------------------------------------------------------
|
|---|
| 270 | # Look for the Boost library LIB-NAME (e.g., LIB-NAME = `thread', for
|
|---|
| 271 | # libboost_thread). Check that HEADER-NAME works and check that
|
|---|
| 272 | # libboost_LIB-NAME can link with the code CXX-TEST. The optional argument
|
|---|
| 273 | # CXX-PROLOGUE can be used to include some C++ code before the `main'
|
|---|
| 274 | # function.
|
|---|
| 275 | #
|
|---|
| 276 | # Invokes BOOST_FIND_HEADER([HEADER-NAME]) (see above).
|
|---|
| 277 | #
|
|---|
| 278 | # Boost libraries typically come compiled with several flavors (with different
|
|---|
| 279 | # runtime options) so PREFERRED-RT-OPT is the preferred suffix. A suffix is one
|
|---|
| 280 | # or more of the following letters: sgdpn (in that order). s = static
|
|---|
| 281 | # runtime, d = debug build, g = debug/diagnostic runtime, p = STLPort build,
|
|---|
| 282 | # n = (unsure) STLPort build without iostreams from STLPort (it looks like `n'
|
|---|
| 283 | # must always be used along with `p'). Additionally, PREFERRED-RT-OPT can
|
|---|
| 284 | # start with `mt-' to indicate that there is a preference for multi-thread
|
|---|
| 285 | # builds. Some sample values for PREFERRED-RT-OPT: (nothing), mt, d, mt-d, gdp
|
|---|
| 286 | # ... If you want to make sure you have a specific version of Boost
|
|---|
| 287 | # (eg, >= 1.33) you *must* invoke BOOST_REQUIRE before this macro.
|
|---|
| 288 | AC_DEFUN([BOOST_FIND_LIB],
|
|---|
| 289 | [AC_REQUIRE([BOOST_REQUIRE])dnl
|
|---|
| 290 | AC_REQUIRE([_BOOST_FIND_COMPILER_TAG])dnl
|
|---|
| 291 | AC_REQUIRE([BOOST_STATIC])dnl
|
|---|
| 292 | AC_REQUIRE([_BOOST_GUESS_WHETHER_TO_USE_MT])dnl
|
|---|
| 293 | if test x"$boost_cv_inc_path" = xno; then
|
|---|
| 294 | AC_MSG_NOTICE([Boost not available, not searching for the Boost $1 library])
|
|---|
| 295 | else
|
|---|
| 296 | dnl The else branch is huge and wasn't intended on purpose.
|
|---|
| 297 | AC_LANG_PUSH([C++])dnl
|
|---|
| 298 | AS_VAR_PUSHDEF([Boost_lib], [boost_cv_lib_$1])dnl
|
|---|
| 299 | AS_VAR_PUSHDEF([Boost_lib_LDFLAGS], [boost_cv_lib_$1_LDFLAGS])dnl
|
|---|
| 300 | AS_VAR_PUSHDEF([Boost_lib_LDPATH], [boost_cv_lib_$1_LDPATH])dnl
|
|---|
| 301 | AS_VAR_PUSHDEF([Boost_lib_LIBS], [boost_cv_lib_$1_LIBS])dnl
|
|---|
| 302 | BOOST_FIND_HEADER([$3])
|
|---|
| 303 | boost_save_CPPFLAGS=$CPPFLAGS
|
|---|
| 304 | CPPFLAGS="$CPPFLAGS $BOOST_CPPFLAGS"
|
|---|
| 305 | # Now let's try to find the library. The algorithm is as follows: first look
|
|---|
| 306 | # for a given library name according to the user's PREFERRED-RT-OPT. For each
|
|---|
| 307 | # library name, we prefer to use the ones that carry the tag (toolset name).
|
|---|
| 308 | # Each library is searched through the various standard paths were Boost is
|
|---|
| 309 | # usually installed. If we can't find the standard variants, we try to
|
|---|
| 310 | # enforce -mt (for instance on MacOSX, libboost_threads.dylib doesn't exist
|
|---|
| 311 | # but there's -obviously- libboost_threads-mt.dylib).
|
|---|
| 312 | AC_CACHE_CHECK([for the Boost $1 library], [Boost_lib],
|
|---|
| 313 | [Boost_lib=no
|
|---|
| 314 | case "$2" in #(
|
|---|
| 315 | mt | mt-) boost_mt=-mt; boost_rtopt=;; #(
|
|---|
| 316 | mt* | mt-*) boost_mt=-mt; boost_rtopt=`expr "X$2" : 'Xmt-*\(.*\)'`;; #(
|
|---|
| 317 | *) boost_mt=; boost_rtopt=$2;;
|
|---|
| 318 | esac
|
|---|
| 319 | if test $enable_static_boost = yes; then
|
|---|
| 320 | boost_rtopt="s$boost_rtopt"
|
|---|
| 321 | fi
|
|---|
| 322 | # Find the proper debug variant depending on what we've been asked to find.
|
|---|
| 323 | case $boost_rtopt in #(
|
|---|
| 324 | *d*) boost_rt_d=$boost_rtopt;; #(
|
|---|
| 325 | *[[sgpn]]*) # Insert the `d' at the right place (in between `sg' and `pn')
|
|---|
| 326 | boost_rt_d=`echo "$boost_rtopt" | sed 's/\(s*g*\)\(p*n*\)/\1\2/'`;; #(
|
|---|
| 327 | *) boost_rt_d='-d';;
|
|---|
| 328 | esac
|
|---|
| 329 | # If the PREFERRED-RT-OPT are not empty, prepend a `-'.
|
|---|
| 330 | test -n "$boost_rtopt" && boost_rtopt="-$boost_rtopt"
|
|---|
| 331 | $boost_guess_use_mt && boost_mt=-mt
|
|---|
| 332 | # Look for the abs path the static archive.
|
|---|
| 333 | # $libext is computed by Libtool but let's make sure it's non empty.
|
|---|
| 334 | test -z "$libext" &&
|
|---|
| 335 | AC_MSG_ERROR([the libext variable is empty, did you invoke Libtool?])
|
|---|
| 336 | boost_save_ac_objext=$ac_objext
|
|---|
| 337 | # Generate the test file.
|
|---|
| 338 | AC_LANG_CONFTEST([AC_LANG_PROGRAM([#include <$3>
|
|---|
| 339 | $5], [$4])])
|
|---|
| 340 | dnl Optimization hacks: compiling C++ is slow, especially with Boost. What
|
|---|
| 341 | dnl we're trying to do here is guess the right combination of link flags
|
|---|
| 342 | dnl (LIBS / LDFLAGS) to use a given library. This can take several
|
|---|
| 343 | dnl iterations before it succeeds and is thus *very* slow. So what we do
|
|---|
| 344 | dnl instead is that we compile the code first (and thus get an object file,
|
|---|
| 345 | dnl typically conftest.o). Then we try various combinations of link flags
|
|---|
| 346 | dnl until we succeed to link conftest.o in an executable. The problem is
|
|---|
| 347 | dnl that the various TRY_LINK / COMPILE_IFELSE macros of Autoconf always
|
|---|
| 348 | dnl remove all the temporary files including conftest.o. So the trick here
|
|---|
| 349 | dnl is to temporarily change the value of ac_objext so that conftest.o is
|
|---|
| 350 | dnl preserved accross tests. This is obviously fragile and I will burn in
|
|---|
| 351 | dnl hell for not respecting Autoconf's documented interfaces, but in the
|
|---|
| 352 | dnl mean time, it optimizes the macro by a factor of 5 to 30.
|
|---|
| 353 | dnl Another small optimization: the first argument of AC_COMPILE_IFELSE left
|
|---|
| 354 | dnl empty because the test file is generated only once above (before we
|
|---|
| 355 | dnl start the for loops).
|
|---|
| 356 | AC_COMPILE_IFELSE([],
|
|---|
| 357 | [ac_objext=do_not_rm_me_plz],
|
|---|
| 358 | [AC_MSG_ERROR([cannot compile a test that uses Boost $1])])
|
|---|
| 359 | ac_objext=$boost_save_ac_objext
|
|---|
| 360 | boost_failed_libs=
|
|---|
| 361 | # Don't bother to ident the 6 nested for loops, only the 2 innermost ones
|
|---|
| 362 | # matter.
|
|---|
| 363 | for boost_tag_ in -$boost_cv_lib_tag ''; do
|
|---|
| 364 | for boost_ver_ in -$boost_cv_lib_version ''; do
|
|---|
| 365 | for boost_mt_ in $boost_mt -mt ''; do
|
|---|
| 366 | for boost_rtopt_ in $boost_rtopt '' -d; do
|
|---|
| 367 | for boost_lib in \
|
|---|
| 368 | boost_$1$boost_tag_$boost_mt_$boost_rtopt_$boost_ver_ \
|
|---|
| 369 | boost_$1$boost_tag_$boost_rtopt_$boost_ver_ \
|
|---|
| 370 | boost_$1$boost_tag_$boost_mt_$boost_ver_ \
|
|---|
| 371 | boost_$1$boost_tag_$boost_ver_
|
|---|
| 372 | do
|
|---|
| 373 | # Avoid testing twice the same lib
|
|---|
| 374 | case $boost_failed_libs in #(
|
|---|
| 375 | *@$boost_lib@*) continue;;
|
|---|
| 376 | esac
|
|---|
| 377 | # If with_boost is empty, we'll search in /lib first, which is not quite
|
|---|
| 378 | # right so instead we'll try to a location based on where the headers are.
|
|---|
| 379 | boost_tmp_lib=$with_boost
|
|---|
| 380 | test x"$with_boost" = x && boost_tmp_lib=${boost_cv_inc_path%/include}
|
|---|
| 381 | for boost_ldpath in "$boost_tmp_lib/lib" '' \
|
|---|
| 382 | /opt/local/lib* /usr/local/lib* /opt/lib* /usr/lib* \
|
|---|
| 383 | "$with_boost" C:/Boost/lib /lib*
|
|---|
| 384 | do
|
|---|
| 385 | test -e "$boost_ldpath" || continue
|
|---|
| 386 | boost_save_LDFLAGS=$LDFLAGS
|
|---|
| 387 | # Are we looking for a static library?
|
|---|
| 388 | case $boost_ldpath:$boost_rtopt_ in #(
|
|---|
| 389 | *?*:*s*) # Yes (Non empty boost_ldpath + s in rt opt)
|
|---|
| 390 | Boost_lib_LIBS="$boost_ldpath/lib$boost_lib.$libext"
|
|---|
| 391 | test -e "$Boost_lib_LIBS" || continue;; #(
|
|---|
| 392 | *) # No: use -lboost_foo to find the shared library.
|
|---|
| 393 | Boost_lib_LIBS="-l$boost_lib";;
|
|---|
| 394 | esac
|
|---|
| 395 | boost_save_LIBS=$LIBS
|
|---|
| 396 | LIBS="$Boost_lib_LIBS $LIBS"
|
|---|
| 397 | test x"$boost_ldpath" != x && LDFLAGS="$LDFLAGS -L$boost_ldpath"
|
|---|
| 398 | dnl First argument of AC_LINK_IFELSE left empty because the test file is
|
|---|
| 399 | dnl generated only once above (before we start the for loops).
|
|---|
| 400 | _BOOST_AC_LINK_IFELSE([],
|
|---|
| 401 | [Boost_lib=yes], [Boost_lib=no])
|
|---|
| 402 | ac_objext=$boost_save_ac_objext
|
|---|
| 403 | LDFLAGS=$boost_save_LDFLAGS
|
|---|
| 404 | LIBS=$boost_save_LIBS
|
|---|
| 405 | if test x"$Boost_lib" = xyes; then
|
|---|
| 406 | Boost_lib_LDFLAGS="-L$boost_ldpath -Wl,-R$boost_ldpath"
|
|---|
| 407 | Boost_lib_LDPATH="$boost_ldpath"
|
|---|
| 408 | break 6
|
|---|
| 409 | else
|
|---|
| 410 | boost_failed_libs="$boost_failed_libs@$boost_lib@"
|
|---|
| 411 | fi
|
|---|
| 412 | done
|
|---|
| 413 | done
|
|---|
| 414 | done
|
|---|
| 415 | done
|
|---|
| 416 | done
|
|---|
| 417 | done
|
|---|
| 418 | rm -f conftest.$ac_objext
|
|---|
| 419 | ])
|
|---|
| 420 | case $Boost_lib in #(
|
|---|
| 421 | no) _AC_MSG_LOG_CONFTEST
|
|---|
| 422 | AC_MSG_ERROR([cannot find the flags to link with Boost $1])
|
|---|
| 423 | ;;
|
|---|
| 424 | esac
|
|---|
| 425 | AC_SUBST(AS_TR_CPP([BOOST_$1_LDFLAGS]), [$Boost_lib_LDFLAGS])dnl
|
|---|
| 426 | AC_SUBST(AS_TR_CPP([BOOST_$1_LDPATH]), [$Boost_lib_LDPATH])dnl
|
|---|
| 427 | AC_SUBST([BOOST_LDPATH], [$Boost_lib_LDPATH])dnl
|
|---|
| 428 | AC_SUBST(AS_TR_CPP([BOOST_$1_LIBS]), [$Boost_lib_LIBS])dnl
|
|---|
| 429 | CPPFLAGS=$boost_save_CPPFLAGS
|
|---|
| 430 | AS_VAR_POPDEF([Boost_lib])dnl
|
|---|
| 431 | AS_VAR_POPDEF([Boost_lib_LDFLAGS])dnl
|
|---|
| 432 | AS_VAR_POPDEF([Boost_lib_LDPATH])dnl
|
|---|
| 433 | AS_VAR_POPDEF([Boost_lib_LIBS])dnl
|
|---|
| 434 | AC_LANG_POP([C++])dnl
|
|---|
| 435 | fi
|
|---|
| 436 | ])# BOOST_FIND_LIB
|
|---|
| 437 |
|
|---|
| 438 |
|
|---|
| 439 | # --------------------------------------- #
|
|---|
| 440 | # Checks for the various Boost libraries. #
|
|---|
| 441 | # --------------------------------------- #
|
|---|
| 442 |
|
|---|
| 443 | # List of boost libraries: http://www.boost.org/libs/libraries.htm
|
|---|
| 444 | # The page http://beta.boost.org/doc/libs is useful: it gives the first release
|
|---|
| 445 | # version of each library (among other things).
|
|---|
| 446 |
|
|---|
| 447 | # BOOST_DEFUN(LIBRARY, CODE)
|
|---|
| 448 | # --------------------------
|
|---|
| 449 | # Define BOOST_<LIBRARY-UPPERCASE> as a macro that runs CODE.
|
|---|
| 450 | #
|
|---|
| 451 | # Use indir to avoid the warning on underquoted macro name given to AC_DEFUN.
|
|---|
| 452 | m4_define([BOOST_DEFUN],
|
|---|
| 453 | [m4_indir([AC_DEFUN],
|
|---|
| 454 | m4_toupper([BOOST_$1]),
|
|---|
| 455 | [m4_pushdef([BOOST_Library], [$1])dnl
|
|---|
| 456 | $2
|
|---|
| 457 | m4_popdef([BOOST_Library])dnl
|
|---|
| 458 | ])
|
|---|
| 459 | ])
|
|---|
| 460 |
|
|---|
| 461 |
|
|---|
| 462 | # BOOST_ANY()
|
|---|
| 463 | # ------------
|
|---|
| 464 | # Look for Boost.Any
|
|---|
| 465 | BOOST_DEFUN([Any],
|
|---|
| 466 | [BOOST_FIND_HEADER([boost/any.hpp])])
|
|---|
| 467 |
|
|---|
| 468 |
|
|---|
| 469 | # BOOST_ARRAY()
|
|---|
| 470 | # -------------
|
|---|
| 471 | # Look for Boost.Array
|
|---|
| 472 | BOOST_DEFUN([Array],
|
|---|
| 473 | [BOOST_FIND_HEADER([boost/array.hpp])])
|
|---|
| 474 |
|
|---|
| 475 |
|
|---|
| 476 | # BOOST_ASIO()
|
|---|
| 477 | # ------------
|
|---|
| 478 | # Look for Boost.Asio (new in Boost 1.35).
|
|---|
| 479 | BOOST_DEFUN([Asio],
|
|---|
| 480 | [AC_REQUIRE([BOOST_SYSTEM])dnl
|
|---|
| 481 | BOOST_FIND_HEADER([boost/asio.hpp])])
|
|---|
| 482 |
|
|---|
| 483 |
|
|---|
| 484 | # BOOST_BIND()
|
|---|
| 485 | # ------------
|
|---|
| 486 | # Look for Boost.Bind
|
|---|
| 487 | BOOST_DEFUN([Bind],
|
|---|
| 488 | [BOOST_FIND_HEADER([boost/bind.hpp])])
|
|---|
| 489 |
|
|---|
| 490 |
|
|---|
| 491 | # BOOST_CONVERSION()
|
|---|
| 492 | # ------------------
|
|---|
| 493 | # Look for Boost.Conversion (cast / lexical_cast)
|
|---|
| 494 | BOOST_DEFUN([Conversion],
|
|---|
| 495 | [BOOST_FIND_HEADER([boost/cast.hpp])
|
|---|
| 496 | BOOST_FIND_HEADER([boost/lexical_cast.hpp])
|
|---|
| 497 | ])# BOOST_CONVERSION
|
|---|
| 498 |
|
|---|
| 499 |
|
|---|
| 500 | # BOOST_DATE_TIME([PREFERRED-RT-OPT])
|
|---|
| 501 | # -----------------------------------
|
|---|
| 502 | # Look for Boost.Date_Time. For the documentation of PREFERRED-RT-OPT, see the
|
|---|
| 503 | # documentation of BOOST_FIND_LIB above.
|
|---|
| 504 | BOOST_DEFUN([Date_Time],
|
|---|
| 505 | [BOOST_FIND_LIB([date_time], [$1],
|
|---|
| 506 | [boost/date_time/posix_time/posix_time.hpp],
|
|---|
| 507 | [boost::posix_time::ptime t;])
|
|---|
| 508 | ])# BOOST_DATE_TIME
|
|---|
| 509 |
|
|---|
| 510 |
|
|---|
| 511 | # BOOST_EXCEPTION()
|
|---|
| 512 | # ------------
|
|---|
| 513 | # Look for Boost.Exception
|
|---|
| 514 | BOOST_DEFUN([Exception],
|
|---|
| 515 | [BOOST_FIND_HEADER([boost/exception/all.hpp])])
|
|---|
| 516 |
|
|---|
| 517 |
|
|---|
| 518 | # BOOST_FILESYSTEM([PREFERRED-RT-OPT])
|
|---|
| 519 | # ------------------------------------
|
|---|
| 520 | # Look for Boost.Filesystem. For the documentation of PREFERRED-RT-OPT, see
|
|---|
| 521 | # the documentation of BOOST_FIND_LIB above.
|
|---|
| 522 | # Do not check for boost/filesystem.hpp because this file was introduced in
|
|---|
| 523 | # 1.34.
|
|---|
| 524 | BOOST_DEFUN([Filesystem],
|
|---|
| 525 | [# Do we have to check for Boost.System? This link-time dependency was
|
|---|
| 526 | # added as of 1.35.0. If we have a version <1.35, we must not attempt to
|
|---|
| 527 | # find Boost.System as it didn't exist by then.
|
|---|
| 528 | if test $boost_major_version -ge 135; then
|
|---|
| 529 | BOOST_SYSTEM([$1])
|
|---|
| 530 | fi # end of the Boost.System check.
|
|---|
| 531 | boost_filesystem_save_LIBS=$LIBS
|
|---|
| 532 | boost_filesystem_save_LDFLAGS=$LDFLAGS
|
|---|
| 533 | m4_pattern_allow([^BOOST_SYSTEM_(LIBS|LDFLAGS)$])dnl
|
|---|
| 534 | LIBS="$LIBS $BOOST_SYSTEM_LIBS"
|
|---|
| 535 | LDFLAGS="$LDFLAGS $BOOST_SYSTEM_LDFLAGS"
|
|---|
| 536 | BOOST_FIND_LIB([filesystem], [$1],
|
|---|
| 537 | [boost/filesystem/path.hpp], [boost::filesystem::path p;])
|
|---|
| 538 | if test $enable_static_boost = yes && test $boost_major_version -ge 135; then
|
|---|
| 539 | AC_SUBST([BOOST_FILESYSTEM_LIBS], ["$BOOST_FILESYSTEM_LIBS $BOOST_SYSTEM_LIBS"])
|
|---|
| 540 | fi
|
|---|
| 541 | LIBS=$boost_filesystem_save_LIBS
|
|---|
| 542 | LDFLAGS=$boost_filesystem_save_LDFLAGS
|
|---|
| 543 | ])# BOOST_FILESYSTEM
|
|---|
| 544 |
|
|---|
| 545 |
|
|---|
| 546 | # BOOST_FOREACH()
|
|---|
| 547 | # ---------------
|
|---|
| 548 | # Look for Boost.Foreach
|
|---|
| 549 | BOOST_DEFUN([Foreach],
|
|---|
| 550 | [BOOST_FIND_HEADER([boost/foreach.hpp])])
|
|---|
| 551 |
|
|---|
| 552 |
|
|---|
| 553 | # BOOST_FORMAT()
|
|---|
| 554 | # --------------
|
|---|
| 555 | # Look for Boost.Format
|
|---|
| 556 | # Note: we can't check for boost/format/format_fwd.hpp because the header isn't
|
|---|
| 557 | # standalone. It can't be compiled because it triggers the following error:
|
|---|
| 558 | # boost/format/detail/config_macros.hpp:88: error: 'locale' in namespace 'std'
|
|---|
| 559 | # does not name a type
|
|---|
| 560 | BOOST_DEFUN([Format],
|
|---|
| 561 | [BOOST_FIND_HEADER([boost/format.hpp])])
|
|---|
| 562 |
|
|---|
| 563 |
|
|---|
| 564 | # BOOST_FUNCTION()
|
|---|
| 565 | # ----------------
|
|---|
| 566 | # Look for Boost.Function
|
|---|
| 567 | BOOST_DEFUN([Function],
|
|---|
| 568 | [BOOST_FIND_HEADER([boost/function.hpp])])
|
|---|
| 569 |
|
|---|
| 570 |
|
|---|
| 571 | # BOOST_GRAPH([PREFERRED-RT-OPT])
|
|---|
| 572 | # -------------------------------
|
|---|
| 573 | # Look for Boost.Graphs. For the documentation of PREFERRED-RT-OPT, see the
|
|---|
| 574 | # documentation of BOOST_FIND_LIB above.
|
|---|
| 575 | BOOST_DEFUN([Graph],
|
|---|
| 576 | [BOOST_FIND_LIB([graph], [$1],
|
|---|
| 577 | [boost/graph/adjacency_list.hpp], [boost::adjacency_list<> g;])
|
|---|
| 578 | ])# BOOST_GRAPH
|
|---|
| 579 |
|
|---|
| 580 |
|
|---|
| 581 | # BOOST_IOSTREAMS([PREFERRED-RT-OPT])
|
|---|
| 582 | # -----------------------------------
|
|---|
| 583 | # Look for Boost.IOStreams. For the documentation of PREFERRED-RT-OPT, see the
|
|---|
| 584 | # documentation of BOOST_FIND_LIB above.
|
|---|
| 585 | BOOST_DEFUN([IOStreams],
|
|---|
| 586 | [BOOST_FIND_LIB([iostreams], [$1],
|
|---|
| 587 | [boost/iostreams/device/file_descriptor.hpp],
|
|---|
| 588 | [boost::iostreams::file_descriptor fd; fd.close();])
|
|---|
| 589 | ])# BOOST_IOSTREAMS
|
|---|
| 590 |
|
|---|
| 591 |
|
|---|
| 592 | # BOOST_HASH()
|
|---|
| 593 | # ------------
|
|---|
| 594 | # Look for Boost.Functional/Hash
|
|---|
| 595 | BOOST_DEFUN([Hash],
|
|---|
| 596 | [BOOST_FIND_HEADER([boost/functional/hash.hpp])])
|
|---|
| 597 |
|
|---|
| 598 |
|
|---|
| 599 | # BOOST_ITERATOR()
|
|---|
| 600 | # ------------
|
|---|
| 601 | # Look for Boost.Iterator
|
|---|
| 602 | BOOST_DEFUN([Iterator],
|
|---|
| 603 | [BOOST_FIND_HEADER([boost/iterator/iterator_adaptor.hpp])])
|
|---|
| 604 |
|
|---|
| 605 |
|
|---|
| 606 | # BOOST_LAMBDA()
|
|---|
| 607 | # --------------
|
|---|
| 608 | # Look for Boost.Lambda
|
|---|
| 609 | BOOST_DEFUN([Lambda],
|
|---|
| 610 | [BOOST_FIND_HEADER([boost/lambda/lambda.hpp])])
|
|---|
| 611 |
|
|---|
| 612 |
|
|---|
| 613 | # BOOST_LOG([PREFERRED-RT-OPT])
|
|---|
| 614 | # -----------------------------
|
|---|
| 615 | # Look for Boost.Log For the documentation of PREFERRED-RT-OPT, see the
|
|---|
| 616 | # documentation of BOOST_FIND_LIB above.
|
|---|
| 617 | BOOST_DEFUN([Log],
|
|---|
| 618 | [BOOST_FIND_LIB([log], [$1],
|
|---|
| 619 | [boost/log/core/core.hpp],
|
|---|
| 620 | [boost::log::attribute a; a.get_value();])
|
|---|
| 621 | ])# BOOST_LOG
|
|---|
| 622 |
|
|---|
| 623 |
|
|---|
| 624 | # BOOST_LOG_SETUP([PREFERRED-RT-OPT])
|
|---|
| 625 | # -----------------------------------
|
|---|
| 626 | # Look for Boost.Log For the documentation of PREFERRED-RT-OPT, see the
|
|---|
| 627 | # documentation of BOOST_FIND_LIB above.
|
|---|
| 628 | BOOST_DEFUN([Log_Setup],
|
|---|
| 629 | [AC_REQUIRE([BOOST_LOG])dnl
|
|---|
| 630 | BOOST_FIND_LIB([log_setup], [$1],
|
|---|
| 631 | [boost/log/utility/init/from_settings.hpp],
|
|---|
| 632 | [boost::log::basic_settings<char> bs; bs.empty();])
|
|---|
| 633 | ])# BOOST_LOG_SETUP
|
|---|
| 634 |
|
|---|
| 635 |
|
|---|
| 636 | # BOOST_MATH()
|
|---|
| 637 | # ------------
|
|---|
| 638 | # Look for Boost.Math
|
|---|
| 639 | # TODO: This library isn't header-only but it comes in multiple different
|
|---|
| 640 | # flavors that don't play well with BOOST_FIND_LIB (e.g, libboost_math_c99,
|
|---|
| 641 | # libboost_math_c99f, libboost_math_c99l, libboost_math_tr1,
|
|---|
| 642 | # libboost_math_tr1f, libboost_math_tr1l). This macro must be fixed to do the
|
|---|
| 643 | # right thing anyway.
|
|---|
| 644 | BOOST_DEFUN([Math],
|
|---|
| 645 | [BOOST_FIND_HEADER([boost/math/special_functions.hpp])])
|
|---|
| 646 |
|
|---|
| 647 |
|
|---|
| 648 | # BOOST_MULTIARRAY()
|
|---|
| 649 | # ------------------
|
|---|
| 650 | # Look for Boost.MultiArray
|
|---|
| 651 | BOOST_DEFUN([MultiArray],
|
|---|
| 652 | [BOOST_FIND_HEADER([boost/multi_array.hpp])])
|
|---|
| 653 |
|
|---|
| 654 |
|
|---|
| 655 | # BOOST_NUMERIC_CONVERSION()
|
|---|
| 656 | # --------------------------
|
|---|
| 657 | # Look for Boost.NumericConversion (policy-based numeric conversion)
|
|---|
| 658 | BOOST_DEFUN([Numeric_Conversion],
|
|---|
| 659 | [BOOST_FIND_HEADER([boost/numeric/conversion/converter.hpp])
|
|---|
| 660 | ])# BOOST_NUMERIC_CONVERSION
|
|---|
| 661 |
|
|---|
| 662 |
|
|---|
| 663 | # BOOST_OPTIONAL()
|
|---|
| 664 | # ----------------
|
|---|
| 665 | # Look for Boost.Optional
|
|---|
| 666 | BOOST_DEFUN([Optional],
|
|---|
| 667 | [BOOST_FIND_HEADER([boost/optional.hpp])])
|
|---|
| 668 |
|
|---|
| 669 |
|
|---|
| 670 | # BOOST_PREPROCESSOR()
|
|---|
| 671 | # --------------------
|
|---|
| 672 | # Look for Boost.Preprocessor
|
|---|
| 673 | BOOST_DEFUN([Preprocessor],
|
|---|
| 674 | [BOOST_FIND_HEADER([boost/preprocessor/repeat.hpp])])
|
|---|
| 675 |
|
|---|
| 676 |
|
|---|
| 677 | # BOOST_RANDOM()
|
|---|
| 678 | # --------------------
|
|---|
| 679 | # Look for Boost.Random
|
|---|
| 680 | BOOST_DEFUN([Random],
|
|---|
| 681 | [BOOST_FIND_HEADER([boost/random/random_number_generator.hpp])])
|
|---|
| 682 |
|
|---|
| 683 |
|
|---|
| 684 | # BOOST_UNORDERED()
|
|---|
| 685 | # -----------------
|
|---|
| 686 | # Look for Boost.Unordered
|
|---|
| 687 | BOOST_DEFUN([Unordered],
|
|---|
| 688 | [BOOST_FIND_HEADER([boost/unordered_map.hpp])])
|
|---|
| 689 |
|
|---|
| 690 |
|
|---|
| 691 | # BOOST_UUID()
|
|---|
| 692 | # ------------
|
|---|
| 693 | # Look for Boost.Uuid
|
|---|
| 694 | BOOST_DEFUN([Uuid],
|
|---|
| 695 | [BOOST_FIND_HEADER([boost/uuid/uuid.hpp])])
|
|---|
| 696 |
|
|---|
| 697 |
|
|---|
| 698 | # BOOST_PROGRAM_OPTIONS([PREFERRED-RT-OPT])
|
|---|
| 699 | # -----------------------------------------
|
|---|
| 700 | # Look for Boost.Program_options. For the documentation of PREFERRED-RT-OPT,
|
|---|
| 701 | # see the documentation of BOOST_FIND_LIB above.
|
|---|
| 702 | BOOST_DEFUN([Program_Options],
|
|---|
| 703 | [BOOST_FIND_LIB([program_options], [$1],
|
|---|
| 704 | [boost/program_options.hpp],
|
|---|
| 705 | [boost::program_options::options_description d("test");])
|
|---|
| 706 | ])# BOOST_PROGRAM_OPTIONS
|
|---|
| 707 |
|
|---|
| 708 |
|
|---|
| 709 |
|
|---|
| 710 | # _BOOST_PYTHON_CONFIG(VARIABLE, FLAG)
|
|---|
| 711 | # ------------------------------------
|
|---|
| 712 | # Save VARIABLE, and define it via `python-config --FLAG`.
|
|---|
| 713 | # Substitute BOOST_PYTHON_VARIABLE.
|
|---|
| 714 | m4_define([_BOOST_PYTHON_CONFIG],
|
|---|
| 715 | [AC_SUBST([BOOST_PYTHON_$1],
|
|---|
| 716 | [`python-config --$2 2>/dev/null`])dnl
|
|---|
| 717 | boost_python_save_$1=$$1
|
|---|
| 718 | $1="$$1 $BOOST_PYTHON_$1"])
|
|---|
| 719 |
|
|---|
| 720 |
|
|---|
| 721 | # BOOST_PYTHON([PREFERRED-RT-OPT])
|
|---|
| 722 | # --------------------------------
|
|---|
| 723 | # Look for Boost.Python. For the documentation of PREFERRED-RT-OPT,
|
|---|
| 724 | # see the documentation of BOOST_FIND_LIB above.
|
|---|
| 725 | BOOST_DEFUN([Python],
|
|---|
| 726 | [_BOOST_PYTHON_CONFIG([CPPFLAGS], [includes])
|
|---|
| 727 | _BOOST_PYTHON_CONFIG([LDFLAGS], [ldflags])
|
|---|
| 728 | _BOOST_PYTHON_CONFIG([LIBS], [libs])
|
|---|
| 729 | m4_pattern_allow([^BOOST_PYTHON_MODULE$])dnl
|
|---|
| 730 | BOOST_FIND_LIB([python], [$1],
|
|---|
| 731 | [boost/python.hpp],
|
|---|
| 732 | [], [BOOST_PYTHON_MODULE(empty) {}])
|
|---|
| 733 | CPPFLAGS=$boost_python_save_CPPFLAGS
|
|---|
| 734 | LDFLAGS=$boost_python_save_LDFLAGS
|
|---|
| 735 | LIBS=$boost_python_save_LIBS
|
|---|
| 736 | ])# BOOST_PYTHON
|
|---|
| 737 |
|
|---|
| 738 |
|
|---|
| 739 | # BOOST_REF()
|
|---|
| 740 | # -----------
|
|---|
| 741 | # Look for Boost.Ref
|
|---|
| 742 | BOOST_DEFUN([Ref],
|
|---|
| 743 | [BOOST_FIND_HEADER([boost/ref.hpp])])
|
|---|
| 744 |
|
|---|
| 745 |
|
|---|
| 746 | # BOOST_REGEX([PREFERRED-RT-OPT])
|
|---|
| 747 | # -------------------------------
|
|---|
| 748 | # Look for Boost.Regex. For the documentation of PREFERRED-RT-OPT, see the
|
|---|
| 749 | # documentation of BOOST_FIND_LIB above.
|
|---|
| 750 | BOOST_DEFUN([Regex],
|
|---|
| 751 | [BOOST_FIND_LIB([regex], [$1],
|
|---|
| 752 | [boost/regex.hpp],
|
|---|
| 753 | [boost::regex exp("*"); boost::regex_match("foo", exp);])
|
|---|
| 754 | ])# BOOST_REGEX
|
|---|
| 755 |
|
|---|
| 756 |
|
|---|
| 757 | # BOOST_SERIALIZATION([PREFERRED-RT-OPT])
|
|---|
| 758 | # ---------------------------------------
|
|---|
| 759 | # Look for Boost.Serialization. For the documentation of PREFERRED-RT-OPT, see
|
|---|
| 760 | # the documentation of BOOST_FIND_LIB above.
|
|---|
| 761 | BOOST_DEFUN([Serialization],
|
|---|
| 762 | [BOOST_FIND_LIB([serialization], [$1],
|
|---|
| 763 | [boost/archive/text_oarchive.hpp],
|
|---|
| 764 | [std::ostream* o = 0; // Cheap way to get an ostream...
|
|---|
| 765 | boost::archive::text_oarchive t(*o);])
|
|---|
| 766 | ])# BOOST_SERIALIZATION
|
|---|
| 767 |
|
|---|
| 768 |
|
|---|
| 769 | # BOOST_SIGNALS([PREFERRED-RT-OPT])
|
|---|
| 770 | # ---------------------------------
|
|---|
| 771 | # Look for Boost.Signals. For the documentation of PREFERRED-RT-OPT, see the
|
|---|
| 772 | # documentation of BOOST_FIND_LIB above.
|
|---|
| 773 | BOOST_DEFUN([Signals],
|
|---|
| 774 | [BOOST_FIND_LIB([signals], [$1],
|
|---|
| 775 | [boost/signal.hpp],
|
|---|
| 776 | [boost::signal<void ()> s;])
|
|---|
| 777 | ])# BOOST_SIGNALS
|
|---|
| 778 |
|
|---|
| 779 |
|
|---|
| 780 | # BOOST_SMART_PTR()
|
|---|
| 781 | # -----------------
|
|---|
| 782 | # Look for Boost.SmartPtr
|
|---|
| 783 | BOOST_DEFUN([Smart_Ptr],
|
|---|
| 784 | [BOOST_FIND_HEADER([boost/scoped_ptr.hpp])
|
|---|
| 785 | BOOST_FIND_HEADER([boost/shared_ptr.hpp])
|
|---|
| 786 | ])
|
|---|
| 787 |
|
|---|
| 788 |
|
|---|
| 789 | # BOOST_STATICASSERT()
|
|---|
| 790 | # --------------------
|
|---|
| 791 | # Look for Boost.StaticAssert
|
|---|
| 792 | BOOST_DEFUN([StaticAssert],
|
|---|
| 793 | [BOOST_FIND_HEADER([boost/static_assert.hpp])])
|
|---|
| 794 |
|
|---|
| 795 |
|
|---|
| 796 | # BOOST_STRING_ALGO()
|
|---|
| 797 | # -------------------
|
|---|
| 798 | # Look for Boost.StringAlgo
|
|---|
| 799 | BOOST_DEFUN([String_Algo],
|
|---|
| 800 | [BOOST_FIND_HEADER([boost/algorithm/string.hpp])
|
|---|
| 801 | ])
|
|---|
| 802 |
|
|---|
| 803 |
|
|---|
| 804 | # BOOST_SYSTEM([PREFERRED-RT-OPT])
|
|---|
| 805 | # --------------------------------
|
|---|
| 806 | # Look for Boost.System. For the documentation of PREFERRED-RT-OPT, see the
|
|---|
| 807 | # documentation of BOOST_FIND_LIB above. This library was introduced in Boost
|
|---|
| 808 | # 1.35.0.
|
|---|
| 809 | BOOST_DEFUN([System],
|
|---|
| 810 | [BOOST_FIND_LIB([system], [$1],
|
|---|
| 811 | [boost/system/error_code.hpp],
|
|---|
| 812 | [boost::system::error_code e; e.clear();])
|
|---|
| 813 | ])# BOOST_SYSTEM
|
|---|
| 814 |
|
|---|
| 815 |
|
|---|
| 816 | # BOOST_TEST([PREFERRED-RT-OPT])
|
|---|
| 817 | # ------------------------------
|
|---|
| 818 | # Look for Boost.Test. For the documentation of PREFERRED-RT-OPT, see the
|
|---|
| 819 | # documentation of BOOST_FIND_LIB above.
|
|---|
| 820 | BOOST_DEFUN([Test],
|
|---|
| 821 | [m4_pattern_allow([^BOOST_CHECK$])dnl
|
|---|
| 822 | BOOST_FIND_LIB([unit_test_framework], [$1],
|
|---|
| 823 | [boost/test/unit_test.hpp], [BOOST_CHECK(2 == 2);],
|
|---|
| 824 | [using boost::unit_test::test_suite;
|
|---|
| 825 | test_suite* init_unit_test_suite(int argc, char ** argv)
|
|---|
| 826 | { return NULL; }])
|
|---|
| 827 | ])# BOOST_TEST
|
|---|
| 828 |
|
|---|
| 829 |
|
|---|
| 830 | # BOOST_THREADS([PREFERRED-RT-OPT])
|
|---|
| 831 | # ---------------------------------
|
|---|
| 832 | # Look for Boost.Thread. For the documentation of PREFERRED-RT-OPT, see the
|
|---|
| 833 | # documentation of BOOST_FIND_LIB above.
|
|---|
| 834 | # FIXME: Provide an alias "BOOST_THREAD".
|
|---|
| 835 | BOOST_DEFUN([Threads],
|
|---|
| 836 | [dnl Having the pthread flag is required at least on GCC3 where
|
|---|
| 837 | dnl boost/thread.hpp would complain if we try to compile without
|
|---|
| 838 | dnl -pthread on GNU/Linux.
|
|---|
| 839 | AC_REQUIRE([_BOOST_PTHREAD_FLAG])dnl
|
|---|
| 840 | boost_threads_save_LIBS=$LIBS
|
|---|
| 841 | boost_threads_save_CPPFLAGS=$CPPFLAGS
|
|---|
| 842 | LIBS="$LIBS $boost_cv_pthread_flag"
|
|---|
| 843 | # Yes, we *need* to put the -pthread thing in CPPFLAGS because with GCC3,
|
|---|
| 844 | # boost/thread.hpp will trigger a #error if -pthread isn't used:
|
|---|
| 845 | # boost/config/requires_threads.hpp:47:5: #error "Compiler threading support
|
|---|
| 846 | # is not turned on. Please set the correct command line options for
|
|---|
| 847 | # threading: -pthread (Linux), -pthreads (Solaris) or -mthreads (Mingw32)"
|
|---|
| 848 | CPPFLAGS="$CPPFLAGS $boost_cv_pthread_flag"
|
|---|
| 849 | BOOST_FIND_LIB([thread], [$1],
|
|---|
| 850 | [boost/thread.hpp], [boost::thread t; boost::mutex m;])
|
|---|
| 851 | BOOST_THREAD_LIBS="$BOOST_THREAD_LIBS $boost_cv_pthread_flag"
|
|---|
| 852 | BOOST_CPPFLAGS="$BOOST_CPPFLAGS $boost_cv_pthread_flag"
|
|---|
| 853 | LIBS=$boost_threads_save_LIBS
|
|---|
| 854 | CPPFLAGS=$boost_threads_save_CPPFLAGS
|
|---|
| 855 | ])# BOOST_THREADS
|
|---|
| 856 |
|
|---|
| 857 |
|
|---|
| 858 | # BOOST_TOKENIZER()
|
|---|
| 859 | # -----------------
|
|---|
| 860 | # Look for Boost.Tokenizer
|
|---|
| 861 | BOOST_DEFUN([Tokenizer],
|
|---|
| 862 | [BOOST_FIND_HEADER([boost/tokenizer.hpp])])
|
|---|
| 863 |
|
|---|
| 864 |
|
|---|
| 865 | # BOOST_TRIBOOL()
|
|---|
| 866 | # ---------------
|
|---|
| 867 | # Look for Boost.Tribool
|
|---|
| 868 | BOOST_DEFUN([Tribool],
|
|---|
| 869 | [BOOST_FIND_HEADER([boost/logic/tribool_fwd.hpp])
|
|---|
| 870 | BOOST_FIND_HEADER([boost/logic/tribool.hpp])
|
|---|
| 871 | ])
|
|---|
| 872 |
|
|---|
| 873 |
|
|---|
| 874 | # BOOST_TUPLE()
|
|---|
| 875 | # -------------
|
|---|
| 876 | # Look for Boost.Tuple
|
|---|
| 877 | BOOST_DEFUN([Tuple],
|
|---|
| 878 | [BOOST_FIND_HEADER([boost/tuple/tuple.hpp])])
|
|---|
| 879 |
|
|---|
| 880 |
|
|---|
| 881 | # BOOST_TYPETRAITS()
|
|---|
| 882 | # --------------------
|
|---|
| 883 | # Look for Boost.TypeTraits
|
|---|
| 884 | BOOST_DEFUN([TypeTraits],
|
|---|
| 885 | [BOOST_FIND_HEADER([boost/type_traits.hpp])])
|
|---|
| 886 |
|
|---|
| 887 |
|
|---|
| 888 | # BOOST_UTILITY()
|
|---|
| 889 | # ---------------
|
|---|
| 890 | # Look for Boost.Utility (noncopyable, result_of, base-from-member idiom,
|
|---|
| 891 | # etc.)
|
|---|
| 892 | BOOST_DEFUN([Utility],
|
|---|
| 893 | [BOOST_FIND_HEADER([boost/utility.hpp])])
|
|---|
| 894 |
|
|---|
| 895 |
|
|---|
| 896 | # BOOST_VARIANT()
|
|---|
| 897 | # ---------------
|
|---|
| 898 | # Look for Boost.Variant.
|
|---|
| 899 | BOOST_DEFUN([Variant],
|
|---|
| 900 | [BOOST_FIND_HEADER([boost/variant/variant_fwd.hpp])
|
|---|
| 901 | BOOST_FIND_HEADER([boost/variant.hpp])])
|
|---|
| 902 |
|
|---|
| 903 |
|
|---|
| 904 | # BOOST_WAVE([PREFERRED-RT-OPT])
|
|---|
| 905 | # ------------------------------
|
|---|
| 906 | # NOTE: If you intend to use Wave/Spirit with thread support, make sure you
|
|---|
| 907 | # call BOOST_THREADS first.
|
|---|
| 908 | # Look for Boost.Wave. For the documentation of PREFERRED-RT-OPT, see the
|
|---|
| 909 | # documentation of BOOST_FIND_LIB above.
|
|---|
| 910 | BOOST_DEFUN([Wave],
|
|---|
| 911 | [AC_REQUIRE([BOOST_FILESYSTEM])dnl
|
|---|
| 912 | AC_REQUIRE([BOOST_DATE_TIME])dnl
|
|---|
| 913 | boost_wave_save_LIBS=$LIBS
|
|---|
| 914 | boost_wave_save_LDFLAGS=$LDFLAGS
|
|---|
| 915 | m4_pattern_allow([^BOOST_((FILE)?SYSTEM|DATE_TIME|THREAD)_(LIBS|LDFLAGS)$])dnl
|
|---|
| 916 | LIBS="$LIBS $BOOST_SYSTEM_LIBS $BOOST_FILESYSTEM_LIBS $BOOST_DATE_TIME_LIBS\
|
|---|
| 917 | $BOOST_THREAD_LIBS"
|
|---|
| 918 | LDFLAGS="$LDFLAGS $BOOST_SYSTEM_LDFLAGS $BOOST_FILESYSTEM_LDFLAGS\
|
|---|
| 919 | $BOOST_DATE_TIME_LDFLAGS $BOOST_THREAD_LDFLAGS"
|
|---|
| 920 | BOOST_FIND_LIB([wave], [$1],
|
|---|
| 921 | [boost/wave.hpp],
|
|---|
| 922 | [boost::wave::token_id id; get_token_name(id);])
|
|---|
| 923 | LIBS=$boost_wave_save_LIBS
|
|---|
| 924 | LDFLAGS=$boost_wave_save_LDFLAGS
|
|---|
| 925 | ])# BOOST_WAVE
|
|---|
| 926 |
|
|---|
| 927 |
|
|---|
| 928 | # BOOST_XPRESSIVE()
|
|---|
| 929 | # -----------------
|
|---|
| 930 | # Look for Boost.Xpressive (new since 1.36.0).
|
|---|
| 931 | BOOST_DEFUN([Xpressive],
|
|---|
| 932 | [BOOST_FIND_HEADER([boost/xpressive/xpressive.hpp])])
|
|---|
| 933 |
|
|---|
| 934 |
|
|---|
| 935 | # ----------------- #
|
|---|
| 936 | # Internal helpers. #
|
|---|
| 937 | # ----------------- #
|
|---|
| 938 |
|
|---|
| 939 |
|
|---|
| 940 | # _BOOST_PTHREAD_FLAG()
|
|---|
| 941 | # ---------------------
|
|---|
| 942 | # Internal helper for BOOST_THREADS. Based on ACX_PTHREAD:
|
|---|
| 943 | # http://autoconf-archive.cryp.to/acx_pthread.html
|
|---|
| 944 | AC_DEFUN([_BOOST_PTHREAD_FLAG],
|
|---|
| 945 | [AC_REQUIRE([AC_PROG_CXX])dnl
|
|---|
| 946 | AC_REQUIRE([AC_CANONICAL_HOST])dnl
|
|---|
| 947 | AC_LANG_PUSH([C++])dnl
|
|---|
| 948 | AC_CACHE_CHECK([for the flags needed to use pthreads], [boost_cv_pthread_flag],
|
|---|
| 949 | [ boost_cv_pthread_flag=
|
|---|
| 950 | # The ordering *is* (sometimes) important. Some notes on the
|
|---|
| 951 | # individual items follow:
|
|---|
| 952 | # (none): in case threads are in libc; should be tried before -Kthread and
|
|---|
| 953 | # other compiler flags to prevent continual compiler warnings
|
|---|
| 954 | # -lpthreads: AIX (must check this before -lpthread)
|
|---|
| 955 | # -Kthread: Sequent (threads in libc, but -Kthread needed for pthread.h)
|
|---|
| 956 | # -kthread: FreeBSD kernel threads (preferred to -pthread since SMP-able)
|
|---|
| 957 | # -llthread: LinuxThreads port on FreeBSD (also preferred to -pthread)
|
|---|
| 958 | # -pthread: GNU Linux/GCC (kernel threads), BSD/GCC (userland threads)
|
|---|
| 959 | # -pthreads: Solaris/GCC
|
|---|
| 960 | # -mthreads: MinGW32/GCC, Lynx/GCC
|
|---|
| 961 | # -mt: Sun Workshop C (may only link SunOS threads [-lthread], but it
|
|---|
| 962 | # doesn't hurt to check since this sometimes defines pthreads too;
|
|---|
| 963 | # also defines -D_REENTRANT)
|
|---|
| 964 | # ... -mt is also the pthreads flag for HP/aCC
|
|---|
| 965 | # -lpthread: GNU Linux, etc.
|
|---|
| 966 | # --thread-safe: KAI C++
|
|---|
| 967 | case $host_os in #(
|
|---|
| 968 | *solaris*)
|
|---|
| 969 | # On Solaris (at least, for some versions), libc contains stubbed
|
|---|
| 970 | # (non-functional) versions of the pthreads routines, so link-based
|
|---|
| 971 | # tests will erroneously succeed. (We need to link with -pthreads/-mt/
|
|---|
| 972 | # -lpthread.) (The stubs are missing pthread_cleanup_push, or rather
|
|---|
| 973 | # a function called by this macro, so we could check for that, but
|
|---|
| 974 | # who knows whether they'll stub that too in a future libc.) So,
|
|---|
| 975 | # we'll just look for -pthreads and -lpthread first:
|
|---|
| 976 | boost_pthread_flags="-pthreads -lpthread -mt -pthread";; #(
|
|---|
| 977 | *)
|
|---|
| 978 | boost_pthread_flags="-lpthreads -Kthread -kthread -llthread -pthread \
|
|---|
| 979 | -pthreads -mthreads -lpthread --thread-safe -mt";;
|
|---|
| 980 | esac
|
|---|
| 981 | # Generate the test file.
|
|---|
| 982 | AC_LANG_CONFTEST([AC_LANG_PROGRAM([#include <pthread.h>],
|
|---|
| 983 | [pthread_t th; pthread_join(th, 0);
|
|---|
| 984 | pthread_attr_init(0); pthread_cleanup_push(0, 0);
|
|---|
| 985 | pthread_create(0,0,0,0); pthread_cleanup_pop(0);])])
|
|---|
| 986 | for boost_pthread_flag in '' $boost_pthread_flags; do
|
|---|
| 987 | boost_pthread_ok=false
|
|---|
| 988 | dnl Re-use the test file already generated.
|
|---|
| 989 | boost_pthreads__save_LIBS=$LIBS
|
|---|
| 990 | LIBS="$LIBS $boost_pthread_flag"
|
|---|
| 991 | AC_LINK_IFELSE([],
|
|---|
| 992 | [if grep ".*$boost_pthread_flag" conftest.err; then
|
|---|
| 993 | echo "This flag seems to have triggered warnings" >&AS_MESSAGE_LOG_FD
|
|---|
| 994 | else
|
|---|
| 995 | boost_pthread_ok=:; boost_cv_pthread_flag=$boost_pthread_flag
|
|---|
| 996 | fi])
|
|---|
| 997 | LIBS=$boost_pthreads__save_LIBS
|
|---|
| 998 | $boost_pthread_ok && break
|
|---|
| 999 | done
|
|---|
| 1000 | ])
|
|---|
| 1001 | AC_LANG_POP([C++])dnl
|
|---|
| 1002 | ])# _BOOST_PTHREAD_FLAG
|
|---|
| 1003 |
|
|---|
| 1004 |
|
|---|
| 1005 | # _BOOST_gcc_test(MAJOR, MINOR)
|
|---|
| 1006 | # -----------------------------
|
|---|
| 1007 | # Internal helper for _BOOST_FIND_COMPILER_TAG.
|
|---|
| 1008 | m4_define([_BOOST_gcc_test],
|
|---|
| 1009 | ["defined __GNUC__ && __GNUC__ == $1 && __GNUC_MINOR__ == $2 && !defined __ICC @ gcc$1$2"])dnl
|
|---|
| 1010 |
|
|---|
| 1011 |
|
|---|
| 1012 | # _BOOST_FIND_COMPILER_TAG()
|
|---|
| 1013 | # --------------------------
|
|---|
| 1014 | # Internal. When Boost is installed without --layout=system, each library
|
|---|
| 1015 | # filename will hold a suffix that encodes the compiler used during the
|
|---|
| 1016 | # build. The Boost build system seems to call this a `tag'.
|
|---|
| 1017 | AC_DEFUN([_BOOST_FIND_COMPILER_TAG],
|
|---|
| 1018 | [AC_REQUIRE([AC_PROG_CXX])dnl
|
|---|
| 1019 | AC_REQUIRE([AC_CANONICAL_HOST])dnl
|
|---|
| 1020 | AC_CACHE_CHECK([for the toolset name used by Boost for $CXX], [boost_cv_lib_tag],
|
|---|
| 1021 | [boost_cv_lib_tag=unknown
|
|---|
| 1022 | if test x$boost_cv_inc_path != xno; then
|
|---|
| 1023 | AC_LANG_PUSH([C++])dnl
|
|---|
| 1024 | # The following tests are mostly inspired by boost/config/auto_link.hpp
|
|---|
| 1025 | # The list is sorted to most recent/common to oldest compiler (in order
|
|---|
| 1026 | # to increase the likelihood of finding the right compiler with the
|
|---|
| 1027 | # least number of compilation attempt).
|
|---|
| 1028 | # Beware that some tests are sensible to the order (for instance, we must
|
|---|
| 1029 | # look for MinGW before looking for GCC3).
|
|---|
| 1030 | # I used one compilation test per compiler with a #error to recognize
|
|---|
| 1031 | # each compiler so that it works even when cross-compiling (let me know
|
|---|
| 1032 | # if you know a better approach).
|
|---|
| 1033 | # Known missing tags (known from Boost's tools/build/v2/tools/common.jam):
|
|---|
| 1034 | # como, edg, kcc, bck, mp, sw, tru, xlc
|
|---|
| 1035 | # I'm not sure about my test for `il' (be careful: Intel's ICC pre-defines
|
|---|
| 1036 | # the same defines as GCC's).
|
|---|
| 1037 | for i in \
|
|---|
| 1038 | _BOOST_gcc_test(4, 6) \
|
|---|
| 1039 | _BOOST_gcc_test(4, 5) \
|
|---|
| 1040 | _BOOST_gcc_test(4, 4) \
|
|---|
| 1041 | _BOOST_gcc_test(4, 3) \
|
|---|
| 1042 | _BOOST_gcc_test(4, 2) \
|
|---|
| 1043 | _BOOST_gcc_test(4, 1) \
|
|---|
| 1044 | _BOOST_gcc_test(4, 0) \
|
|---|
| 1045 | "defined __GNUC__ && __GNUC__ == 3 && !defined __ICC \
|
|---|
| 1046 | && (defined WIN32 || defined WINNT || defined _WIN32 || defined __WIN32 \
|
|---|
| 1047 | || defined __WIN32__ || defined __WINNT || defined __WINNT__) @ mgw" \
|
|---|
| 1048 | _BOOST_gcc_test(3, 4) \
|
|---|
| 1049 | _BOOST_gcc_test(3, 3) \
|
|---|
| 1050 | "defined _MSC_VER && _MSC_VER >= 1500 @ vc90" \
|
|---|
| 1051 | "defined _MSC_VER && _MSC_VER == 1400 @ vc80" \
|
|---|
| 1052 | _BOOST_gcc_test(3, 2) \
|
|---|
| 1053 | "defined _MSC_VER && _MSC_VER == 1310 @ vc71" \
|
|---|
| 1054 | _BOOST_gcc_test(3, 1) \
|
|---|
| 1055 | _BOOST_gcc_test(3, 0) \
|
|---|
| 1056 | "defined __BORLANDC__ @ bcb" \
|
|---|
| 1057 | "defined __ICC && (defined __unix || defined __unix__) @ il" \
|
|---|
| 1058 | "defined __ICL @ iw" \
|
|---|
| 1059 | "defined _MSC_VER && _MSC_VER == 1300 @ vc7" \
|
|---|
| 1060 | _BOOST_gcc_test(2, 95) \
|
|---|
| 1061 | "defined __MWERKS__ && __MWERKS__ <= 0x32FF @ cw9" \
|
|---|
| 1062 | "defined _MSC_VER && _MSC_VER < 1300 && !defined UNDER_CE @ vc6" \
|
|---|
| 1063 | "defined _MSC_VER && _MSC_VER < 1300 && defined UNDER_CE @ evc4" \
|
|---|
| 1064 | "defined __MWERKS__ && __MWERKS__ <= 0x31FF @ cw8"
|
|---|
| 1065 | do
|
|---|
| 1066 | boost_tag_test=`expr "X$i" : 'X\([[^@]]*\) @ '`
|
|---|
| 1067 | boost_tag=`expr "X$i" : 'X[[^@]]* @ \(.*\)'`
|
|---|
| 1068 | AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
|
|---|
| 1069 | #if $boost_tag_test
|
|---|
| 1070 | /* OK */
|
|---|
| 1071 | #else
|
|---|
| 1072 | # error $boost_tag_test
|
|---|
| 1073 | #endif
|
|---|
| 1074 | ]])], [boost_cv_lib_tag=$boost_tag; break], [])
|
|---|
| 1075 | done
|
|---|
| 1076 | AC_LANG_POP([C++])dnl
|
|---|
| 1077 | case $boost_cv_lib_tag in #(
|
|---|
| 1078 | # Some newer (>= 1.35?) versions of Boost seem to only use "gcc" as opposed
|
|---|
| 1079 | # to "gcc41" for instance.
|
|---|
| 1080 | *-gcc | *'-gcc ') :;; #( Don't re-add -gcc: it's already in there.
|
|---|
| 1081 | gcc*)
|
|---|
| 1082 | boost_tag_x=
|
|---|
| 1083 | case $host_os in #(
|
|---|
| 1084 | darwin*)
|
|---|
| 1085 | if test $boost_major_version -ge 136; then
|
|---|
| 1086 | # The `x' added in r46793 of Boost.
|
|---|
| 1087 | boost_tag_x=x
|
|---|
| 1088 | fi;;
|
|---|
| 1089 | esac
|
|---|
| 1090 | # We can specify multiple tags in this variable because it's used by
|
|---|
| 1091 | # BOOST_FIND_LIB that does a `for tag in -$boost_cv_lib_tag' ...
|
|---|
| 1092 | boost_cv_lib_tag="$boost_tag_x$boost_cv_lib_tag -${boost_tag_x}gcc"
|
|---|
| 1093 | ;; #(
|
|---|
| 1094 | unknown)
|
|---|
| 1095 | AC_MSG_WARN([[could not figure out which toolset name to use for $CXX]])
|
|---|
| 1096 | boost_cv_lib_tag=
|
|---|
| 1097 | ;;
|
|---|
| 1098 | esac
|
|---|
| 1099 | fi])dnl end of AC_CACHE_CHECK
|
|---|
| 1100 | ])# _BOOST_FIND_COMPILER_TAG
|
|---|
| 1101 |
|
|---|
| 1102 |
|
|---|
| 1103 | # _BOOST_GUESS_WHETHER_TO_USE_MT()
|
|---|
| 1104 | # --------------------------------
|
|---|
| 1105 | # Compile a small test to try to guess whether we should favor MT (Multi
|
|---|
| 1106 | # Thread) flavors of Boost. Sets boost_guess_use_mt accordingly.
|
|---|
| 1107 | AC_DEFUN([_BOOST_GUESS_WHETHER_TO_USE_MT],
|
|---|
| 1108 | [# Check whether we do better use `mt' even though we weren't ask to.
|
|---|
| 1109 | AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
|
|---|
| 1110 | #if defined _REENTRANT || defined _MT || defined __MT__
|
|---|
| 1111 | /* use -mt */
|
|---|
| 1112 | #else
|
|---|
| 1113 | # error MT not needed
|
|---|
| 1114 | #endif
|
|---|
| 1115 | ]])], [boost_guess_use_mt=:], [boost_guess_use_mt=false])
|
|---|
| 1116 | ])
|
|---|
| 1117 |
|
|---|
| 1118 | # _BOOST_AC_LINK_IFELSE(PROGRAM, [ACTION-IF-TRUE], [ACTION-IF-FALSE])
|
|---|
| 1119 | # -------------------------------------------------------------------
|
|---|
| 1120 | # Fork of _AC_LINK_IFELSE that preserves conftest.o across calls. Fragile,
|
|---|
| 1121 | # will break when Autoconf changes its internals. Requires that you manually
|
|---|
| 1122 | # rm -f conftest.$ac_objext in between to really different tests, otherwise
|
|---|
| 1123 | # you will try to link a conftest.o left behind by a previous test.
|
|---|
| 1124 | # Used to aggressively optimize BOOST_FIND_LIB (see the big comment in this
|
|---|
| 1125 | # macro).
|
|---|
| 1126 | #
|
|---|
| 1127 | # Don't use "break" in the actions, as it would short-circuit some code
|
|---|
| 1128 | # this macro runs after the actions.
|
|---|
| 1129 | m4_define([_BOOST_AC_LINK_IFELSE],
|
|---|
| 1130 | [m4_ifvaln([$1], [AC_LANG_CONFTEST([$1])])dnl
|
|---|
| 1131 | rm -f conftest$ac_exeext
|
|---|
| 1132 | boost_save_ac_ext=$ac_ext
|
|---|
| 1133 | boost_use_source=:
|
|---|
| 1134 | # If we already have a .o, re-use it. We change $ac_ext so that $ac_link
|
|---|
| 1135 | # tries to link the existing object file instead of compiling from source.
|
|---|
| 1136 | test -f conftest.$ac_objext && ac_ext=$ac_objext && boost_use_source=false &&
|
|---|
| 1137 | _AS_ECHO_LOG([re-using the existing conftest.$ac_objext])
|
|---|
| 1138 | AS_IF([_AC_DO_STDERR($ac_link) && {
|
|---|
| 1139 | test -z "$ac_[]_AC_LANG_ABBREV[]_werror_flag" ||
|
|---|
| 1140 | test ! -s conftest.err
|
|---|
| 1141 | } && test -s conftest$ac_exeext && {
|
|---|
| 1142 | test "$cross_compiling" = yes ||
|
|---|
| 1143 | $as_executable_p conftest$ac_exeext
|
|---|
| 1144 | dnl FIXME: use AS_TEST_X instead when 2.61 is widespread enough.
|
|---|
| 1145 | }],
|
|---|
| 1146 | [$2],
|
|---|
| 1147 | [if $boost_use_source; then
|
|---|
| 1148 | _AC_MSG_LOG_CONFTEST
|
|---|
| 1149 | fi
|
|---|
| 1150 | $3])
|
|---|
| 1151 | ac_objext=$boost_save_ac_objext
|
|---|
| 1152 | ac_ext=$boost_save_ac_ext
|
|---|
| 1153 | dnl Delete also the IPA/IPO (Inter Procedural Analysis/Optimization)
|
|---|
| 1154 | dnl information created by the PGI compiler (conftest_ipa8_conftest.oo),
|
|---|
| 1155 | dnl as it would interfere with the next link command.
|
|---|
| 1156 | rm -f core conftest.err conftest_ipa8_conftest.oo \
|
|---|
| 1157 | conftest$ac_exeext m4_ifval([$1], [conftest.$ac_ext])[]dnl
|
|---|
| 1158 | ])# _BOOST_AC_LINK_IFELSE
|
|---|
| 1159 |
|
|---|
| 1160 | # Local Variables:
|
|---|
| 1161 | # mode: autoconf
|
|---|
| 1162 | # End:
|
|---|
