source: LinearAlgebra/configure.ac@ abae35

#                                               -*- Autoconf -*-
# Process this file with autoconf to produce a configure script.

AC_PREREQ(2.59)
AC_INIT(LinearAlgebra, 1.0.3, [heber@ins.uni-bonn.de], [linearalgebra], [http://trac.ins.uni-bonn.de/projects/molecuilder/])
AC_CONFIG_AUX_DIR([build-aux])
AC_CONFIG_SRCDIR([src/LinearAlgebra/Vector.cpp])
AC_CONFIG_HEADER([config.h libLinearAlgebra_config.h])
AC_CONFIG_MACRO_DIR([m4])

# parallel-tests: use parallel test druver
# color-tests: us coloring to indicate success/failure when available
# tar-pax: use newer tar implementation with longer filename (>99 chars)
AM_INIT_AUTOMAKE([dist-bzip2 1.11 parallel-tests color-tests tar-pax])

# Checks for programs.
AM_PATH_CPPUNIT(1.9.6)
AC_PROG_CXX
AC_PROG_CC
AC_PROG_INSTALL

DX_HTML_FEATURE(ON)
DX_PS_FEATURE(OFF)
DX_PDF_FEATURE(OFF)
DX_INIT_DOXYGEN(LinearAlgebra, Doxyfile, ${docdir})

LT_INIT([static])

# Define these substitions here to keep all version information in one place.
# For information on how to properly maintain the library version information,
# refer to the libtool manual, section "Updating library version information":
# http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
AC_SUBST([LINEARALGEBRA_SO_VERSION], [3:0:0])
AC_SUBST([LINEARALGEBRA_API_VERSION], [1.0.3])

dnl this macro is used to get the arguments supplied
dnl to the configure script (./configure --enable-debug)
dnl Check if we have enable debug support.
AC_MSG_CHECKING(whether to enable debugging)
AC_ARG_ENABLE(debug, [  --enable-debug=[no/yes/full] turn on debugging
                     [default=yes]],, enable_debug=$enableval)
AC_MSG_RESULT($enable_debug)
if test "x$enable_debug" = "xyes"; then
  AC_DEFINE(MEMDEBUG,1, ["Use memory debugger."])
  AC_DEFINE(HAVE_DEBUG,1, ["Use debug setting to compile code."])
elif test "x$enable_debug" = "xfull"; then
  AC_DEFINE(MEMDEBUG,1, ["Use memory debugger."])
  AC_DEFINE(LOG_OBSERVER,1, ["Use observer log."])
  AC_DEFINE(HAVE_DEBUG,2, ["Use debug setting to compile code."])
else
  AC_DEFINE(NDEBUG,1, ["Don't compile in debugging code."])
  AC_DEFINE(HAVE_DEBUG,0, ["Use debug setting to compile code."])
fi
AC_SUBST(HAVE_DEBUG)

dnl this macro is used to get the arguments supplied
dnl to the configure script (./configure --enable-debug)
dnl Check if we have enable debug support.
AC_MSG_CHECKING([whether to enable internal caching of values (speedup!)])
AC_ARG_ENABLE(cache, [  --enable-cache=[no/yes] turn on caching
                     [default=yes]],, enable_cache=$enableval)
AC_MSG_RESULT($enable_cache)
if test "x$enable_cache" = "xno"; then
  AC_DEFINE(NO_CACHING,1, ["Don't use caching code."])
  AC_DEFINE(HAVE_CACHE,0, ["cache variables to speed up the code."])
else
  AC_DEFINE(HAVE_CACHE,1, ["cache variables to speed up the code."])
  AC_MSG_RESULT(yes)
fi
AC_SUBST(HAVE_CACHE)

# Checks for libraries.
AC_CHECK_LIB(m, sqrt, , AC_MSG_ERROR([compatible libc math library not found]))

# CodePatterns library (serialization header before MemDebug.hpp ) 
AM_PATH_CODEPATTERNS([1.1.5], $have_debug,,[AC_MSG_ERROR([Missing CodePatterns library, please specify PKG_CONFIG_PATH or use --with-codepatterns...])])

# boost
BOOST_REQUIRE([1.40])

# boost headers
BOOST_BIND
BOOST_EXCEPTION

# boost libraries
BOOST_SERIALIZATION

# Checks for header files.
AC_HEADER_STDC
AC_CHECK_HEADERS([sys/time.h])
AC_HEADER_STDBOOL

AC_FUNC_MALLOC
AC_FUNC_REALLOC
AC_CHECK_FUNCS([floor pow sqrt strchr])

# Checks for typedefs, structures, and compiler characteristics.
AC_C_CONST
AC_C_INLINE
AC_C_RESTRICT
AC_TYPE_SIZE_T

# Checks for library functions.
# check for GNU Scientific Library
AC_CHECK_HEADERS([gsl/gsl_blas.h])
AC_SEARCH_LIBS(dnrm2, gslblas gslcblas goto blas cblas)
AC_SEARCH_LIBS(cblas_dnrm2, gslblas gslcblas blas cblas)
AC_SEARCH_LIBS(gsl_blas_dnrm2,, gsl)
#AC_CHECK_LIB(gsl, gsl_blas_dnrm2, , [AC_MSG_ERROR(["No working BLAS found for GSL, stopping."])])
AC_CHECK_LIB(gsl, main)

# use CppUnit TestRunner or not
AC_ARG_ENABLE([ecut],AS_HELP_STRING([--enable-ecut],[Use ECut TestRunnerClient (default is no)]),
              [enable_ecut=$enableval], [enable_ecut=no])
if test x"$enable_ecut" = xyes; then
  AC_DEFINE(HAVE_ECUT,1, ["Use ECut TestRunnerClient instead of our own."])
  AC_SUBST(HAVE_ECUT)
fi

# with valgrinding testsuite or not
AC_MSG_CHECKING(whether to enable valgrind memory checking in testsuite)
AC_ARG_WITH([valgrind],AS_HELP_STRING([--with-valgrind],[Use Valgrind on the testsuite (default is no)]),
              [with_valgrind=$withval], [with_valgrind=no])
AC_MSG_RESULT($with_valgrind)
AS_IF([test "$with_valgrind" = yes],[
  AC_CHECK_HEADER([valgrind/valgrind.h],
    [
      # check header
      AC_DEFINE(HAVE_VALGRIND_TESTSUITE,1, ["Use Valgrind to check the testsuite."])
      # check path
      AC_PATH_PROG(VALGRIND, [valgrind], [/bin/false])
      # set variables 
      AC_SUBST(HAVE_VALGRIND_TESTSUITE)
      AC_SUBST(VALGRIND)
    ],
    [
      AC_MSG_ERROR(["Valgrind support requested but headers not available."])
    ]
  )
])

# Check for "extern inline", using a modified version
# of the test for AC_C_INLINE from acspecific.mt
AC_CACHE_CHECK([for extern inline], ac_cv_c_extern_inline,
[ac_cv_c_extern_inline=no
AC_TRY_COMPILE([extern $ac_cv_c_inline double foo(double x);
extern $ac_cv_c_inline double foo(double x) { return x+1.0; };
double foo (double x) { return x + 1.0; };], 
[  foo(1.0)  ],
[ac_cv_c_extern_inline="yes"])
])

if test "$ac_cv_c_inline" != no ; then
  AC_DEFINE(HAVE_INLINE,1, ["May use inline routines"])
  AC_SUBST(HAVE_INLINE)
fi

#AC_MSG_NOTICE(["CFLAGS: $CFLAGS, CXXFLAGS: $CXXFLAGS, LDFLAGS: $LDFLAGS, CC: $CC, CXX:, $CXX, MPICC: $MPICC, MPILIBS: $MPILIBS, LIBS: $LIBS"])

# test suite
AC_CONFIG_TESTDIR(tests/CodeChecks)
AC_CONFIG_FILES([
        tests/CodeChecks/atlocal 
        tests/CodeChecks/Makefile])

AC_CONFIG_FILES([
  LinearAlgebra.pc:LinearAlgebra.pc.in
  LinearAlgebra-debug.pc:LinearAlgebra-debug.pc.in])

AC_CONFIG_FILES([
        Makefile 
        doc/Makefile 
        src/LinearAlgebra/Makefile 
])

AC_CONFIG_FILES([
        src/unittests/Makefile
])
AC_OUTPUT