Context Navigation

source: configure.ac@ b10593

Visit:

Action_Thermostats Adding_MD_integration_tests Adding_StructOpt_integration_tests AutomationFragmentation_failures Candidate_v1.6.1 ChemicalSpaceEvaluator Enhanced_StructuralOptimization Enhanced_StructuralOptimization_continued Exclude_Hydrogens_annealWithBondGraph Fix_Verbose_Codepatterns ForceAnnealing_with_BondGraph ForceAnnealing_with_BondGraph_continued ForceAnnealing_with_BondGraph_continued_betteresults ForceAnnealing_with_BondGraph_contraction-expansion Gui_displays_atomic_force_velocity JobMarket_RobustOnKillsSegFaults JobMarket_StableWorkerPool PythonUI_with_named_parameters Recreated_GuiChecks StoppableMakroAction TremoloParser_IncreasedPrecision

Last change on this file since b10593 was b10593, checked in by Frederik Heber <frederik.heber@…>, 7 years ago

Recreated all GuiChecks.

GuiChecks lacked difffragmentresultcontainer, refers to the one compiled in regression.

Property mode set to 100644

File size: 20.2 KB

Line
1	# -- Autoconf --
2	# Process this file with autoconf to produce a configure script.
3
4	AC_PREREQ(2.59)
5	AC_INIT(MoleCuilder, 1.6.0, [bug@molecuilder.de], [molecuilder], [http://www.molecuilder.de/])
6	AC_CONFIG_AUX_DIR([build-aux])
7	AC_CONFIG_SRCDIR([src/builder.cpp])
8	AC_CONFIG_HEADER([config.h libmolecuilder_config.h])
9	AC_CONFIG_MACRO_DIR([m4])
10	AC_CONFIG_SUBDIRS([ThirdParty/LinearAlgebra])
11	AC_CONFIG_SUBDIRS([ThirdParty/mpqc_open])
12
13	# parallel-tests: use parallel test druver
14	# color-tests: us coloring to indicate success/failure when available
15	# tar-pax: use newer tar implementation with longer filename (>99 chars)
16	AM_INIT_AUTOMAKE([dist-bzip2 1.5 parallel-tests color-tests tar-pax subdir-objects])
17
18	# Checks for programs.
19	AC_PROG_CXX
20	AC_PROG_INSTALL
21
22	# check for cppunit (taken from svn.apache.org/../xmlbeanscxx)
23	AM_PATH_CPPUNIT(1.9.6)
24	AM_CONDITIONAL(CONDCPPUNIT, test "$CPPUNIT_LIBS")
25
26	dnl Check if we have enable python
27	# python module-
28	AC_MSG_CHECKING(whether to enable python module)
29	AC_ARG_ENABLE(
30	[python],
31	AS_HELP_STRING([--enable-python],[turn on python module [default=yes]]),
32	enable_python=$enableval,
33	enable_python="yes")
34	AC_MSG_RESULT($enable_python)
35	AS_IF([test x"$enable_python" != x"no"],[
36	# Python (for boost::python)
37	AM_PATH_PYTHON([2.2])
38	AX_PYTHON
39	AC_DEFINE(HAVE_PYTHON,1, ["Build python module and scripts."])
40	])
41	AM_CONDITIONAL([CONDPYTHON], [test x"$enable_python" != x"no"])
42	AC_SUBST(HAVE_PYTHON)
43
44	dnl Check whether no extra thread for ActionQueue shall be used
45	AC_MSG_CHECKING(whether to enable ActionQueue's run thread)
46	AC_ARG_ENABLE(
47	[action_thread],
48	AS_HELP_STRING([--enable-action-thread],[turn on extra run thread for ActionQueue [default=yes]]),
49	enable_action_thread=$enableval,
50	enable_action_thread="no"
51	)
52	AC_MSG_RESULT($enable_action_thread)
53	AS_IF([test x"$enable_action_thread" != x"no"],[
54	AC_DEFINE(HAVE_ACTION_THREAD,1, ["Have extra run thread for ActionQueue."])
55	])
56	AM_CONDITIONAL([CONDACTIONTHREAD], [test x"$enable_action_thread" != x"no"])
57	AC_SUBST(HAVE_ACTION_THREAD)
58
59	dnl Check if we have enable qtgui
60	# Qt programs
61	AC_MSG_CHECKING(whether to enable Qt-based GUI)
62	AC_ARG_ENABLE(
63	[qtgui],
64	AS_HELP_STRING([--enable-qtgui],[turn on Qt GUI compilation [default=yes]]),
65	enable_qtgui=$enableval,
66	enable_qtgui="yes")
67	AC_MSG_RESULT($enable_qtgui)
68	AS_IF([test x"$enable_qtgui" != x"no"],[
69	AC_ARG_WITH(
70	[Qt-bin],
71	[AS_HELP_STRING([--with-Qt-bin], [give path to Qt binaries])],
72	[have_qtgui_path=$withval],
73	have_qtgui_path="")
74	AS_IF([test x"$have_qtgui_path" != x""],[
75	AC_PATH_PROGS([QT_MOC],
76	[moc-qt4 moc],
77	[AC_MSG_ERROR(["Qts moc not found, please use --with-Qt-bin."])],
78	[$have_qtgui_path]
79	)
80	AC_PATH_PROGS([QT_RCC],
81	[rcc-qt4 rcc],
82	[AC_MSG_ERROR(["Qts rcc not found, please use --with-Qt-bin."])],
83	[$have_qtgui_path]
84	)
85	AC_PATH_PROGS([QT_UIC],
86	[uic-qt4 uic],
87	[AC_MSG_ERROR(["Qts uic not found, please use --with-Qt-bin."])],
88	[$have_qtgui_path]
89	)
90	],[
91	AC_PATH_PROGS([QT_MOC],
92	[moc-qt4 moc],
93	[AC_MSG_ERROR(["Qts moc not found, please use --with-Qt-bin."])]
94	)
95	AC_PATH_PROGS([QT_RCC],
96	[rcc-qt4 rcc],
97	[AC_MSG_ERROR(["Qts rcc not found, please use --with-Qt-bin."])]
98	)
99	AC_PATH_PROGS([QT_UIC],
100	[uic-qt4 uic],
101	[AC_MSG_ERROR(["Qts uic not found, please use --with-Qt-bin."])]
102	)
103	])
104	PKG_CHECK_MODULES([QT], [QtCore QtGui Qt3D], [
105	])
106	AC_SUBST([QT_CFLAGS])
107	AC_SUBST([QT_LIBS])
108	AC_DEFINE(HAVE_QTGUI,1, ["Build Qt-based GUI"])
109	])
110	AM_CONDITIONAL([CONDQTGUI], [test x"$enable_qtgui" != x"no"])
111	AC_SUBST(HAVE_QTGUI)
112
113	dnl Check whether qtgui captures log or not
114	AC_MSG_CHECKING(whether to capture stdout in qtgui)
115	AC_ARG_ENABLE(
116	[qtgui_capture_log],
117	AS_HELP_STRING([--enable-qtgui-capture-log],[turn on capturing of log inside qtgui [default=yes]]),
118	enable_qtgui_capture_log=$enableval,
119	enable_qtgui_capture_log="yes"
120	)
121	AC_MSG_RESULT($enable_qtgui_capture_log)
122	AS_IF([test x"$enable_qtgui_capture_log" != x"no"],[
123	AC_DEFINE(QT_CAPTURES_LOG,1, ["Have QtGui capture the stdout."])
124	])
125	AC_SUBST(QT_CAPTURES_LOG)
126
127
128	# check additionally for QWT to enable plotting of potentials
129	AC_MSG_CHECKING(whether to enable Qwt-based plotting)
130	#enable_qwt=yes
131	AC_ARG_ENABLE(
132	[qwt],
133	AS_HELP_STRING([--enable-qwt],[turn on Qwt compilation [default=yes]]),
134	enable_qwt=$enableval,
135	enable_qwt="yes")
136	AC_MSG_RESULT($enable_qwt)
137	AS_IF([test x"$enable_qwt" != x"no"],[
138	MOL_AC_HAVE_QWT_IFELSE(
139	[
140	enable_qwt=yes
141	AC_DEFINE(HAVE_QWT,1, ["Build Qwt-based plotting"])
142	],
143	[
144	enable_qwt=no
145	AC_MSG_WARN([Qwt not found, disabling plotting in QtUI.])
146	]
147	)
148	])
149	AM_CONDITIONAL([CONDQWT], [test x"$enable_qwt" != x"no"])
150	AC_SUBST(HAVE_QWT)
151
152	# use doxygen
153	DX_HTML_FEATURE(ON)
154	DX_PS_FEATURE(OFF)
155	DX_PDF_FEATURE(OFF)
156	DX_INIT_DOXYGEN(MoleCuilder, Doxyfile, ${docdir})
157
158	# use docbook
159	AX_CHECK_DOCBOOK
160
161	# use libtool
162	LT_INIT([static])
163	AC_SUBST([LIBTOOL_DEPS])
164
165	# Define these substitions here to keep all version information in one place.
166	# For information on how to properly maintain the library version information,
167	# refer to the libtool manual, section "Updating library version information":
168	# http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
169	AC_SUBST([MOLECUILDER_SO_VERSION], [17:0:1])
170	AC_SUBST([MOLECUILDER_API_VERSION], [1.6.0])
171
172	dnl this macro is used to get the arguments supplied
173	dnl to the configure script (./configure --enable-debug)
174	dnl Check if we have enable debug support.
175	AC_MSG_CHECKING(whether to enable debugging)
176	have_debug="no"
177	AC_ARG_ENABLE(
178	[debug],
179	AS_HELP_STRING([--enable-debug],[turn on debugging [default=no]]),
180	enable_debug=$enableval,
181	enable_debug="no")
182	AC_MSG_RESULT($enable_debug)
183	AS_IF([test x"$enable_debug" = x"yes"],[
184	AC_DEFINE(MEMDEBUG,1, ["Use memory debugger."])
185	AC_DEFINE(HAVE_DEBUG,1, ["Use debug setting to compile code."])
186	have_debug="yes"
187	],[
188	AS_IF([test x"$enable_debug" = x"full"],[
189	AC_DEFINE(MEMDEBUG,1, ["Use memory debugger."])
190	AC_DEFINE(LOG_OBSERVER,1, ["Use observer log."])
191	AC_DEFINE(HAVE_DEBUG,2, ["Use debug setting to compile code."])
192	dnl AC_DEFINE(QT_DEBUG,, ["Enable Qt debug messages."])
193	have_debug="full"
194	],[
195	AC_DEFINE(NDEBUG,1, ["Don't compile in debugging code."])
196	AC_DEFINE(HAVE_DEBUG,0, ["Use debug setting to compile code."])
197	AC_DEFINE(QT_NO_DEBUG_OUTPUT,, ["Disable Qt debug messages."])
198	have_debug="no"
199	])
200	])
201	AC_SUBST(HAVE_DEBUG)
202
203	dnl this macro is used to get the arguments supplied
204	dnl to the configure script (./configure --enable-debug)
205	dnl Check if we have enable debug support.
206	AC_MSG_CHECKING(whether to enable internal caching/lazy evaluation)
207	AC_ARG_ENABLE(
208	[cache],
209	AS_HELP_STRING([--enable-cache],[turn on internal lazy evaluation [default=yes]]),
210	enable_cache=$enableval,
211	enable_cache="yes")
212	AC_MSG_RESULT($enable_cache)
213	AS_IF([test x"$enable_cache" != x"no"],[
214	AC_DEFINE(HAVE_CACHE,1, ["cache variables to speed up the code."])
215	],[
216	AC_DEFINE(NO_CACHING,1, ["Don't use caching code."])
217	AC_DEFINE(HAVE_CACHE,0, ["cache variables to speed up the code."])
218	])
219	AC_SUBST(HAVE_CACHE)
220
221	# Checks for libraries.
222	AC_CHECK_LIB(m, sqrt, , AC_MSG_ERROR([compatible libc math library not found]))
223
224	# Pthreads
225	ACX_PTHREAD()
226
227	# Boost
228	BOOST_REQUIRE([1.40])
229
230	# Boost headers only
231	BOOST_ANY
232	BOOST_ARRAY
233	BOOST_BIMAP
234	BOOST_BIND
235	BOOST_CAST
236	BOOST_CONVERSION
237	BOOST_EXCEPTION
238	BOOST_FOREACH
239	BOOST_FUNCTION
240	BOOST_FUSION
241	BOOST_GRAPH
242	BOOST_ITERATOR
243	BOOST_MULTIARRAY
244	BOOST_MULTIINDEXCONTAINER
245	BOOST_MPL
246	BOOST_PREPROCESSOR
247	BOOST_RANDOM
248	BOOST_SMART_PTR
249	BOOST_STRING_ALGO
250	BOOST_TOKENIZER
251
252	# Boost headers with libraries
253	BOOST_FILESYSTEM
254	BOOST_IOSTREAMS
255	BOOST_PROGRAM_OPTIONS
256	AS_IF([test x"$enable_python" != x"no"], [BOOST_PYTHON])
257	BOOST_SERIALIZATION
258	BOOST_THREADS
259
260
261	# CodePatterns library (requiring UnobservedIterator)
262	compile_codepatterns="no"
263	AM_PATH_CODEPATTERNS([1.3.2], $have_debug,,[
264	# compile from ThirdParty
265	AC_CONFIG_SUBDIRS([ThirdParty/CodePatterns])
266	compile_codepatterns="yes"
267	[CodePatterns_LDFLAGS='-L$(top_builddir)/ThirdParty/CodePatterns/src']
268	[CodePatterns_CFLAGS='-I$(top_srcdir)/ThirdParty/CodePatterns/src']
269	AS_IF([test x"$enable_debug" != x"no"], [
270	[CodePatterns_LIBS='-lcodepatterns-debug']
271	],[
272	[CodePatterns_LIBS='-lcodepatterns']
273	])
274	AC_SUBST(CodePatterns_LDFLAGS)
275	AC_SUBST(CodePatterns_CFLAGS)
276	AC_SUBST(CodePatterns_LIBS)
277	#AC_MSG_ERROR([Missing CodePatterns library, please specify PKG_CONFIG_PATH or use --with-codepatterns...])
278	])
279	AC_MSG_CHECKING(whether to compile codepatterns)
280	AC_MSG_RESULT($compile_codepatterns)
281	AM_CONDITIONAL([COND_COMPILE_CODEPATTERNS], [test x"$compile_codepatterns" = x"yes"])
282
283	# JobMarket library (needs boost/archive/iserializer.hpp before MemDebug.hpp)
284	AC_MSG_CHECKING(whether to enable jobmarket)
285	AC_ARG_ENABLE(
286	[jobmarket],
287	AS_HELP_STRING([--enable-jobmarket],[turn on JobMarket feature [default=yes]]),
288	enable_jobmarket=$enableval,
289	enable_jobmarket="yes")
290	AC_MSG_RESULT($enable_jobmarket)
291	compile_jobmarket="no"
292	AC_MSG_CHECKING(whether to compile jobmarket)
293	AS_IF([test x"$enable_jobmarket" != x"no"],[
294	# the following is only required if we use JobMarket
295	BOOST_ASIO
296	AC_DEFINE(HAVE_JOBMARKET,1, ["use JobMarket to calculate fragment jobs."])
297	# JobMarket library (needs SystemCommandJob with suffix)
298	AM_PATH_JOBMARKET([1.1.6], $have_debug,
299	,[
300	AC_CONFIG_SUBDIRS([ThirdParty/JobMarket])
301	compile_jobmarket="yes"
302	[JobMarket_CFLAGS='-I$(top_srcdir)/ThirdParty/JobMarket/src']
303	[JobMarket_LDFLAGS='-L$(top_builddir)/ThirdParty/JobMarket/src/JobMarket']
304	[JobMarket_LIBS='-lJobMarket']
305	[JobMarket_Controller_LIBS='-lJobMarketController']
306	[JobMarket_Server_LIBS='-lJobMarketServer']
307	[JobMarket_PoolWorker_LIBS='-lJobMarketPoolWorker']
308	AC_SUBST(JobMarket_CFLAGS)
309	AC_SUBST(JobMarket_LDFLAGS)
310	AC_SUBST(JobMarket_LIBS)
311	AC_SUBST(JobMarket_Controller_LIBS)
312	AC_SUBST(JobMarket_Server_LIBS)
313	AC_SUBST(JobMarket_PoolWorker_LIBS)
314	])
315	]
316	AC_MSG_RESULT($compile_jobmarket)
317	#[
318	# AC_DEFINE(HAVE_JOBMARKET,0, ["use JobMarket to calculate fragment jobs."])
319	#]
320	)
321	AC_SUBST(HAVE_JOBMARKET)
322	AM_CONDITIONAL([COND_COMPILE_JOBMARKET], [test x"$compile_jobmarket" = x"yes"])
323	AM_CONDITIONAL([CONDJOBMARKET], [test x"$enable_jobmarket" = x"yes"])
324
325	# VMG library
326	AC_MSG_CHECKING(whether to compile in long-range support via vmg)
327	AC_ARG_ENABLE(
328	[vmg],
329	[AS_HELP_STRING([--enable-vmg], [turn on long-range potential calculation via VMG [default=no]])],
330	[enable_vmg=$enableval],
331	enable_vmg="no")
332	AC_MSG_RESULT($enable_vmg)
333	compile_vmg="no"
334	AC_MSG_CHECKING(whether to compile vmg library)
335	AS_IF([test x"$enable_vmg" != x"no"],[
336	PKG_CHECK_MODULES(VMG, VMG >= 0.1, [enable_vmg="yes"], [enable_vmg="no"])
337	AS_IF([test x"$enable_vmg" = x"no"],[
338	AC_CONFIG_SUBDIRS([ThirdParty/vmg])
339	compile_vmg="yes"
340	enable_vmg="yes"
341	[VMG_CFLAGS='-I$(top_srcdir)/ThirdParty/vmg/src']
342	[VMG_LDFLAGS='-L$(top_builddir)/ThirdParty/vmg/src']
343	[VMG_LIBS='-lvmg']
344	])
345	AC_SUBST(VMG_CFLAGS)
346	AC_SUBST(VMG_LDFLAGS)
347	AC_SUBST(VMG_LIBS)
348	AC_DEFINE(HAVE_VMG,1, ["use VMG to calculate long-range contributions."])
349
350	# check whether to use mpi
351	AC_ARG_WITH(
352	[vmg-mpi],
353	[AS_HELP_STRING([--with-vmg-mpi], [whether to use MPI for communication in VMGJobs])],
354	[with_vmg_mpi=yes],
355	[with_vmg_mpi=no])
356	AS_IF(
357	[test "x$with_vmg_mpi" != xno],
358	[
359	AC_LANG_SAVE
360	AC_LANG_CPLUSPLUS
361	LX_FIND_MPI
362	AC_LANG_RESTORE
363	AS_IF([test "x$have_CXX_mpi" = xyes],[
364	AC_DEFINE([MPICH_SKIP_MPICXX], [1], [Skip C++ bindings])
365	AC_DEFINE([OMPI_SKIP_MPICXX], [1], [Skip C++ bindings])
366	AC_DEFINE([MPI_NO_CPPBIND], [1], [Skip C++ bindings])
367	AC_DEFINE([_MPICC_H], [1], [Skip C++ bindings])
368	AC_DEFINE([MPIBULL_SKIP_MPICXX], [1], [Skip C++ bindings])
369	#ac_configure_args="$ac_configure_args --with-mpi-thread=single --with-default-parallel=mpi --with-include=\"$MPI_CXXFLAGS\" --with-libs=\"$MPI_CXXLDFLAGS\""
370	ac_configure_args="$ac_configure_args --with-default-parallel=none"
371	])
372	],
373	[])
374	])
375	AC_MSG_RESULT($compile_vmg)
376	AM_CONDITIONAL([CONDVMG], [test x"$enable_vmg" = x"yes"])
377	AM_CONDITIONAL([CONDVMGMPI], [test x"$have_CXX_mpi" = x"yes"])
378	AM_CONDITIONAL([COND_COMPILE_VMG], [test x"$compile_vmg" = x"yes"])
379
380
381	# Check for Levenberg-Marquardt implementation
382	AC_MSG_CHECKING(whether to enable function fitting via levmar)
383	AC_ARG_ENABLE(
384	[levmar],
385	AS_HELP_STRING([--enable-levmar],[turn on LevMar feature [default=no]]),
386	enable_levmar=$enableval,
387	enable_levmar="no")
388	AC_MSG_RESULT($enable_levmar)
389	# don't use AS_IF here as it expands (and tests) AC_F77_FUN even if levmar
390	# is disabled.
391	compile_levmar="no"
392	AS_IF([test x"$enable_levmar" = xyes],[
393	AC_MSG_CHECKING(for levmar presence via given path )
394	AC_ARG_WITH(
395	[levmar],
396	[AS_HELP_STRING([--with-levmar], [give path to LevMar package])],
397	[have_levmar_path=$withval
398	enable_levmar=yes],
399	[
400	enable_levmar=no
401	])
402	AC_MSG_RESULT($enable_levmar)
403	AS_IF([test -n "$have_levmar_path"],[
404	LEVMAR_CPPFLAGS="-I${have_levmar_path}/include"
405	LEVMAR_LDFLAGS="-L${have_levmar_path}/lib"
406	LEVMAR_LIBS="-llevmar"],
407	[PKG_CHECK_MODULES([LEVMAR],[levmar],[enable_levmar=yes],[enable_levmar=no])
408	])
409	],[enable_levmar=no]
410	)
411	if test x"$enable_levmar" = xyes; then
412	AX_LAPACK([enable_levmar=yes],
413	[enable_levmar=no
414	AC_MSG_WARN(["Missing LAPACK, disabling off levmar"])
415	]
416	)
417	else
418	AC_CONFIG_SUBDIRS([ThirdParty/levmar])
419	compile_levmar="yes"
420	enable_levmar="yes"
421	LEVMAR_CPPFLAGS='-I$(top_srcdir)/ThirdParty/levmar/src'
422	LEVMAR_LDFLAGS='-L$(top_builddir)/ThirdParty/levmar/src'
423	LEVMAR_LIBS='-llevmar'
424	fi
425	AC_MSG_CHECKING(for levmar usability)
426	AS_IF([test x"$enable_levmar" = xyes],[
427	AC_SUBST(LEVMAR_CPPFLAGS)
428	AC_SUBST(LEVMAR_LDFLAGS)
429	AC_SUBST(LEVMAR_LIBS)
430	AC_DEFINE(HAVE_LEVMAR,1, ["use levmar for non-linear minimisation/potential fitting."])])
431	AC_MSG_RESULT($enable_levmar)
432	AM_CONDITIONAL([CONDLEVMAR], [test x"$enable_levmar" = x"yes"])
433	AM_CONDITIONAL([COND_COMPILE_LEVMAR], [test x"$compile_levmar" = x"yes"])
434
435	# Checks for header files.
436	AC_HEADER_STDC
437	AC_CHECK_HEADERS([sys/time.h])
438	AC_HEADER_STDBOOL
439
440	AC_FUNC_MALLOC
441	AC_FUNC_REALLOC
442	AC_CHECK_FUNCS([floor pow sqrt strchr])
443
444	# Checks for typedefs, structures, and compiler characteristics.
445	AC_C_CONST
446	AC_C_INLINE
447	AC_C_RESTRICT
448	AC_TYPE_SIZE_T
449
450	# Checks for library functions.
451	# check for GNU Scientific Library
452	AC_CHECK_HEADERS([gsl/gsl_blas.h])
453	AC_SEARCH_LIBS(dnrm2, gslblas gslcblas goto blas cblas)
454	AC_SEARCH_LIBS(cblas_dnrm2, gslblas gslcblas blas cblas)
455	AC_SEARCH_LIBS(gsl_blas_dnrm2,, gsl)
456	#AC_CHECK_LIB(gsl, gsl_blas_dnrm2, , [AC_MSG_ERROR(["No working BLAS found for GSL, stopping."])])
457	AC_CHECK_LIB(gsl, main)
458
459	# use CppUnit TestRunner or not
460	AC_MSG_CHECKING(whether to enable ECut TestRunnerClient)
461	AC_ARG_ENABLE(
462	[ecut],
463	AS_HELP_STRING([--enable-ecut],[Use ECut TestRunnerClient [default=no]]),
464	enable_ecut=$disableval,
465	enable_ecut="no")
466	AC_MSG_RESULT($enable_ecut)
467	AS_IF([test x"$enable_ecut" = x"yes"],[
468	AC_DEFINE(HAVE_ECUT,1, ["Use ECut TestRunnerClient instead of our own."])
469	AC_SUBST(HAVE_ECUT)
470	])
471	AM_CONDITIONAL([CONDECUT], [test x"$enable_ecut" = x"yes"])
472
473	# with valgrinding testsuite or not
474	AC_MSG_CHECKING(whether to enable valgrind memory checking in testsuite)
475	AC_ARG_ENABLE(
476	[valgrind],
477	AS_HELP_STRING([--enable-valgrind],[Use Valgrind on the testsuite [default=no]]),
478	enable_valgrind=$enableval,
479	enable_valgrind="no")
480	AC_MSG_RESULT($enable_valgrind)
481	AS_IF([test x"$enable_valgrind" = x"yes"], [
482	AC_CHECK_HEADER([valgrind/valgrind.h],
483	[
484	# check header
485	AC_DEFINE(HAVE_VALGRIND_TESTSUITE,1, ["Use Valgrind to check the testsuite."])
486	# check path
487	AC_PATH_PROG(VALGRIND, [valgrind], [/bin/false])
488	# set variables
489	AC_SUBST(HAVE_VALGRIND_TESTSUITE)
490	AC_SUBST(VALGRIND)
491	],
492	[
493	AC_MSG_ERROR(["Valgrind support requested but headers not available."])
494	]
495	)
496	])
497
498	# Check for "extern inline", using a modified version
499	# of the test for AC_C_INLINE from acspecific.mt
500	AC_CACHE_CHECK([for extern inline], ac_cv_c_extern_inline,
501	[ac_cv_c_extern_inline=no
502	AC_TRY_COMPILE([extern $ac_cv_c_inline double foo(double x);
503	extern $ac_cv_c_inline double foo(double x) { return x+1.0; };
504	double foo (double x) { return x + 1.0; };],
505	[ foo(1.0) ],
506	[ac_cv_c_extern_inline="yes"])
507	])
508
509	if test "$ac_cv_c_inline" != no ; then
510	AC_DEFINE(HAVE_INLINE,1, ["May use inline routines"])
511	AC_SUBST(HAVE_INLINE)
512	fi
513
514	#AC_MSG_NOTICE(["CFLAGS: $CFLAGS, CXXFLAGS: $CXXFLAGS, LDFLAGS: $LDFLAGS, CC: $CC, CXX:, $CXX, MPICC: $MPICC, MPILIBS: $MPILIBS, LIBS: $LIBS"])
515
516	# test suite
517
518	AC_CONFIG_FILES([
519	tests/Makefile])
520
521	AC_CONFIG_TESTDIR(tests/Calculations)
522	AC_CONFIG_FILES([
523	tests/Calculations/atlocal
524	tests/Calculations/Makefile])
525	AC_CONFIG_FILES([tests/Calculations/molecuilder], [chmod +x tests/Calculations/molecuilder])
526	AC_CONFIG_FILES([tests/Calculations/molecuilder_poolworker], [chmod +x tests/Calculations/molecuilder_poolworker])
527
528	AC_CONFIG_TESTDIR(tests/CodeChecks)
529	AC_CONFIG_FILES([
530	tests/CodeChecks/atlocal
531	tests/CodeChecks/Makefile])
532
533	AC_CONFIG_TESTDIR(tests/Fragmentations)
534	AC_CONFIG_FILES([
535	tests/Fragmentations/atlocal
536	tests/Fragmentations/Makefile])
537	AC_CONFIG_FILES([tests/Fragmentations/molecuilder], [chmod +x tests/Fragmentations/molecuilder])
538
539	AC_CONFIG_TESTDIR(tests/GuiChecks)
540	AC_CONFIG_FILES([
541	tests/GuiChecks/atlocal
542	tests/GuiChecks/Makefile])
543	AC_CONFIG_FILES([tests/GuiChecks/molecuilder], [chmod +x tests/GuiChecks/molecuilder])
544	AC_CONFIG_FILES([tests/GuiChecks/molecuilderguitest], [chmod +x tests/GuiChecks/molecuilderguitest])
545	AC_CONFIG_FILES([tests/GuiChecks/adjacencymatcher], [chmod +x tests/GuiChecks/adjacencymatcher])
546	AC_CONFIG_FILES([tests/GuiChecks/difffragmentresultcontainer], [chmod +x tests/GuiChecks/difffragmentresultcontainer])
547	AC_CONFIG_FILES([tests/GuiChecks/trianglematcher], [chmod +x tests/GuiChecks/trianglematcher])
548
549	AC_CONFIG_TESTDIR(tests/JobMarket)
550	AC_CONFIG_FILES([
551	tests/JobMarket/atlocal
552	tests/JobMarket/Makefile])
553	AC_CONFIG_FILES([tests/JobMarket/molecuilder], [chmod +x tests/JobMarket/molecuilder])
554
555	AC_CONFIG_TESTDIR(tests/integration)
556	AC_CONFIG_FILES([
557	tests/integration/atlocal
558	tests/integration/Makefile])
559	AC_CONFIG_FILES([tests/integration/molecuilder], [chmod +x tests/integration/molecuilder])
560	AC_CONFIG_FILES([tests/integration/molecuilder_poolworker], [chmod +x tests/integration/molecuilder_poolworker])
561
562	AC_CONFIG_TESTDIR(tests/regression)
563	AC_CONFIG_FILES([
564	tests/regression/atlocal
565	tests/regression/Makefile])
566	AC_CONFIG_FILES([tests/regression/molecuilder], [chmod +x tests/regression/molecuilder])
567	AC_CONFIG_FILES([tests/regression/adjacencymatcher], [chmod +x tests/regression/adjacencymatcher])
568	AC_CONFIG_FILES([tests/regression/difffragmentresultcontainer], [chmod +x tests/regression/difffragmentresultcontainer])
569	AC_CONFIG_FILES([tests/regression/trianglematcher], [chmod +x tests/regression/trianglematcher])
570	AC_CONFIG_FILES([tests/regression/runpython], [chmod +x tests/regression/runpython])
571
572	AC_CONFIG_TESTDIR(tests/Tesselations)
573	AC_CONFIG_FILES([
574	tests/Tesselations/atlocal
575	tests/Tesselations/Makefile])
576	AC_CONFIG_FILES([tests/Tesselations/molecuilder], [chmod +x tests/Tesselations/molecuilder])
577	AC_CONFIG_FILES([tests/Tesselations/trianglematcher], [chmod +x tests/Tesselations/trianglematcher])
578
579	AC_CONFIG_TESTDIR(tests/Examples)
580	AC_CONFIG_FILES([
581	tests/Examples/atlocal
582	tests/Examples/Makefile])
583	AC_CONFIG_FILES([tests/Examples/molecuilder], [chmod +x tests/Examples/molecuilder])
584	AC_CONFIG_FILES([tests/Examples/molecuilder_poolworker], [chmod +x tests/Examples/molecuilder_poolworker])
585
586	AC_CONFIG_FILES([
587	doc/molecuilder.xml])
588	AC_CONFIG_FILES([
589	doc/userguide/catalog.xml:doc/userguide/catalog.xml.in])
590	AC_CONFIG_FILES([
591	MoleCuilder.pc:MoleCuilder.pc.in])
592	AC_CONFIG_FILES([
593	doc/Makefile
594	doc/userguide/Makefile
595	])
596	AC_CONFIG_FILES([
597	Makefile
598	python/Makefile
599	src/Makefile
600	src/Bond/AdjacencyMatcher/Makefile
601	src/Tesselation/TriangleMatcher/Makefile
602	ThirdParty/Makefile
603	data/icons/Makefile
604	utils/Makefile
605	])
606	AC_CONFIG_FILES([
607	src/unittests/Makefile
608	])
609
610	# produce python scripts and tests only when python's present
611	AC_CONFIG_TESTDIR([tests/Python])
612	AC_CONFIG_FILES([tests/Python/atlocal])
613	AM_COND_IF([CONDPYTHON],[
614	AC_CONFIG_FILES([utils/Python/boxmaker.py:utils/Python/boxmaker.py.in], [chmod +x utils/Python/boxmaker.py])
615	AC_CONFIG_FILES([utils/Python/python_wrapper:utils/Python/python_wrapper.in], [chmod +x utils/Python/python_wrapper])
616	AC_CONFIG_FILES([tests/Python/run], [chmod +x tests/Python/run])
617	])
618	AC_CONFIG_FILES([tests/Python/Makefile])
619
620	AC_OUTPUT

Note: See TracBrowser for help on using the repository browser.

Download in other formats:

Original Format