Context Navigation

source: m4/boost.m4

Visit:

Candidate_v1.6.1

Last change on this file was 0bc2c6, checked in by Frederik Heber <frederik.heber@…>, 6 years ago
Added gcc 5.4.0 to boost.m4.
Property mode set to `100644`
File size: 56.3 KB

Line
1	# boost.m4: Locate Boost headers and libraries for autoconf-based projects.
2	# Copyright (C) 2007-2011, 2014 Benoit Sigoure <tsuna@lrde.epita.fr>
3	#
4	# This program is free software: you can redistribute it and/or modify
5	# it under the terms of the GNU General Public License as published by
6	# the Free Software Foundation, either version 3 of the License, or
7	# (at your option) any later version.
8	#
9	# Additional permission under section 7 of the GNU General Public
10	# License, version 3 ("GPLv3"):
11	#
12	# If you convey this file as part of a work that contains a
13	# configuration script generated by Autoconf, you may do so under
14	# terms of your choice.
15	#
16	# This program is distributed in the hope that it will be useful,
17	# but WITHOUT ANY WARRANTY; without even the implied warranty of
18	# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
19	# GNU General Public License for more details.
20	#
21	# You should have received a copy of the GNU General Public License
22	# along with this program. If not, see <http://www.gnu.org/licenses/>.
23
24	m4_define([_BOOST_SERIAL], [m4_translit([
25	# serial 26
26	], [#
27	], [])])
28
29	# Original sources can be found at http://github.com/tsuna/boost.m4
30	# You can fetch the latest version of the script by doing:
31	# wget http://github.com/tsuna/boost.m4/raw/master/build-aux/boost.m4
32
33	# ------ #
34	# README #
35	# ------ #
36
37	# This file provides several macros to use the various Boost libraries.
38	# The first macro is BOOST_REQUIRE. It will simply check if it's possible to
39	# find the Boost headers of a given (optional) minimum version and it will
40	# define BOOST_CPPFLAGS accordingly. It will add an option --with-boost to
41	# your configure so that users can specify non standard locations.
42	# If the user's environment contains BOOST_ROOT and --with-boost was not
43	# specified, --with-boost=$BOOST_ROOT is implicitly used.
44	# For more README and documentation, go to http://github.com/tsuna/boost.m4
45	# Note: THESE MACROS ASSUME THAT YOU USE LIBTOOL. If you don't, don't worry,
46	# simply read the README, it will show you what to do step by step.
47
48	m4_pattern_forbid([^_?(BOOST\|Boost)_])
49
50
51	# _BOOST_SED_CPP(SED-PROGRAM, PROGRAM,
52	# [ACTION-IF-FOUND], [ACTION-IF-NOT-FOUND])
53	# --------------------------------------------------------
54	# Same as AC_EGREP_CPP, but leave the result in conftest.i.
55	#
56	# SED-PROGRAM is not overquoted, as in AC_EGREP_CPP. It is expanded
57	# in double-quotes, so escape your double quotes.
58	#
59	# It could be useful to turn this into a macro which extracts the
60	# value of any macro.
61	m4_define([_BOOST_SED_CPP],
62	[AC_LANG_PUSH([C++])dnl
63	AC_LANG_PREPROC_REQUIRE()dnl
64	AC_REQUIRE([AC_PROG_SED])dnl
65	AC_LANG_CONFTEST([AC_LANG_SOURCE([[$2]])])
66	AS_IF([dnl eval is necessary to expand ac_cpp.
67	dnl Ultrix and Pyramid sh refuse to redirect output of eval, so use subshell.
68	dnl Beware of Windows end-of-lines, for instance if we are running
69	dnl some Windows programs under Wine. In that case, boost/version.hpp
70	dnl is certainly using "\r\n", but the regular Unix shell will only
71	dnl strip `\n' with backquotes, not the `\r'. This results in
72	dnl boost_cv_lib_version='1_37\r' for instance, which breaks
73	dnl everything else.
74	dnl Cannot use 'dnl' after [$4] because a trailing dnl may break AC_CACHE_CHECK
75	dnl
76	dnl Beware that GCC 5, when expanding macros, may embed # line directives
77	dnl a within single line:
78	dnl
79	dnl # 1 "conftest.cc"
80	dnl # 1 "<built-in>"
81	dnl # 1 "<command-line>"
82	dnl # 1 "conftest.cc"
83	dnl # 1 "/opt/local/include/boost/version.hpp" 1 3
84	dnl # 2 "conftest.cc" 2
85	dnl boost-lib-version =
86	dnl # 2 "conftest.cc" 3
87	dnl "1_56"
88	dnl
89	dnl So get rid of the # and empty lines, and glue the remaining ones together.
90	(eval "$ac_cpp conftest.$ac_ext") 2>&AS_MESSAGE_LOG_FD \|
91	grep -v '#' \|
92	grep -v '^[[[:space:]]]*$' \|
93	tr -d '\r' \|
94	tr -s '\n' ' ' \|
95	$SED -n -e "$1" >conftest.i 2>&1],
96	[$3],
97	[$4])
98	rm -rf conftest*
99	AC_LANG_POP([C++])dnl
100	])# _BOOST_SED_CPP
101
102
103
104	# BOOST_REQUIRE([VERSION], [ACTION-IF-NOT-FOUND])
105	# -----------------------------------------------
106	# Look for Boost. If version is given, it must either be a literal of the form
107	# "X.Y.Z" where X, Y and Z are integers (the ".Z" part being optional) or a
108	# variable "$var".
109	# Defines the value BOOST_CPPFLAGS. This macro only checks for headers with
110	# the required version, it does not check for any of the Boost libraries.
111	# On # success, defines HAVE_BOOST. On failure, calls the optional
112	# ACTION-IF-NOT-FOUND action if one was supplied.
113	# Otherwise aborts with an error message.
114	AC_DEFUN_ONCE([BOOST_REQUIRE],
115	[AC_REQUIRE([AC_PROG_CXX])dnl
116	AC_REQUIRE([AC_PROG_GREP])dnl
117	echo "$as_me: this is boost.m4[]_BOOST_SERIAL" >&AS_MESSAGE_LOG_FD
118	boost_save_IFS=$IFS
119	boost_version_req=$1
120	IFS=.
121	set x $boost_version_req 0 0 0
122	IFS=$boost_save_IFS
123	shift
124	boost_version_req=`expr "$[1]" '' 100000 + "$[2]" '' 100 + "$[3]"`
125	boost_version_req_string=$[1].$[2].$[3]
126	AC_ARG_WITH([boost],
127	[AS_HELP_STRING([--with-boost=DIR],
128	[prefix of Boost $1 @<:@guess@:>@])])dnl
129	AC_ARG_VAR([BOOST_ROOT],[Location of Boost installation])dnl
130	# If BOOST_ROOT is set and the user has not provided a value to
131	# --with-boost, then treat BOOST_ROOT as if it the user supplied it.
132	if test x"$BOOST_ROOT" != x; then
133	if test x"$with_boost" = x; then
134	AC_MSG_NOTICE([Detected BOOST_ROOT; continuing with --with-boost=$BOOST_ROOT])
135	with_boost=$BOOST_ROOT
136	else
137	AC_MSG_NOTICE([Detected BOOST_ROOT=$BOOST_ROOT, but overridden by --with-boost=$with_boost])
138	fi
139	fi
140	AC_SUBST([DISTCHECK_CONFIGURE_FLAGS],
141	["$DISTCHECK_CONFIGURE_FLAGS '--with-boost=$with_boost'"])dnl
142	boost_save_CPPFLAGS=$CPPFLAGS
143	AC_CACHE_CHECK([for Boost headers version >= $boost_version_req_string],
144	[boost_cv_inc_path],
145	[boost_cv_inc_path=no
146	AC_LANG_PUSH([C++])dnl
147	m4_pattern_allow([^BOOST_VERSION$])dnl
148	AC_LANG_CONFTEST([AC_LANG_PROGRAM([[#include <boost/version.hpp>
149	#if !defined BOOST_VERSION
150	# error BOOST_VERSION is not defined
151	#elif BOOST_VERSION < $boost_version_req
152	# error Boost headers version < $boost_version_req
153	#endif
154	]])])
155	# If the user provided a value to --with-boost, use it and only it.
156	case $with_boost in #(
157	''\|yes) set x '' /opt/local/include /usr/local/include /opt/include \
158	/usr/include C:/Boost/include;; #(
159	*) set x "$with_boost/include" "$with_boost";;
160	esac
161	shift
162	for boost_dir
163	do
164	# Without --layout=system, Boost (or at least some versions) installs
165	# itself in <prefix>/include/boost-<version>. This inner loop helps to
166	# find headers in such directories.
167	#
168	# Any ${boost_dir}/boost-x_xx directories are searched in reverse version
169	# order followed by ${boost_dir}. The final '.' is a sentinel for
170	# searching $boost_dir" itself. Entries are whitespace separated.
171	#
172	# I didn't indent this loop on purpose (to avoid over-indented code)
173	boost_layout_system_search_list=`cd "$boost_dir" 2>/dev/null \
174	&& ls -1 \| "${GREP}" '^boost-' \| sort -rn -t- -k2 \
175	&& echo .`
176	for boost_inc in $boost_layout_system_search_list
177	do
178	if test x"$boost_inc" != x.; then
179	boost_inc="$boost_dir/$boost_inc"
180	else
181	boost_inc="$boost_dir" # Uses sentinel in boost_layout_system_search_list
182	fi
183	if test x"$boost_inc" != x; then
184	# We are going to check whether the version of Boost installed
185	# in $boost_inc is usable by running a compilation that
186	# #includes it. But if we pass a -I/some/path in which Boost
187	# is not installed, the compiler will just skip this -I and
188	# use other locations (either from CPPFLAGS, or from its list
189	# of system include directories). As a result we would use
190	# header installed on the machine instead of the /some/path
191	# specified by the user. So in that precise case (trying
192	# $boost_inc), make sure the version.hpp exists.
193	#
194	# Use test -e as there can be symlinks.
195	test -e "$boost_inc/boost/version.hpp" \|\| continue
196	CPPFLAGS="$CPPFLAGS -I$boost_inc"
197	fi
198	AC_COMPILE_IFELSE([], [boost_cv_inc_path=yes], [boost_cv_version=no])
199	if test x"$boost_cv_inc_path" = xyes; then
200	if test x"$boost_inc" != x; then
201	boost_cv_inc_path=$boost_inc
202	fi
203	break 2
204	fi
205	done
206	done
207	AC_LANG_POP([C++])dnl
208	])
209	case $boost_cv_inc_path in #(
210	no)
211	boost_errmsg="cannot find Boost headers version >= $boost_version_req_string"
212	m4_if([$2], [], [AC_MSG_ERROR([$boost_errmsg])],
213	[AC_MSG_NOTICE([$boost_errmsg])])
214	$2
215	;;#(
216	yes)
217	BOOST_CPPFLAGS=
218	;;#(
219	*)
220	AC_SUBST([BOOST_CPPFLAGS], ["-I$boost_cv_inc_path"])dnl
221	;;
222	esac
223	if test x"$boost_cv_inc_path" != xno; then
224	AC_DEFINE([HAVE_BOOST], [1],
225	[Defined if the requested minimum BOOST version is satisfied])
226	AC_CACHE_CHECK([for Boost's header version],
227	[boost_cv_lib_version],
228	[m4_pattern_allow([^BOOST_LIB_VERSION$])dnl
229	_BOOST_SED_CPP([[/^boost-lib-version = /{s///;s/[\" ]//g;p;q;}]],
230	[#include <boost/version.hpp>
231	boost-lib-version = BOOST_LIB_VERSION],
232	[boost_cv_lib_version=`cat conftest.i`])])
233	# e.g. "134" for 1_34_1 or "135" for 1_35
234	boost_major_version=`echo "$boost_cv_lib_version" \| sed 's/_//;s/_.*//'`
235	case $boost_major_version in #(
236	'' \| [[!0-9]])
237	AC_MSG_ERROR([invalid value: boost_major_version='$boost_major_version'])
238	;;
239	esac
240	fi
241	CPPFLAGS=$boost_save_CPPFLAGS
242	])# BOOST_REQUIRE
243
244
245	# BOOST_STATIC()
246	# --------------
247	# Add the "--enable-static-boost" configure argument. If this argument is given
248	# on the command line, static versions of the libraries will be looked up.
249	AC_DEFUN([BOOST_STATIC],
250	[AC_ARG_ENABLE([static-boost],
251	[AS_HELP_STRING([--enable-static-boost],
252	[Prefer the static boost libraries over the shared ones [no]])],
253	[enable_static_boost=yes],
254	[enable_static_boost=no])])# BOOST_STATIC
255
256
257	# BOOST_FIND_HEADER([HEADER-NAME], [ACTION-IF-NOT-FOUND], [ACTION-IF-FOUND])
258	# --------------------------------------------------------------------------
259	# Wrapper around AC_CHECK_HEADER for Boost headers. Useful to check for
260	# some parts of the Boost library which are only made of headers and don't
261	# require linking (such as Boost.Foreach).
262	#
263	# Default ACTION-IF-NOT-FOUND: Fail with a fatal error unless Boost couldn't be
264	# found in the first place, in which case by default a notice is issued to the
265	# user. Presumably if we haven't died already it's because it's OK to not have
266	# Boost, which is why only a notice is issued instead of a hard error.
267	#
268	# Default ACTION-IF-FOUND: define the preprocessor symbol HAVE_<HEADER-NAME> in
269	# case of success # (where HEADER-NAME is written LIKE_THIS, e.g.,
270	# HAVE_BOOST_FOREACH_HPP).
271	AC_DEFUN([BOOST_FIND_HEADER],
272	[AC_REQUIRE([BOOST_REQUIRE])dnl
273	if test x"$boost_cv_inc_path" = xno; then
274	m4_default([$2], [AC_MSG_NOTICE([Boost not available, not searching for $1])])
275	else
276	AC_LANG_PUSH([C++])dnl
277	boost_save_CPPFLAGS=$CPPFLAGS
278	CPPFLAGS="$CPPFLAGS $BOOST_CPPFLAGS"
279	AC_CHECK_HEADER([$1],
280	[m4_default([$3], [AC_DEFINE(AS_TR_CPP([HAVE_$1]), [1],
281	[Define to 1 if you have <$1>])])],
282	[m4_default([$2], [AC_MSG_ERROR([cannot find $1])])])
283	CPPFLAGS=$boost_save_CPPFLAGS
284	AC_LANG_POP([C++])dnl
285	fi
286	])# BOOST_FIND_HEADER
287
288
289	# BOOST_FIND_LIBS([COMPONENT-NAME], [CANDIDATE-LIB-NAMES],
290	# [PREFERRED-RT-OPT], [HEADER-NAME], [CXX-TEST],
291	# [CXX-PROLOGUE])
292	# --------------------------------------------------------------
293	# Look for the Boost library COMPONENT-NAME (e.g., `thread', for
294	# libboost_thread) under the possible CANDIDATE-LIB-NAMES (e.g.,
295	# "thread_win32 thread"). Check that HEADER-NAME works and check that
296	# libboost_LIB-NAME can link with the code CXX-TEST. The optional
297	# argument CXX-PROLOGUE can be used to include some C++ code before
298	# the `main' function.
299	#
300	# Invokes BOOST_FIND_HEADER([HEADER-NAME]) (see above).
301	#
302	# Boost libraries typically come compiled with several flavors (with different
303	# runtime options) so PREFERRED-RT-OPT is the preferred suffix. A suffix is one
304	# or more of the following letters: sgdpn (in that order). s = static
305	# runtime, d = debug build, g = debug/diagnostic runtime, p = STLPort build,
306	# n = (unsure) STLPort build without iostreams from STLPort (it looks like `n'
307	# must always be used along with `p'). Additionally, PREFERRED-RT-OPT can
308	# start with `mt-' to indicate that there is a preference for multi-thread
309	# builds. Some sample values for PREFERRED-RT-OPT: (nothing), mt, d, mt-d, gdp
310	# ... If you want to make sure you have a specific version of Boost
311	# (eg, >= 1.33) you must invoke BOOST_REQUIRE before this macro.
312	AC_DEFUN([BOOST_FIND_LIBS],
313	[AC_REQUIRE([BOOST_REQUIRE])dnl
314	AC_REQUIRE([_BOOST_FIND_COMPILER_TAG])dnl
315	AC_REQUIRE([BOOST_STATIC])dnl
316	AC_REQUIRE([_BOOST_GUESS_WHETHER_TO_USE_MT])dnl
317	if test x"$boost_cv_inc_path" = xno; then
318	AC_MSG_NOTICE([Boost not available, not searching for the Boost $1 library])
319	else
320	dnl The else branch is huge and wasn't intended on purpose.
321	AC_LANG_PUSH([C++])dnl
322	AS_VAR_PUSHDEF([Boost_lib], [boost_cv_lib_$1])dnl
323	AS_VAR_PUSHDEF([Boost_lib_LDFLAGS], [boost_cv_lib_$1_LDFLAGS])dnl
324	AS_VAR_PUSHDEF([Boost_lib_LDPATH], [boost_cv_lib_$1_LDPATH])dnl
325	AS_VAR_PUSHDEF([Boost_lib_LIBS], [boost_cv_lib_$1_LIBS])dnl
326	BOOST_FIND_HEADER([$4])
327	boost_save_CPPFLAGS=$CPPFLAGS
328	CPPFLAGS="$CPPFLAGS $BOOST_CPPFLAGS"
329	AC_CACHE_CHECK([for the Boost $1 library], [Boost_lib],
330	[_BOOST_FIND_LIBS($@)])
331	case $Boost_lib in #(
332	(no) _AC_MSG_LOG_CONFTEST
333	AC_MSG_ERROR([cannot find the flags to link with Boost $1])
334	;;
335	esac
336	AC_SUBST(AS_TR_CPP([BOOST_$1_LDFLAGS]), [$Boost_lib_LDFLAGS])dnl
337	AC_SUBST(AS_TR_CPP([BOOST_$1_LDPATH]), [$Boost_lib_LDPATH])dnl
338	AC_SUBST([BOOST_LDPATH], [$Boost_lib_LDPATH])dnl
339	AC_SUBST(AS_TR_CPP([BOOST_$1_LIBS]), [$Boost_lib_LIBS])dnl
340	CPPFLAGS=$boost_save_CPPFLAGS
341	AS_VAR_POPDEF([Boost_lib])dnl
342	AS_VAR_POPDEF([Boost_lib_LDFLAGS])dnl
343	AS_VAR_POPDEF([Boost_lib_LDPATH])dnl
344	AS_VAR_POPDEF([Boost_lib_LIBS])dnl
345	AC_LANG_POP([C++])dnl
346	fi
347	])
348
349
350	# BOOST_FIND_LIB([LIB-NAME],
351	# [PREFERRED-RT-OPT], [HEADER-NAME], [CXX-TEST],
352	# [CXX-PROLOGUE])
353	# --------------------------------------------------------------
354	# Backward compatibility wrapper for BOOST_FIND_LIBS.
355	AC_DEFUN([BOOST_FIND_LIB],
356	[BOOST_FIND_LIBS([$1], $@)])
357
358
359	# _BOOST_FIND_LIBS([LIB-NAME], [CANDIDATE-LIB-NAMES],
360	# [PREFERRED-RT-OPT], [HEADER-NAME], [CXX-TEST],
361	# [CXX-PROLOGUE])
362	# --------------------------------------------------------------
363	# Real implementation of BOOST_FIND_LIBS: rely on these local macros:
364	# Boost_lib, Boost_lib_LDFLAGS, Boost_lib_LDPATH, Boost_lib_LIBS
365	#
366	# The algorithm is as follows: first look for a given library name
367	# according to the user's PREFERRED-RT-OPT. For each library name, we
368	# prefer to use the ones that carry the tag (toolset name). Each
369	# library is searched through the various standard paths were Boost is
370	# usually installed. If we can't find the standard variants, we try
371	# to enforce -mt (for instance on MacOSX, libboost_thread.dylib
372	# doesn't exist but there's -obviously- libboost_thread-mt.dylib).
373	AC_DEFUN([_BOOST_FIND_LIBS],
374	[Boost_lib=no
375	case "$3" in #(
376	(mt \| mt-) boost_mt=-mt; boost_rtopt=;; #(
377	(mt* \| mt-) boost_mt=-mt; boost_rtopt=`expr "X$3" : 'Xmt-\(.*\)'`;; #(
378	(*) boost_mt=; boost_rtopt=$3;;
379	esac
380	if test $enable_static_boost = yes; then
381	boost_rtopt="s$boost_rtopt"
382	fi
383	# Find the proper debug variant depending on what we've been asked to find.
384	case $boost_rtopt in #(
385	(d) boost_rt_d=$boost_rtopt;; #(
386	([[sgpn]]) # Insert the `d' at the right place (in between `sg' and `pn')
387	boost_rt_d=`echo "$boost_rtopt" \| sed 's/\(sg\)\(pn\)/\1\2/'`;; #(
388	(*) boost_rt_d='-d';;
389	esac
390	# If the PREFERRED-RT-OPT are not empty, prepend a `-'.
391	test -n "$boost_rtopt" && boost_rtopt="-$boost_rtopt"
392	$boost_guess_use_mt && boost_mt=-mt
393	# Look for the abs path the static archive.
394	# $libext is computed by Libtool but let's make sure it's non empty.
395	test -z "$libext" &&
396	AC_MSG_ERROR([the libext variable is empty, did you invoke Libtool?])
397	boost_save_ac_objext=$ac_objext
398	# Generate the test file.
399	AC_LANG_CONFTEST([AC_LANG_PROGRAM([#include <$4>
400	$6], [$5])])
401	dnl Optimization hacks: compiling C++ is slow, especially with Boost. What
402	dnl we're trying to do here is guess the right combination of link flags
403	dnl (LIBS / LDFLAGS) to use a given library. This can take several
404	dnl iterations before it succeeds and is thus very slow. So what we do
405	dnl instead is that we compile the code first (and thus get an object file,
406	dnl typically conftest.o). Then we try various combinations of link flags
407	dnl until we succeed to link conftest.o in an executable. The problem is
408	dnl that the various TRY_LINK / COMPILE_IFELSE macros of Autoconf always
409	dnl remove all the temporary files including conftest.o. So the trick here
410	dnl is to temporarily change the value of ac_objext so that conftest.o is
411	dnl preserved accross tests. This is obviously fragile and I will burn in
412	dnl hell for not respecting Autoconf's documented interfaces, but in the
413	dnl mean time, it optimizes the macro by a factor of 5 to 30.
414	dnl Another small optimization: the first argument of AC_COMPILE_IFELSE left
415	dnl empty because the test file is generated only once above (before we
416	dnl start the for loops).
417	AC_COMPILE_IFELSE([],
418	[ac_objext=do_not_rm_me_plz],
419	[AC_MSG_ERROR([cannot compile a test that uses Boost $1])])
420	ac_objext=$boost_save_ac_objext
421	boost_failed_libs=
422	# Don't bother to ident the following nested for loops, only the 2
423	# innermost ones matter.
424	for boost_lib_ in $2; do
425	for boost_tag_ in -$boost_cv_lib_tag ''; do
426	for boost_ver_ in -$boost_cv_lib_version ''; do
427	for boost_mt_ in $boost_mt -mt ''; do
428	for boost_rtopt_ in $boost_rtopt '' -d; do
429	for boost_lib in \
430	boost_$boost_lib_$boost_tag_$boost_mt_$boost_rtopt_$boost_ver_ \
431	boost_$boost_lib_$boost_tag_$boost_rtopt_$boost_ver_ \
432	boost_$boost_lib_$boost_tag_$boost_mt_$boost_ver_ \
433	boost_$boost_lib_$boost_tag_$boost_ver_
434	do
435	# Avoid testing twice the same lib
436	case $boost_failed_libs in #(
437	(@$boost_lib@) continue;;
438	esac
439	# If with_boost is empty, we'll search in /lib first, which is not quite
440	# right so instead we'll try to a location based on where the headers are.
441	boost_tmp_lib=$with_boost
442	test x"$with_boost" = x && boost_tmp_lib=${boost_cv_inc_path%/include}
443	for boost_ldpath in "$boost_tmp_lib/lib" '' \
444	/opt/local/lib* /usr/local/lib* /opt/lib* /usr/lib* \
445	"$with_boost" C:/Boost/lib /lib*
446	do
447	# Don't waste time with directories that don't exist.
448	if test x"$boost_ldpath" != x && test ! -e "$boost_ldpath"; then
449	continue
450	fi
451	boost_save_LDFLAGS=$LDFLAGS
452	# Are we looking for a static library?
453	case $boost_ldpath:$boost_rtopt_ in #(
454	(?:s) # Yes (Non empty boost_ldpath + s in rt opt)
455	Boost_lib_LIBS="$boost_ldpath/lib$boost_lib.$libext"
456	test -e "$Boost_lib_LIBS" \|\| continue;; #(
457	(*) # No: use -lboost_foo to find the shared library.
458	Boost_lib_LIBS="-l$boost_lib";;
459	esac
460	boost_save_LIBS=$LIBS
461	LIBS="$Boost_lib_LIBS $LIBS"
462	test x"$boost_ldpath" != x && LDFLAGS="$LDFLAGS -L$boost_ldpath"
463	dnl First argument of AC_LINK_IFELSE left empty because the test file is
464	dnl generated only once above (before we start the for loops).
465	_BOOST_AC_LINK_IFELSE([],
466	[Boost_lib=yes], [Boost_lib=no])
467	ac_objext=$boost_save_ac_objext
468	LDFLAGS=$boost_save_LDFLAGS
469	LIBS=$boost_save_LIBS
470	if test x"$Boost_lib" = xyes; then
471	# Check or used cached result of whether or not using -R or
472	# -rpath makes sense. Some implementations of ld, such as for
473	# Mac OSX, require -rpath but -R is the flag known to work on
474	# other systems. https://github.com/tsuna/boost.m4/issues/19
475	AC_CACHE_VAL([boost_cv_rpath_link_ldflag],
476	[case $boost_ldpath in
477	'') # Nothing to do.
478	boost_cv_rpath_link_ldflag=
479	boost_rpath_link_ldflag_found=yes;;
480	*)
481	for boost_cv_rpath_link_ldflag in -Wl,-R, -Wl,-rpath,; do
482	LDFLAGS="$boost_save_LDFLAGS -L$boost_ldpath $boost_cv_rpath_link_ldflag$boost_ldpath"
483	LIBS="$boost_save_LIBS $Boost_lib_LIBS"
484	_BOOST_AC_LINK_IFELSE([],
485	[boost_rpath_link_ldflag_found=yes
486	break],
487	[boost_rpath_link_ldflag_found=no])
488	done
489	;;
490	esac
491	AS_IF([test "x$boost_rpath_link_ldflag_found" != "xyes"],
492	[AC_MSG_ERROR([Unable to determine whether to use -R or -rpath])])
493	LDFLAGS=$boost_save_LDFLAGS
494	LIBS=$boost_save_LIBS
495	])
496	test x"$boost_ldpath" != x &&
497	Boost_lib_LDFLAGS="-L$boost_ldpath $boost_cv_rpath_link_ldflag$boost_ldpath"
498	Boost_lib_LDPATH="$boost_ldpath"
499	break 7
500	else
501	boost_failed_libs="$boost_failed_libs@$boost_lib@"
502	fi
503	done
504	done
505	done
506	done
507	done
508	done
509	done # boost_lib_
510	rm -f conftest.$ac_objext
511	])
512
513
514
515	# --------------------------------------- #
516	# Checks for the various Boost libraries. #
517	# --------------------------------------- #
518
519	# List of boost libraries: http://www.boost.org/libs/libraries.htm
520	# The page http://beta.boost.org/doc/libs is useful: it gives the first release
521	# version of each library (among other things).
522
523	# BOOST_DEFUN(LIBRARY, CODE)
524	# --------------------------
525	# Define BOOST_<LIBRARY-UPPERCASE> as a macro that runs CODE.
526	#
527	# Use indir to avoid the warning on underquoted macro name given to AC_DEFUN.
528	m4_define([BOOST_DEFUN],
529	[m4_indir([AC_DEFUN],
530	m4_toupper([BOOST_$1]),
531	[m4_pushdef([BOOST_Library], [$1])dnl
532	$2
533	m4_popdef([BOOST_Library])dnl
534	])
535	])
536
537
538	# BOOST_ANY()
539	# ------------
540	# Look for Boost.Any
541	BOOST_DEFUN([Any],
542	[BOOST_FIND_HEADER([boost/any.hpp])])
543
544
545	# BOOST_ARRAY()
546	# -------------
547	# Look for Boost.Array
548	BOOST_DEFUN([Array],
549	[BOOST_FIND_HEADER([boost/array.hpp])])
550
551
552	# BOOST_ASIO()
553	# ------------
554	# Look for Boost.Asio (new in Boost 1.35).
555	BOOST_DEFUN([Asio],
556	[AC_REQUIRE([BOOST_SYSTEM])dnl
557	BOOST_FIND_HEADER([boost/asio.hpp])])
558
559	# BOOST_BIMAP()
560	# ------------
561	# Look for Boost.Bimap
562	BOOST_DEFUN([Bimap],
563	[BOOST_FIND_HEADER([boost/bimap.hpp])])
564
565
566	# BOOST_ASSIGN()
567	# -------------
568	# Look for Boost.Assign
569	BOOST_DEFUN([Assign],
570	[BOOST_FIND_HEADER([boost/assign.hpp])])
571
572
573	# BOOST_BIND()
574	# ------------
575	# Look for Boost.Bind.
576	BOOST_DEFUN([Bind],
577	[BOOST_FIND_HEADER([boost/bind.hpp])])
578
579
580	# BOOST_CAST()
581	# ------------
582	# Look for Boost.Cast
583	BOOST_DEFUN([Cast],
584	[BOOST_FIND_HEADER([boost/cast.hpp])])
585
586
587	# BOOST_CHRONO()
588	# --------------
589	# Look for Boost.Chrono.
590	BOOST_DEFUN([Chrono],
591	[# Do we have to check for Boost.System? This link-time dependency was
592	# added as of 1.35.0. If we have a version <1.35, we must not attempt to
593	# find Boost.System as it didn't exist by then.
594	if test $boost_major_version -ge 135; then
595	BOOST_SYSTEM([$1])
596	fi # end of the Boost.System check.
597	boost_filesystem_save_LIBS=$LIBS
598	boost_filesystem_save_LDFLAGS=$LDFLAGS
599	m4_pattern_allow([^BOOST_SYSTEM_(LIBS\|LDFLAGS)$])dnl
600	LIBS="$LIBS $BOOST_SYSTEM_LIBS"
601	LDFLAGS="$LDFLAGS $BOOST_SYSTEM_LDFLAGS"
602	BOOST_FIND_LIB([chrono], [$1],
603	[boost/chrono.hpp],
604	[boost::chrono::thread_clock d;])
605	if test $enable_static_boost = yes && test $boost_major_version -ge 135; then
606	BOOST_CHRONO_LIBS="$BOOST_CHRONO_LIBS $BOOST_SYSTEM_LIBS"
607	fi
608	LIBS=$boost_filesystem_save_LIBS
609	LDFLAGS=$boost_filesystem_save_LDFLAGS
610	])# BOOST_CHRONO
611
612
613	# BOOST_CONTEXT([PREFERRED-RT-OPT])
614	# -----------------------------------
615	# Look for Boost.Context. For the documentation of PREFERRED-RT-OPT, see the
616	# documentation of BOOST_FIND_LIB above.
617	#
618	# * This library was introduced in Boost 1.51.0
619	# * The signatures of make_fcontext() and jump_fcontext were changed in 1.56.0
620	# * A dependency on boost_thread appears in 1.57.0
621	BOOST_DEFUN([Context],
622	[boost_context_save_LIBS=$LIBS
623	boost_context_save_LDFLAGS=$LDFLAGS
624	if test $boost_major_version -ge 157; then
625	BOOST_THREAD([$1])
626	m4_pattern_allow([^BOOST_THREAD_(LIBS\|LDFLAGS)$])dnl
627	LIBS="$LIBS $BOOST_THREAD_LIBS"
628	LDFLAGS="$LDFLAGS $BOOST_THREAD_LDFLAGS"
629	fi
630	BOOST_FIND_LIB([context], [$1],
631	[boost/context/all.hpp],[[
632
633	// creates a stack
634	void * stack_pointer = new void*[4096];
635	std::size_t const size = sizeof(void*[4096]);
636
637	#if BOOST_VERSION <= 105100
638	ctx::make_fcontext(&fc, f);
639	return ctx::jump_fcontext(&fcm, &fc, 3) == 6;
640
641	#else
642
643	fc = ctx::make_fcontext(stack_pointer, size, f);
644	return ctx::jump_fcontext(&fcm, fc, 3) == 6;
645
646	#endif
647
648
649	]],[dnl
650
651	#include <boost/version.hpp>
652	#if BOOST_VERSION <= 105100
653
654	namespace ctx = boost::ctx;
655
656	static ctx::fcontext_t fcm, fc;
657
658	static void f(intptr_t i) {
659	ctx::jump_fcontext(&fc, &fcm, i * 2);
660	}
661
662	#elif BOOST_VERSION <= 105500
663
664	namespace ctx = boost::context;
665
666	// context
667	static ctx::fcontext_t fcm, *fc;
668
669	// context-function
670	static void f(intptr_t i) {
671	ctx::jump_fcontext(fc, &fcm, i * 2);
672	}
673
674	#else
675
676	namespace ctx = boost::context;
677
678	// context
679	static ctx::fcontext_t fcm, fc;
680
681	// context-function
682	static void f(intptr_t i) {
683	ctx::jump_fcontext(&fc, fcm, i * 2);
684	}
685	#endif
686	])
687	LIBS=$boost_context_save_LIBS
688	LDFLAGS=$boost_context_save_LDFLAGS
689	])# BOOST_CONTEXT
690
691
692	# BOOST_CONVERSION()
693	# ------------------
694	# Look for Boost.Conversion (cast / lexical_cast)
695	BOOST_DEFUN([Conversion],
696	[BOOST_FIND_HEADER([boost/cast.hpp])
697	BOOST_FIND_HEADER([boost/lexical_cast.hpp])
698	])# BOOST_CONVERSION
699
700
701	# BOOST_COROUTINE([PREFERRED-RT-OPT])
702	# -----------------------------------
703	# Look for Boost.Coroutine. For the documentation of PREFERRED-RT-OPT, see the
704	# documentation of BOOST_FIND_LIB above. This library was introduced in Boost
705	# 1.53.0
706	BOOST_DEFUN([Coroutine],
707	[
708	boost_coroutine_save_LIBS=$LIBS
709	boost_coroutine_save_LDFLAGS=$LDFLAGS
710	# Link-time dependency from coroutine to context
711	BOOST_CONTEXT([$1])
712	# Starting from Boost 1.55 a dependency on Boost.System is added
713	if test $boost_major_version -ge 155; then
714	BOOST_SYSTEM([$1])
715	fi
716	m4_pattern_allow([^BOOST_(CONTEXT\|SYSTEM)_(LIBS\|LDFLAGS)])
717	LIBS="$LIBS $BOOST_CONTEXT_LIBS $BOOST_SYSTEM_LIBS"
718	LDFLAGS="$LDFLAGS $BOOST_CONTEXT_LDFLAGS"
719
720	# in 1.53 coroutine was a header only library
721	if test $boost_major_version -eq 153; then
722	BOOST_FIND_HEADER([boost/coroutine/coroutine.hpp])
723	else
724	BOOST_FIND_LIB([coroutine], [$1],
725	[boost/coroutine/coroutine.hpp],
726	[
727	#include <boost/version.hpp>
728	#if BOOST_VERSION <= 105500
729	boost::coroutines::coroutine<int(int)> coro; coro.get();
730	#else
731	boost::coroutines::asymmetric_coroutine<int>::pull_type coro; coro.get();
732	#endif
733	])
734	fi
735	# Link-time dependency from coroutine to context, existed only in 1.53, in 1.54
736	# coroutine doesn't use context from its headers but from its library.
737	if test $boost_major_version -eq 153 \|\| test $enable_static_boost = yes && test $boost_major_version -ge 154; then
738	BOOST_COROUTINE_LIBS="$BOOST_COROUTINE_LIBS $BOOST_CONTEXT_LIBS"
739	BOOST_COROUTINE_LDFLAGS="$BOOST_COROUTINE_LDFLAGS $BOOST_CONTEXT_LDFLAGS"
740	fi
741	if test $enable_static_boost = yes && test $boost_major_version -ge 155; then
742	BOOST_COROUTINE_LIBS="$BOOST_COROUTINE_LIBS $BOOST_SYSTEM_LIBS"
743	BOOST_COROUTINE_LDFLAGS="$BOOST_COROUTINE_LDFLAGS $BOOST_SYSTEM_LDFLAGS"
744	fi
745	LIBS=$boost_coroutine_save_LIBS
746	LDFLAGS=$boost_coroutine_save_LDFLAGS
747	])# BOOST_COROUTINE
748
749
750	# BOOST_CRC()
751	# -----------
752	# Look for Boost.CRC
753	BOOST_DEFUN([CRC],
754	[BOOST_FIND_HEADER([boost/crc.hpp])
755	])# BOOST_CRC
756
757
758	# BOOST_DATE_TIME([PREFERRED-RT-OPT])
759	# -----------------------------------
760	# Look for Boost.Date_Time. For the documentation of PREFERRED-RT-OPT, see the
761	# documentation of BOOST_FIND_LIB above.
762	BOOST_DEFUN([Date_Time],
763	[BOOST_FIND_LIB([date_time], [$1],
764	[boost/date_time/posix_time/posix_time.hpp],
765	[boost::posix_time::ptime t;])
766	])# BOOST_DATE_TIME
767
768
769	# BOOST_EXCEPTION()
770	# ------------
771	# Look for Boost.Exception
772	BOOST_DEFUN([Exception],
773	[BOOST_FIND_HEADER([boost/exception/all.hpp])])
774
775
776	# BOOST_FILESYSTEM([PREFERRED-RT-OPT])
777	# ------------------------------------
778	# Look for Boost.Filesystem. For the documentation of PREFERRED-RT-OPT, see
779	# the documentation of BOOST_FIND_LIB above.
780	# Do not check for boost/filesystem.hpp because this file was introduced in
781	# 1.34.
782	BOOST_DEFUN([Filesystem],
783	[# Do we have to check for Boost.System? This link-time dependency was
784	# added as of 1.35.0. If we have a version <1.35, we must not attempt to
785	# find Boost.System as it didn't exist by then.
786	if test $boost_major_version -ge 135; then
787	BOOST_SYSTEM([$1])
788	fi # end of the Boost.System check.
789	boost_filesystem_save_LIBS=$LIBS
790	boost_filesystem_save_LDFLAGS=$LDFLAGS
791	m4_pattern_allow([^BOOST_SYSTEM_(LIBS\|LDFLAGS)$])dnl
792	LIBS="$LIBS $BOOST_SYSTEM_LIBS"
793	LDFLAGS="$LDFLAGS $BOOST_SYSTEM_LDFLAGS"
794	BOOST_FIND_LIB([filesystem], [$1],
795	[boost/filesystem/path.hpp], [boost::filesystem::path p;])
796	if test $enable_static_boost = yes && test $boost_major_version -ge 135; then
797	BOOST_FILESYSTEM_LIBS="$BOOST_FILESYSTEM_LIBS $BOOST_SYSTEM_LIBS"
798	fi
799	LIBS=$boost_filesystem_save_LIBS
800	LDFLAGS=$boost_filesystem_save_LDFLAGS
801	])# BOOST_FILESYSTEM
802
803
804	# BOOST_FLYWEIGHT()
805	# -----------------
806	# Look for Boost.Flyweight.
807	BOOST_DEFUN([Flyweight],
808	[dnl There's a hidden dependency on pthreads.
809	AC_REQUIRE([_BOOST_PTHREAD_FLAG])dnl
810	BOOST_FIND_HEADER([boost/flyweight.hpp])
811	AC_SUBST([BOOST_FLYWEIGHT_LIBS], [$boost_cv_pthread_flag])
812	])
813
814
815	# BOOST_FOREACH()
816	# ---------------
817	# Look for Boost.Foreach.
818	BOOST_DEFUN([Foreach],
819	[BOOST_FIND_HEADER([boost/foreach.hpp])])
820
821
822	# BOOST_FORMAT()
823	# --------------
824	# Look for Boost.Format.
825	# Note: we can't check for boost/format/format_fwd.hpp because the header isn't
826	# standalone. It can't be compiled because it triggers the following error:
827	# boost/format/detail/config_macros.hpp:88: error: 'locale' in namespace 'std'
828	# does not name a type
829	BOOST_DEFUN([Format],
830	[BOOST_FIND_HEADER([boost/format.hpp])])
831
832
833	# BOOST_FUNCTION()
834	# ----------------
835	# Look for Boost.Function
836	BOOST_DEFUN([Function],
837	[BOOST_FIND_HEADER([boost/function.hpp])])
838
839
840	# BOOST_FUSION()
841	# -----------------
842	# Look for Boost.Fusion
843	BOOST_DEFUN([Fusion],
844	[BOOST_FIND_HEADER([boost/fusion/sequence.hpp])])
845
846
847	# BOOST_GEOMETRY()
848	# ----------------
849	# Look for Boost.Geometry (new since 1.47.0).
850	BOOST_DEFUN([Geometry],
851	[BOOST_FIND_HEADER([boost/geometry.hpp])
852	])# BOOST_GEOMETRY
853
854
855	# BOOST_GRAPH([PREFERRED-RT-OPT])
856	# -------------------------------
857	# Look for Boost.Graphs. For the documentation of PREFERRED-RT-OPT, see the
858	# documentation of BOOST_FIND_LIB above.
859	BOOST_DEFUN([Graph],
860	[boost_graph_save_LIBS=$LIBS
861	boost_graph_save_LDFLAGS=$LDFLAGS
862	# Link-time dependency from graph to regex was added as of 1.40.0.
863	if test $boost_major_version -ge 140; then
864	BOOST_REGEX([$1])
865	m4_pattern_allow([^BOOST_REGEX_(LIBS\|LDFLAGS)$])dnl
866	LIBS="$LIBS $BOOST_REGEX_LIBS"
867	LDFLAGS="$LDFLAGS $BOOST_REGEX_LDFLAGS"
868	fi
869	BOOST_FIND_LIB([graph], [$1],
870	[boost/graph/adjacency_list.hpp], [boost::adjacency_list<> g;])
871	LIBS=$boost_graph_save_LIBS
872	LDFLAGS=$boost_graph_save_LDFLAGS
873	])# BOOST_GRAPH
874
875
876	# BOOST_HASH()
877	# ------------
878	# Look for Boost.Functional/Hash
879	BOOST_DEFUN([Hash],
880	[BOOST_FIND_HEADER([boost/functional/hash.hpp])])
881
882
883	# BOOST_IOSTREAMS([PREFERRED-RT-OPT])
884	# -----------------------------------
885	# Look for Boost.IOStreams. For the documentation of PREFERRED-RT-OPT, see the
886	# documentation of BOOST_FIND_LIB above.
887	BOOST_DEFUN([IOStreams],
888	[BOOST_FIND_LIB([iostreams], [$1],
889	[boost/iostreams/device/file_descriptor.hpp],
890	[boost::iostreams::file_descriptor fd; fd.close();])
891	])# BOOST_IOSTREAMS
892
893
894	# BOOST_ITERATOR()
895	# ------------
896	# Look for Boost.Iterator
897	BOOST_DEFUN([Iterator],
898	[BOOST_FIND_HEADER([boost/iterator/iterator_adaptor.hpp])])
899
900
901	# BOOST_LAMBDA()
902	# --------------
903	# Look for Boost.Lambda
904	BOOST_DEFUN([Lambda],
905	[BOOST_FIND_HEADER([boost/lambda/lambda.hpp])])
906
907
908	# BOOST_LOCALE()
909	# --------------
910	# Look for Boost.Locale
911	BOOST_DEFUN([Locale],
912	[
913	boost_locale_save_LIBS=$LIBS
914	boost_locale_save_LDFLAGS=$LDFLAGS
915	# require SYSTEM for boost-1.50.0 and up
916	if test $boost_major_version -ge 150; then
917	BOOST_SYSTEM([$1])
918	m4_pattern_allow([^BOOST_SYSTEM_(LIBS\|LDFLAGS)$])dnl
919	LIBS="$LIBS $BOOST_SYSTEM_LIBS"
920	LDFLAGS="$LDFLAGS $BOOST_SYSTEM_LDFLAGS"
921	fi # end of the Boost.System check.
922	BOOST_FIND_LIB([locale], [$1],
923	[boost/locale.hpp],
924	[[boost::locale::generator gen; std::locale::global(gen(""));]])
925	LIBS=$boost_locale_save_LIBS
926	LDFLAGS=$boost_locale_save_LDFLAGS
927	])# BOOST_LOCALE
928
929	# BOOST_LOG([PREFERRED-RT-OPT])
930	# -----------------------------
931	# Look for Boost.Log. For the documentation of PREFERRED-RT-OPT, see the
932	# documentation of BOOST_FIND_LIB above.
933	BOOST_DEFUN([Log],
934	[boost_log_save_LIBS=$LIBS
935	boost_log_save_LDFLAGS=$LDFLAGS
936	BOOST_SYSTEM([$1])
937	BOOST_FILESYSTEM([$1])
938	BOOST_DATE_TIME([$1])
939	m4_pattern_allow([^BOOST_(SYSTEM\|FILESYSTEM\|DATE_TIME)_(LIBS\|LDFLAGS)$])dnl
940	LIBS="$LIBS $BOOST_DATE_TIME_LIBS $BOOST_FILESYSTEM_LIBS $BOOST_SYSTEM_LIBS"
941	LDFLAGS="$LDFLAGS $BOOST_DATE_TIME_LDFLAGS $BOOST_FILESYSTEM_LDFLAGS $BOOST_SYSTEM_LDFLAGS"
942	BOOST_FIND_LIB([log], [$1],
943	[boost/log/core/core.hpp],
944	[boost::log::attribute a; a.get_value();])
945	LIBS=$boost_log_save_LIBS
946	LDFLAGS=$boost_log_save_LDFLAGS
947	])# BOOST_LOG
948
949
950	# BOOST_LOG_SETUP([PREFERRED-RT-OPT])
951	# -----------------------------------
952	# Look for Boost.Log. For the documentation of PREFERRED-RT-OPT, see the
953	# documentation of BOOST_FIND_LIB above.
954	BOOST_DEFUN([Log_Setup],
955	[boost_log_setup_save_LIBS=$LIBS
956	boost_log_setup_save_LDFLAGS=$LDFLAGS
957	BOOST_LOG([$1])
958	m4_pattern_allow([^BOOST_LOG_(LIBS\|LDFLAGS)$])dnl
959	LIBS="$LIBS $BOOST_LOG_LIBS"
960	LDFLAGS="$LDFLAGS $BOOST_LOG_LDFLAGS"
961	BOOST_FIND_LIB([log_setup], [$1],
962	[boost/log/utility/setup/from_settings.hpp],
963	[boost::log::basic_settings<char> bs; bs.empty();])
964	LIBS=$boost_log_setup_save_LIBS
965	LDFLAGS=$boost_log_setup_save_LDFLAGS
966	])# BOOST_LOG_SETUP
967
968
969	# BOOST_MATH()
970	# ------------
971	# Look for Boost.Math
972	# TODO: This library isn't header-only but it comes in multiple different
973	# flavors that don't play well with BOOST_FIND_LIB (e.g, libboost_math_c99,
974	# libboost_math_c99f, libboost_math_c99l, libboost_math_tr1,
975	# libboost_math_tr1f, libboost_math_tr1l). This macro must be fixed to do the
976	# right thing anyway.
977	BOOST_DEFUN([Math],
978	[BOOST_FIND_HEADER([boost/math/special_functions.hpp])])
979
980
981	# BOOST_MPI([PREFERRED-RT-OPT])
982	# -------------------------------
983	# Look for Boost MPI. For the documentation of PREFERRED-RT-OPT, see the
984	# documentation of BOOST_FIND_LIB above. Uses MPICXX variable if it is
985	# set, otherwise tries CXX
986	#
987	BOOST_DEFUN([MPI],
988	[boost_save_CXX=${CXX}
989	boost_save_CXXCPP=${CXXCPP}
990	if test x"${MPICXX}" != x; then
991	CXX=${MPICXX}
992	CXXCPP="${MPICXX} -E"
993	fi
994	BOOST_FIND_LIB([mpi], [$1],
995	[boost/mpi.hpp],
996	[int argc = 0;
997	char **argv = 0;
998	boost::mpi::environment env(argc,argv);])
999	CXX=${boost_save_CXX}
1000	CXXCPP=${boost_save_CXXCPP}
1001	])# BOOST_MPI
1002
1003
1004	# BOOST_MPL()
1005	# ------------------
1006	# Look for Boost.MPL
1007	BOOST_DEFUN([MPL],
1008	[BOOST_FIND_HEADER([boost/mpl/for_each.hpp])])
1009
1010
1011	# BOOST_MULTIARRAY()
1012	# ------------------
1013	# Look for Boost.MultiArray
1014	BOOST_DEFUN([MultiArray],
1015	[BOOST_FIND_HEADER([boost/multi_array.hpp])])
1016
1017
1018	# BOOST_MULTIINDEXCCONTAINER()
1019	# ------------------
1020	# Look for Boost.MultiIndexContainer
1021	BOOST_DEFUN([MultiIndexContainer],
1022	[BOOST_FIND_HEADER([boost/multi_index_container.hpp])])
1023
1024
1025	# BOOST_NUMERIC_UBLAS()
1026	# --------------------------
1027	# Look for Boost.NumericUblas (Basic Linear Algebra)
1028	BOOST_DEFUN([Numeric_Ublas],
1029	[BOOST_FIND_HEADER([boost/numeric/ublas/vector.hpp])
1030	])# BOOST_NUMERIC_UBLAS
1031
1032
1033	# BOOST_NUMERIC_CONVERSION()
1034	# --------------------------
1035	# Look for Boost.NumericConversion (policy-based numeric conversion)
1036	BOOST_DEFUN([Numeric_Conversion],
1037	[BOOST_FIND_HEADER([boost/numeric/conversion/converter.hpp])
1038	])# BOOST_NUMERIC_CONVERSION
1039
1040
1041	# BOOST_OPTIONAL()
1042	# ----------------
1043	# Look for Boost.Optional
1044	BOOST_DEFUN([Optional],
1045	[BOOST_FIND_HEADER([boost/optional.hpp])])
1046
1047
1048	# BOOST_PREPROCESSOR()
1049	# --------------------
1050	# Look for Boost.Preprocessor
1051	BOOST_DEFUN([Preprocessor],
1052	[BOOST_FIND_HEADER([boost/preprocessor/repeat.hpp])])
1053
1054
1055	# BOOST_PROPERTY_TREE([PREFERRED-RT-OPT])
1056	# -----------------------------------------
1057	# Look for Boost.Property_Tree. For the documentation of PREFERRED-RT-OPT,
1058	# see the documentation of BOOST_FIND_LIB above.
1059	BOOST_DEFUN([Property_Tree],
1060	[BOOST_FIND_LIB([property_tree], [$1],
1061	[boost/property_tree/ptree.hpp],
1062	[boost::property_tree::ptree pt; boost::property_tree::read_xml d("test", pt);])
1063	])# BOOST_PROPERTY_TREE
1064
1065
1066	# BOOST_RANDOM()
1067	# --------------------
1068	# Look for Boost.Random
1069	BOOST_DEFUN([Random],
1070	[BOOST_FIND_HEADER([boost/random/random_number_generator.hpp])])
1071
1072
1073	# BOOST_RANGE()
1074	# --------------------
1075	# Look for Boost.Range
1076	BOOST_DEFUN([Range],
1077	[BOOST_FIND_HEADER([boost/range/adaptors.hpp])])
1078
1079	# BOOST_UNORDERED()
1080	# -----------------
1081	# Look for Boost.Unordered
1082	BOOST_DEFUN([Unordered],
1083	[BOOST_FIND_HEADER([boost/unordered_map.hpp])])
1084
1085
1086	# BOOST_UUID()
1087	# ------------
1088	# Look for Boost.Uuid
1089	BOOST_DEFUN([Uuid],
1090	[BOOST_FIND_HEADER([boost/uuid/uuid.hpp])])
1091
1092
1093	# BOOST_PROGRAM_OPTIONS([PREFERRED-RT-OPT])
1094	# -----------------------------------------
1095	# Look for Boost.Program_options. For the documentation of PREFERRED-RT-OPT,
1096	# see the documentation of BOOST_FIND_LIB above.
1097	BOOST_DEFUN([Program_Options],
1098	[BOOST_FIND_LIB([program_options], [$1],
1099	[boost/program_options.hpp],
1100	[boost::program_options::options_description d("test");])
1101	])# BOOST_PROGRAM_OPTIONS
1102
1103
1104
1105	# _BOOST_PYTHON_CONFIG(VARIABLE, FLAG)
1106	# ------------------------------------
1107	# Save VARIABLE, and define it via `python-config --FLAG`.
1108	# Substitute BOOST_PYTHON_VARIABLE.
1109	m4_define([_BOOST_PYTHON_CONFIG],
1110	[AC_SUBST([BOOST_PYTHON_$1],
1111	[`python-config --$2 2>/dev/null`])dnl
1112	boost_python_save_$1=$$1
1113	$1="$$1 $BOOST_PYTHON_$1"])
1114
1115
1116	# BOOST_PYTHON([PREFERRED-RT-OPT])
1117	# --------------------------------
1118	# Look for Boost.Python. For the documentation of PREFERRED-RT-OPT,
1119	# see the documentation of BOOST_FIND_LIB above.
1120	BOOST_DEFUN([Python],
1121	[_BOOST_PYTHON_CONFIG([CPPFLAGS], [includes])
1122	_BOOST_PYTHON_CONFIG([LDFLAGS], [ldflags])
1123	_BOOST_PYTHON_CONFIG([LIBS], [libs])
1124	m4_pattern_allow([^BOOST_PYTHON_MODULE$])dnl
1125	BOOST_FIND_LIBS([python], [python python3], [$1],
1126	[boost/python.hpp],
1127	[], [BOOST_PYTHON_MODULE(empty) {}])
1128	CPPFLAGS=$boost_python_save_CPPFLAGS
1129	LDFLAGS=$boost_python_save_LDFLAGS
1130	LIBS=$boost_python_save_LIBS
1131	])# BOOST_PYTHON
1132
1133
1134	# BOOST_REF()
1135	# -----------
1136	# Look for Boost.Ref
1137	BOOST_DEFUN([Ref],
1138	[BOOST_FIND_HEADER([boost/ref.hpp])])
1139
1140
1141	# BOOST_REGEX([PREFERRED-RT-OPT])
1142	# -------------------------------
1143	# Look for Boost.Regex. For the documentation of PREFERRED-RT-OPT, see the
1144	# documentation of BOOST_FIND_LIB above.
1145	BOOST_DEFUN([Regex],
1146	[BOOST_FIND_LIB([regex], [$1],
1147	[boost/regex.hpp],
1148	[boost::regex exp("*"); boost::regex_match("foo", exp);])
1149	])# BOOST_REGEX
1150
1151
1152	# BOOST_SERIALIZATION([PREFERRED-RT-OPT])
1153	# ---------------------------------------
1154	# Look for Boost.Serialization. For the documentation of PREFERRED-RT-OPT, see
1155	# the documentation of BOOST_FIND_LIB above.
1156	BOOST_DEFUN([Serialization],
1157	[BOOST_FIND_LIB([serialization], [$1],
1158	[boost/archive/text_oarchive.hpp],
1159	[std::ostream* o = 0; // Cheap way to get an ostream...
1160	boost::archive::text_oarchive t(*o);])
1161	])# BOOST_SERIALIZATION
1162
1163
1164	# BOOST_SIGNALS([PREFERRED-RT-OPT])
1165	# ---------------------------------
1166	# Look for Boost.Signals. For the documentation of PREFERRED-RT-OPT, see the
1167	# documentation of BOOST_FIND_LIB above.
1168	BOOST_DEFUN([Signals],
1169	[BOOST_FIND_LIB([signals], [$1],
1170	[boost/signal.hpp],
1171	[boost::signal<void ()> s;])
1172	])# BOOST_SIGNALS
1173
1174
1175	# BOOST_SIGNALS2()
1176	# ----------------
1177	# Look for Boost.Signals2 (new since 1.39.0).
1178	BOOST_DEFUN([Signals2],
1179	[BOOST_FIND_HEADER([boost/signals2.hpp])
1180	])# BOOST_SIGNALS2
1181
1182
1183	# BOOST_SMART_PTR()
1184	# -----------------
1185	# Look for Boost.SmartPtr
1186	BOOST_DEFUN([Smart_Ptr],
1187	[BOOST_FIND_HEADER([boost/scoped_ptr.hpp])
1188	BOOST_FIND_HEADER([boost/shared_ptr.hpp])
1189	])
1190
1191
1192	# BOOST_STATICASSERT()
1193	# --------------------
1194	# Look for Boost.StaticAssert
1195	BOOST_DEFUN([StaticAssert],
1196	[BOOST_FIND_HEADER([boost/static_assert.hpp])])
1197
1198
1199	# BOOST_STRING_ALGO()
1200	# -------------------
1201	# Look for Boost.StringAlgo
1202	BOOST_DEFUN([String_Algo],
1203	[BOOST_FIND_HEADER([boost/algorithm/string.hpp])
1204	])
1205
1206
1207	# BOOST_SYSTEM([PREFERRED-RT-OPT])
1208	# --------------------------------
1209	# Look for Boost.System. For the documentation of PREFERRED-RT-OPT, see the
1210	# documentation of BOOST_FIND_LIB above. This library was introduced in Boost
1211	# 1.35.0.
1212	BOOST_DEFUN([System],
1213	[BOOST_FIND_LIB([system], [$1],
1214	[boost/system/error_code.hpp],
1215	[boost::system::error_code e; e.clear();])
1216	])# BOOST_SYSTEM
1217
1218
1219	# BOOST_TEST([PREFERRED-RT-OPT])
1220	# ------------------------------
1221	# Look for Boost.Test. For the documentation of PREFERRED-RT-OPT, see the
1222	# documentation of BOOST_FIND_LIB above.
1223	BOOST_DEFUN([Test],
1224	[m4_pattern_allow([^BOOST_CHECK$])dnl
1225	BOOST_FIND_LIB([unit_test_framework], [$1],
1226	[boost/test/unit_test.hpp], [BOOST_CHECK(2 == 2);],
1227	[using boost::unit_test::test_suite;
1228	test_suite* init_unit_test_suite(int argc, char ** argv)
1229	{ return NULL; }])
1230	])# BOOST_TEST
1231
1232
1233	# BOOST_THREAD([PREFERRED-RT-OPT])
1234	# ---------------------------------
1235	# Look for Boost.Thread. For the documentation of PREFERRED-RT-OPT, see the
1236	# documentation of BOOST_FIND_LIB above.
1237	BOOST_DEFUN([Thread],
1238	[dnl Having the pthread flag is required at least on GCC3 where
1239	dnl boost/thread.hpp would complain if we try to compile without
1240	dnl -pthread on GNU/Linux.
1241	AC_REQUIRE([_BOOST_PTHREAD_FLAG])dnl
1242	boost_thread_save_LIBS=$LIBS
1243	boost_thread_save_LDFLAGS=$LDFLAGS
1244	boost_thread_save_CPPFLAGS=$CPPFLAGS
1245	# Link-time dependency from thread to system was added as of 1.49.0.
1246	if test $boost_major_version -ge 149; then
1247	BOOST_SYSTEM([$1])
1248	fi # end of the Boost.System check.
1249	m4_pattern_allow([^BOOST_SYSTEM_(LIBS\|LDFLAGS)$])dnl
1250	LIBS="$LIBS $BOOST_SYSTEM_LIBS $boost_cv_pthread_flag"
1251	LDFLAGS="$LDFLAGS $BOOST_SYSTEM_LDFLAGS"
1252	CPPFLAGS="$CPPFLAGS $boost_cv_pthread_flag"
1253
1254	# When compiling for the Windows platform, the threads library is named
1255	# differently. This suffix doesn't exist in new versions of Boost, or
1256	# possibly new versions of GCC on mingw I am assuming it's Boost's change for
1257	# now and I am setting version to 1.48, for lack of knowledge as to when this
1258	# change occurred.
1259	if test $boost_major_version -lt 148; then
1260	case $host_os in
1261	(mingw) boost_thread_lib_ext=_win32;;
1262	esac
1263	fi
1264	BOOST_FIND_LIBS([thread], [thread$boost_thread_lib_ext],
1265	[$1],
1266	[boost/thread.hpp], [boost::thread t; boost::mutex m;])
1267
1268	case $host_os in
1269	(mingw) boost_thread_w32_socket_link=-lws2_32;;
1270	esac
1271
1272	BOOST_THREAD_LIBS="$BOOST_THREAD_LIBS $BOOST_SYSTEM_LIBS $boost_cv_pthread_flag $boost_thread_w32_socket_link"
1273	BOOST_THREAD_LDFLAGS="$BOOST_SYSTEM_LDFLAGS"
1274	BOOST_CPPFLAGS="$BOOST_CPPFLAGS $boost_cv_pthread_flag"
1275	LIBS=$boost_thread_save_LIBS
1276	LDFLAGS=$boost_thread_save_LDFLAGS
1277	CPPFLAGS=$boost_thread_save_CPPFLAGS
1278	])# BOOST_THREAD
1279
1280	AU_ALIAS([BOOST_THREADS], [BOOST_THREAD])
1281
1282
1283	# BOOST_TOKENIZER()
1284	# -----------------
1285	# Look for Boost.Tokenizer
1286	BOOST_DEFUN([Tokenizer],
1287	[BOOST_FIND_HEADER([boost/tokenizer.hpp])])
1288
1289
1290	# BOOST_TRIBOOL()
1291	# ---------------
1292	# Look for Boost.Tribool
1293	BOOST_DEFUN([Tribool],
1294	[BOOST_FIND_HEADER([boost/logic/tribool_fwd.hpp])
1295	BOOST_FIND_HEADER([boost/logic/tribool.hpp])
1296	])
1297
1298
1299	# BOOST_TUPLE()
1300	# -------------
1301	# Look for Boost.Tuple
1302	BOOST_DEFUN([Tuple],
1303	[BOOST_FIND_HEADER([boost/tuple/tuple.hpp])])
1304
1305
1306	# BOOST_TYPETRAITS()
1307	# --------------------
1308	# Look for Boost.TypeTraits
1309	BOOST_DEFUN([TypeTraits],
1310	[BOOST_FIND_HEADER([boost/type_traits.hpp])])
1311
1312
1313	# BOOST_UTILITY()
1314	# ---------------
1315	# Look for Boost.Utility (noncopyable, result_of, base-from-member idiom,
1316	# etc.)
1317	BOOST_DEFUN([Utility],
1318	[BOOST_FIND_HEADER([boost/utility.hpp])])
1319
1320
1321	# BOOST_VARIANT()
1322	# ---------------
1323	# Look for Boost.Variant.
1324	BOOST_DEFUN([Variant],
1325	[BOOST_FIND_HEADER([boost/variant/variant_fwd.hpp])
1326	BOOST_FIND_HEADER([boost/variant.hpp])])
1327
1328
1329	# BOOST_POINTER_CONTAINER()
1330	# ------------------------
1331	# Look for Boost.PointerContainer
1332	BOOST_DEFUN([Pointer_Container],
1333	[BOOST_FIND_HEADER([boost/ptr_container/ptr_deque.hpp])
1334	BOOST_FIND_HEADER([boost/ptr_container/ptr_list.hpp])
1335	BOOST_FIND_HEADER([boost/ptr_container/ptr_vector.hpp])
1336	BOOST_FIND_HEADER([boost/ptr_container/ptr_array.hpp])
1337	BOOST_FIND_HEADER([boost/ptr_container/ptr_set.hpp])
1338	BOOST_FIND_HEADER([boost/ptr_container/ptr_map.hpp])
1339	])# BOOST_POINTER_CONTAINER
1340
1341
1342	# BOOST_WAVE([PREFERRED-RT-OPT])
1343	# ------------------------------
1344	# NOTE: If you intend to use Wave/Spirit with thread support, make sure you
1345	# call BOOST_THREAD first.
1346	# Look for Boost.Wave. For the documentation of PREFERRED-RT-OPT, see the
1347	# documentation of BOOST_FIND_LIB above.
1348	BOOST_DEFUN([Wave],
1349	[AC_REQUIRE([BOOST_FILESYSTEM])dnl
1350	AC_REQUIRE([BOOST_DATE_TIME])dnl
1351	boost_wave_save_LIBS=$LIBS
1352	boost_wave_save_LDFLAGS=$LDFLAGS
1353	m4_pattern_allow([^BOOST_((FILE)?SYSTEM\|DATE_TIME\|THREAD)_(LIBS\|LDFLAGS)$])dnl
1354	LIBS="$LIBS $BOOST_SYSTEM_LIBS $BOOST_FILESYSTEM_LIBS $BOOST_DATE_TIME_LIBS \
1355	$BOOST_THREAD_LIBS"
1356	LDFLAGS="$LDFLAGS $BOOST_SYSTEM_LDFLAGS $BOOST_FILESYSTEM_LDFLAGS \
1357	$BOOST_DATE_TIME_LDFLAGS $BOOST_THREAD_LDFLAGS"
1358	BOOST_FIND_LIB([wave], [$1],
1359	[boost/wave.hpp],
1360	[boost::wave::token_id id; get_token_name(id);])
1361	LIBS=$boost_wave_save_LIBS
1362	LDFLAGS=$boost_wave_save_LDFLAGS
1363	])# BOOST_WAVE
1364
1365
1366	# BOOST_XPRESSIVE()
1367	# -----------------
1368	# Look for Boost.Xpressive (new since 1.36.0).
1369	BOOST_DEFUN([Xpressive],
1370	[BOOST_FIND_HEADER([boost/xpressive/xpressive.hpp])])
1371
1372
1373	# ----------------- #
1374	# Internal helpers. #
1375	# ----------------- #
1376
1377
1378	# _BOOST_PTHREAD_FLAG()
1379	# ---------------------
1380	# Internal helper for BOOST_THREAD. Computes boost_cv_pthread_flag
1381	# which must be used in CPPFLAGS and LIBS.
1382	#
1383	# Yes, we need to put the -pthread thing in CPPFLAGS because with GCC3,
1384	# boost/thread.hpp will trigger a #error if -pthread isn't used:
1385	# boost/config/requires_threads.hpp:47:5: #error "Compiler threading support
1386	# is not turned on. Please set the correct command line options for
1387	# threading: -pthread (Linux), -pthreads (Solaris) or -mthreads (Mingw32)"
1388	#
1389	# Based on ACX_PTHREAD: http://autoconf-archive.cryp.to/acx_pthread.html
1390	AC_DEFUN([_BOOST_PTHREAD_FLAG],
1391	[AC_REQUIRE([AC_PROG_CXX])dnl
1392	AC_REQUIRE([AC_CANONICAL_HOST])dnl
1393	AC_LANG_PUSH([C++])dnl
1394	AC_CACHE_CHECK([for the flags needed to use pthreads], [boost_cv_pthread_flag],
1395	[ boost_cv_pthread_flag=
1396	# The ordering is (sometimes) important. Some notes on the
1397	# individual items follow:
1398	# (none): in case threads are in libc; should be tried before -Kthread and
1399	# other compiler flags to prevent continual compiler warnings
1400	# -lpthreads: AIX (must check this before -lpthread)
1401	# -Kthread: Sequent (threads in libc, but -Kthread needed for pthread.h)
1402	# -kthread: FreeBSD kernel threads (preferred to -pthread since SMP-able)
1403	# -llthread: LinuxThreads port on FreeBSD (also preferred to -pthread)
1404	# -pthread: GNU Linux/GCC (kernel threads), BSD/GCC (userland threads)
1405	# -pthreads: Solaris/GCC
1406	# -mthreads: MinGW32/GCC, Lynx/GCC
1407	# -mt: Sun Workshop C (may only link SunOS threads [-lthread], but it
1408	# doesn't hurt to check since this sometimes defines pthreads too;
1409	# also defines -D_REENTRANT)
1410	# ... -mt is also the pthreads flag for HP/aCC
1411	# -lpthread: GNU Linux, etc.
1412	# --thread-safe: KAI C++
1413	case $host_os in #(
1414	solaris)
1415	# On Solaris (at least, for some versions), libc contains stubbed
1416	# (non-functional) versions of the pthreads routines, so link-based
1417	# tests will erroneously succeed. (We need to link with -pthreads/-mt/
1418	# -lpthread.) (The stubs are missing pthread_cleanup_push, or rather
1419	# a function called by this macro, so we could check for that, but
1420	# who knows whether they'll stub that too in a future libc.) So,
1421	# we'll just look for -pthreads and -lpthread first:
1422	boost_pthread_flags="-pthreads -lpthread -mt -pthread";; #(
1423	*)
1424	boost_pthread_flags="-lpthreads -Kthread -kthread -llthread -pthread \
1425	-pthreads -mthreads -lpthread --thread-safe -mt";;
1426	esac
1427	# Generate the test file.
1428	AC_LANG_CONFTEST([AC_LANG_PROGRAM([#include <pthread.h>],
1429	[pthread_t th; pthread_join(th, 0);
1430	pthread_attr_init(0); pthread_cleanup_push(0, 0);
1431	pthread_create(0,0,0,0); pthread_cleanup_pop(0);])])
1432	for boost_pthread_flag in '' $boost_pthread_flags; do
1433	boost_pthread_ok=false
1434	dnl Re-use the test file already generated.
1435	boost_pthreads__save_LIBS=$LIBS
1436	LIBS="$LIBS $boost_pthread_flag"
1437	AC_LINK_IFELSE([],
1438	[if grep ".*$boost_pthread_flag" conftest.err; then
1439	echo "This flag seems to have triggered warnings" >&AS_MESSAGE_LOG_FD
1440	else
1441	boost_pthread_ok=:; boost_cv_pthread_flag=$boost_pthread_flag
1442	fi])
1443	LIBS=$boost_pthreads__save_LIBS
1444	$boost_pthread_ok && break
1445	done
1446	])
1447	AC_LANG_POP([C++])dnl
1448	])# _BOOST_PTHREAD_FLAG
1449
1450
1451	# _BOOST_gcc_test(MAJOR, MINOR)
1452	# -----------------------------
1453	# Internal helper for _BOOST_FIND_COMPILER_TAG.
1454	m4_define([_BOOST_gcc_test],
1455	["defined __GNUC__ && __GNUC__ == $1 && __GNUC_MINOR__ == $2 && !defined __ICC @ gcc$1$2"])dnl
1456
1457	# _BOOST_mingw_test(MAJOR, MINOR)
1458	# -----------------------------
1459	# Internal helper for _BOOST_FIND_COMPILER_TAG.
1460	m4_define([_BOOST_mingw_test],
1461	["defined __GNUC__ && __GNUC__ == $1 && __GNUC_MINOR__ == $2 && !defined __ICC && \
1462	(defined WIN32 \|\| defined WINNT \|\| defined _WIN32 \|\| defined __WIN32 \
1463	\|\| defined __WIN32__ \|\| defined __WINNT \|\| defined __WINNT__) @ mgw$1$2"])dnl
1464
1465
1466	# _BOOST_FIND_COMPILER_TAG()
1467	# --------------------------
1468	# Internal. When Boost is installed without --layout=system, each library
1469	# filename will hold a suffix that encodes the compiler used during the
1470	# build. The Boost build system seems to call this a `tag'.
1471	AC_DEFUN([_BOOST_FIND_COMPILER_TAG],
1472	[AC_REQUIRE([AC_PROG_CXX])dnl
1473	AC_REQUIRE([AC_CANONICAL_HOST])dnl
1474	AC_CACHE_CHECK([for the toolset name used by Boost for $CXX],
1475	[boost_cv_lib_tag],
1476	[boost_cv_lib_tag=unknown
1477	if test x$boost_cv_inc_path != xno; then
1478	AC_LANG_PUSH([C++])dnl
1479	# The following tests are mostly inspired by boost/config/auto_link.hpp
1480	# The list is sorted to most recent/common to oldest compiler (in order
1481	# to increase the likelihood of finding the right compiler with the
1482	# least number of compilation attempt).
1483	# Beware that some tests are sensible to the order (for instance, we must
1484	# look for MinGW before looking for GCC3).
1485	# I used one compilation test per compiler with a #error to recognize
1486	# each compiler so that it works even when cross-compiling (let me know
1487	# if you know a better approach).
1488	# Known missing tags (known from Boost's tools/build/v2/tools/common.jam):
1489	# como, edg, kcc, bck, mp, sw, tru, xlc
1490	# I'm not sure about my test for `il' (be careful: Intel's ICC pre-defines
1491	# the same defines as GCC's).
1492	for i in \
1493	_BOOST_mingw_test(6, 2) \
1494	_BOOST_gcc_test(6, 2) \
1495	_BOOST_mingw_test(6, 1) \
1496	_BOOST_gcc_test(6, 1) \
1497	_BOOST_mingw_test(6, 0) \
1498	_BOOST_gcc_test(6, 0) \
1499	_BOOST_mingw_test(5, 4) \
1500	_BOOST_gcc_test(5, 4) \
1501	_BOOST_mingw_test(5, 3) \
1502	_BOOST_gcc_test(5, 3) \
1503	_BOOST_mingw_test(5, 2) \
1504	_BOOST_gcc_test(5, 2) \
1505	_BOOST_mingw_test(5, 1) \
1506	_BOOST_gcc_test(5, 1) \
1507	_BOOST_mingw_test(5, 0) \
1508	_BOOST_gcc_test(5, 0) \
1509	_BOOST_mingw_test(4, 10) \
1510	_BOOST_gcc_test(4, 10) \
1511	_BOOST_mingw_test(4, 9) \
1512	_BOOST_gcc_test(4, 9) \
1513	_BOOST_mingw_test(4, 8) \
1514	_BOOST_gcc_test(4, 8) \
1515	_BOOST_mingw_test(4, 7) \
1516	_BOOST_gcc_test(4, 7) \
1517	_BOOST_mingw_test(4, 6) \
1518	_BOOST_gcc_test(4, 6) \
1519	_BOOST_mingw_test(4, 5) \
1520	_BOOST_gcc_test(4, 5) \
1521	_BOOST_mingw_test(4, 4) \
1522	_BOOST_gcc_test(4, 4) \
1523	_BOOST_mingw_test(4, 3) \
1524	_BOOST_gcc_test(4, 3) \
1525	_BOOST_mingw_test(4, 2) \
1526	_BOOST_gcc_test(4, 2) \
1527	_BOOST_mingw_test(4, 1) \
1528	_BOOST_gcc_test(4, 1) \
1529	_BOOST_mingw_test(4, 0) \
1530	_BOOST_gcc_test(4, 0) \
1531	"defined __GNUC__ && __GNUC__ == 3 && !defined __ICC \
1532	&& (defined WIN32 \|\| defined WINNT \|\| defined _WIN32 \|\| defined __WIN32 \
1533	\|\| defined __WIN32__ \|\| defined __WINNT \|\| defined __WINNT__) @ mgw" \
1534	_BOOST_gcc_test(3, 4) \
1535	_BOOST_gcc_test(3, 3) \
1536	"defined _MSC_VER && _MSC_VER >= 1500 @ vc90" \
1537	"defined _MSC_VER && _MSC_VER == 1400 @ vc80" \
1538	_BOOST_gcc_test(3, 2) \
1539	"defined _MSC_VER && _MSC_VER == 1310 @ vc71" \
1540	_BOOST_gcc_test(3, 1) \
1541	_BOOST_gcc_test(3, 0) \
1542	"defined __BORLANDC__ @ bcb" \
1543	"defined __ICC && (defined __unix \|\| defined __unix__) @ il" \
1544	"defined __ICL @ iw" \
1545	"defined _MSC_VER && _MSC_VER == 1300 @ vc7" \
1546	_BOOST_gcc_test(2, 95) \
1547	"defined __MWERKS__ && __MWERKS__ <= 0x32FF @ cw9" \
1548	"defined _MSC_VER && _MSC_VER < 1300 && !defined UNDER_CE @ vc6" \
1549	"defined _MSC_VER && _MSC_VER < 1300 && defined UNDER_CE @ evc4" \
1550	"defined __MWERKS__ && __MWERKS__ <= 0x31FF @ cw8"
1551	do
1552	boost_tag_test=`expr "X$i" : 'X\([[^@]]*\) @ '`
1553	boost_tag=`expr "X$i" : 'X[[^@]]* @ \(.*\)'`
1554	AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1555	#if $boost_tag_test
1556	/* OK */
1557	#else
1558	# error $boost_tag_test
1559	#endif
1560	]])], [boost_cv_lib_tag=$boost_tag; break], [])
1561	done
1562	AC_LANG_POP([C++])dnl
1563	case $boost_cv_lib_tag in #(
1564	# Some newer (>= 1.35?) versions of Boost seem to only use "gcc" as opposed
1565	# to "gcc41" for instance.
1566	-gcc \| '-gcc ') :;; #( Don't re-add -gcc: it's already in there.
1567	gcc*)
1568	boost_tag_x=
1569	case $host_os in #(
1570	darwin*)
1571	if test $boost_major_version -ge 136; then
1572	# The `x' added in r46793 of Boost.
1573	boost_tag_x=x
1574	fi;;
1575	esac
1576	# We can specify multiple tags in this variable because it's used by
1577	# BOOST_FIND_LIB that does a `for tag in -$boost_cv_lib_tag' ...
1578	boost_cv_lib_tag="$boost_tag_x$boost_cv_lib_tag -${boost_tag_x}gcc"
1579	;; #(
1580	unknown)
1581	AC_MSG_WARN([[could not figure out which toolset name to use for $CXX]])
1582	boost_cv_lib_tag=
1583	;;
1584	esac
1585	fi])dnl end of AC_CACHE_CHECK
1586	])# _BOOST_FIND_COMPILER_TAG
1587
1588
1589	# _BOOST_GUESS_WHETHER_TO_USE_MT()
1590	# --------------------------------
1591	# Compile a small test to try to guess whether we should favor MT (Multi
1592	# Thread) flavors of Boost. Sets boost_guess_use_mt accordingly.
1593	AC_DEFUN([_BOOST_GUESS_WHETHER_TO_USE_MT],
1594	[# Check whether we do better use `mt' even though we weren't ask to.
1595	AC_LANG_PUSH([C++])dnl
1596	AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1597	#if defined _REENTRANT \|\| defined _MT \|\| defined __MT__
1598	/* use -mt */
1599	#else
1600	# error MT not needed
1601	#endif
1602	]])], [boost_guess_use_mt=:], [boost_guess_use_mt=false])
1603	AC_LANG_POP([C++])dnl
1604	])
1605
1606	# _BOOST_AC_LINK_IFELSE(PROGRAM, [ACTION-IF-TRUE], [ACTION-IF-FALSE])
1607	# -------------------------------------------------------------------
1608	# Fork of _AC_LINK_IFELSE that preserves conftest.o across calls. Fragile,
1609	# will break when Autoconf changes its internals. Requires that you manually
1610	# rm -f conftest.$ac_objext in between to really different tests, otherwise
1611	# you will try to link a conftest.o left behind by a previous test.
1612	# Used to aggressively optimize BOOST_FIND_LIB (see the big comment in this
1613	# macro).
1614	#
1615	# Don't use "break" in the actions, as it would short-circuit some code
1616	# this macro runs after the actions.
1617	m4_define([_BOOST_AC_LINK_IFELSE],
1618	[m4_ifvaln([$1], [AC_LANG_CONFTEST([$1])])dnl
1619	rm -f conftest$ac_exeext
1620	boost_save_ac_ext=$ac_ext
1621	boost_use_source=:
1622	# If we already have a .o, re-use it. We change $ac_ext so that $ac_link
1623	# tries to link the existing object file instead of compiling from source.
1624	test -f conftest.$ac_objext && ac_ext=$ac_objext && boost_use_source=false &&
1625	_AS_ECHO_LOG([re-using the existing conftest.$ac_objext])
1626	AS_IF([_AC_DO_STDERR($ac_link) && {
1627	test -z "$ac_[]_AC_LANG_ABBREV[]_werror_flag" \|\|
1628	test ! -s conftest.err
1629	} && test -s conftest$ac_exeext && {
1630	test "$cross_compiling" = yes \|\|
1631	$as_executable_p conftest$ac_exeext
1632	dnl FIXME: use AS_TEST_X instead when 2.61 is widespread enough.
1633	}],
1634	[$2],
1635	[if $boost_use_source; then
1636	_AC_MSG_LOG_CONFTEST
1637	fi
1638	$3])
1639	ac_objext=$boost_save_ac_objext
1640	ac_ext=$boost_save_ac_ext
1641	dnl Delete also the IPA/IPO (Inter Procedural Analysis/Optimization)
1642	dnl information created by the PGI compiler (conftest_ipa8_conftest.oo),
1643	dnl as it would interfere with the next link command.
1644	rm -f core conftest.err conftest_ipa8_conftest.oo \
1645	conftest$ac_exeext m4_ifval([$1], [conftest.$ac_ext])[]dnl
1646	])# _BOOST_AC_LINK_IFELSE
1647
1648	# Local Variables:
1649	# mode: autoconf
1650	# End:

Note: See TracBrowser for help on using the repository browser.

Download in other formats: